Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BEDDINJ

BEDDINJ.m

Go to the documentation of this file. 
  1. BEDDINJ ;GDIT/HS/BEE-BEDD Retrieve Injury Information ; 08 Nov 2011  12:00 PM
  1.  ;;2.0;BEDD DASHBOARD;;Jun 04, 2014;Build 13
  1.  ;
  1.  ;This routine is included in the BEDD XML 2.0 install and is not in the KIDS
  1.  ; 
  1.  Q
  1. ISINJ(VIEN) ;Return whether visit is injury related or not
  1.  ;
  1.  NEW EXEC,ISINJ,INJ,OBJID
  1.  ;
  1.  I $G(VIEN)="" Q 0
  1.  ;
  1.  S EXEC="S OBJID=$O(^BEDD.EDVISITI(""ADIdx"",VIEN,""""))" X EXEC
  1.  I OBJID="" Q 0
  1.  ;
  1.  ;Check if it is an injury
  1.  S EXEC="S INJ=##CLASS(BEDD.EDVISIT).%OpenId("_OBJID_",0)" X EXEC
  1.  S EXEC="S ISINJ=INJ.Injury" X EXEC
  1.  S INJ=$S($G(ISINJ)="YES":1,1:0)
  1.  ;
  1.  Q INJ
  1.  ;
  1. INJURY(VIEN,INJURY) ;Return injury related information entered on the dashboard
  1.  ;
  1.  I $G(VIEN)="" Q
  1.  ;
  1.  NEW OBJID,EXEC,INJ,ICIEN,INLOC,INSCO,INSPO,ISINJ,INDAT,MVLOC,INSET,INJEQ,WKREL
  1.  ;
  1.  ;Get the BEDD Object Id
  1.  S (ISINJ,ICIEN,OBJID,INLOC,INSCO,INSPO,INDAT,MVLOC,INSET,INJEQ,WKREL)=""
  1.  S EXEC="S OBJID=$O(^BEDD.EDVISITI(""ADIdx"",VIEN,""""))" X EXEC
  1.  I OBJID="" Q
  1.  ;
  1.  S EXEC="S INJ=##CLASS(BEDD.EDVISIT).%OpenId("_OBJID_",0)" X EXEC
  1.  S EXEC="S ISINJ=INJ.Injury" X EXEC
  1.  S EXEC="S ICIEN=INJ.PtInjury.InjCauseIEN" X EXEC
  1.  S EXEC="S INLOC=INJ.PtInjury.InjLocat" X EXEC
  1.  S EXEC="S INSCO=INJ.PtInjury.AtFaultInsurance" X EXEC
  1.  S EXEC="S INSPO=INJ.PtInjury.AtFaultInsPolicy" X EXEC
  1.  S EXEC="S INDAT=INJ.PtInjury.InjDtTm" X EXEC
  1.  S EXEC="S MVLOC=INJ.PtInjury.MVCLoc" X EXEC
  1.  S EXEC="S INSET=INJ.PtInjury.InjSet" X EXEC
  1.  S EXEC="S INJEQ=INJ.PtInjury.SafetyEquip" X EXEC
  1.  S EXEC="S WKREL=INJ.PtInjury.WrkRel" X EXEC
  1.  S INJ=""
  1.  ;
  1.  S INJURY("OBJID")=OBJID
  1.  S INJURY("ISINJ")=ISINJ
  1.  S INJURY("ICIEN")=ICIEN
  1.  S INJURY("INLOC")=$E(INLOC,1,100)
  1.  S INJURY("INSCO")=INSCO
  1.  S INJURY("INSPO")=INSPO
  1.  S INJURY("INDAT")=INDAT
  1.  S INJURY("MVLOC")=MVLOC
  1.  S INJURY("INSET")=INSET
  1.  S INJURY("INJEQ")=INJEQ
  1.  S INJURY("WKREL")=$S(WKREL="YES":1,1:0)
  1.  ;
  1.  Q
  1.  ;
  1. UPDINJ(VIEN) ;Update the BEDD injury information
  1.  ;
  1.  I $G(VIEN)="" Q
  1.  ;
  1.  NEW OBJID,EXEC,INJ,ISINJ,STS,AUPNVSIT
  1.  ;
  1.  ;Get the BEDD Object Id
  1.  S (ISINJ,OBJID)=""
  1.  S EXEC="S OBJID=$O(^BEDD.EDVISITI(""ADIdx"",VIEN,""""))" X EXEC
  1.  I OBJID="" Q
  1.  ;
  1.  ;Format Injury
  1.  S ISINJ=$G(^TMP("AMER",$J,2,2)) S ISINJ=$S(ISINJ=1:"YES",1:"NO")
  1.  ;
  1.  S EXEC="S INJ=##CLASS(BEDD.EDVISIT).%OpenId("_OBJID_",0)" X EXEC
  1.  ;
  1.  ;Injury YES/NO
  1.  S EXEC="S INJ.Injury=ISINJ" X EXEC
  1.  ;
  1.  ;Injury Cause
  1.  S EXEC="S INJ.PtInjury.InjCauseIEN=$G(^TMP(""AMER"",$J,2,33))" X EXEC
  1.  ;
  1.  ;Injury Town Location
  1.  S EXEC="I $G(^TMP(""AMER"",$J,2,31))]"""" S INJ.PtInjury.InjLocat=$G(^TMP(""AMER"",$J,2,31))" X EXEC
  1.  ;S EXEC="S INSCO=INJ.PtInjury.AtFaultInsurance" X EXEC
  1.  ;S EXEC="S INSPO=INJ.PtInjury.AtFaultInsPolicy" X EXEC
  1.  ;
  1.  ;Injury Date/Time
  1.  S EXEC="S INJ.PtInjury.InjDtTm=$G(^TMP(""AMER"",$J,2,32))" X EXEC
  1.  ;
  1.  ;Injury - MVC Location
  1.  S EXEC="S INJ.PtInjury.MVCLoc=$G(^TMP(""AMER"",$J,2,41))" X EXEC
  1.  ;
  1.  ;Injury - Driver Insurance Company
  1.  S EXEC="S INJ.PtInjury.AtFaultInsurance=$G(^TMP(""AMER"",$J,2,42))" X EXEC
  1.  ;
  1.  ;Injury - Driver Insurance Policy
  1.  S EXEC="S INJ.PtInjury.AtFaultInsPolicy=$G(^TMP(""AMER"",$J,2,43))" X EXEC
  1.  ;
  1.  ;Injury - Setting
  1.  S EXEC="S INJ.PtInjury.InjSet=$G(^TMP(""AMER"",$J,2,34))" X EXEC
  1.  ;
  1.  ;Injury - Safety Equipment
  1.  S EXEC="S INJ.PtInjury.SafetyEquip=$G(^TMP(""AMER"",$J,2,35))" X EXEC
  1.  ;
  1.  ;Save the entry
  1.  S EXEC="S STS=INJ.%Save()" X EXEC
  1.  S INJ=""
  1.  ;
  1.  ;Flag visit as updated
  1.  S AUPNVSIT=VIEN D MOD^AUPNVSIT
  1.  ;
  1.  Q
  1.  ;
  1. INJFLD(VIEN,FIELD,VALUE) ;Update the specific BEDD injury field
  1.  ;
  1.  I $G(VIEN)="" Q
  1.  ;
  1.  NEW OBJID,EXEC,INJ,STS,AUPNVSIT
  1.  ;
  1.  ;Get the BEDD Object Id
  1.  S (OBJID)=""
  1.  S EXEC="S OBJID=$O(^BEDD.EDVISITI(""ADIdx"",VIEN,""""))" X EXEC
  1.  I OBJID="" Q
  1.  ;
  1.  ;Format Injury
  1.  I (FIELD="INJ.Injury")!(FIELD="INJ.PtInjury.WrkRel") S VALUE=$S(VALUE=1:"YES",1:"NO")
  1.  ;
  1.  ;Open the entry
  1.  S EXEC="S INJ=##CLASS(BEDD.EDVISIT).%OpenId("_OBJID_",0)" X EXEC
  1.  ;
  1.  ;Assemble the entry to save
  1.  S EXEC="S "_FIELD_"="""_VALUE_"""" X EXEC
  1.  ;
  1.  ;Save the entry
  1.  S EXEC="S STS=INJ.%Save()" X EXEC
  1.  S INJ=""
  1.  ;
  1.  ;Flag visit as updated
  1.  S AUPNVSIT=VIEN D MOD^AUPNVSIT
  1.  Q