Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BGP1DCL

BGP1DCL.m

Go to the documentation of this file. 
  1. BGP1DCL ; IHS/CMI/LAB - national patient list 20 Dec 2004 9:24 AM ;
  1.  ;;11.1;IHS CLINICAL REPORTING SYSTEM;;JUN 27, 2011;Build 33
  1.  ;
  1.  ;
  1.  ;
  1.  W:$D(IOF) @IOF
  1.  W !,$$CTR("Comprehensive National GPRA & PART Patient List",80)
  1.  W !,$$CTR($$RPTVER^BGP1BAN,80)
  1. INTRO ;
  1.  D XIT
  1.  S BGPTEXT="INTROT" F BGPJ=1:1 S BGPX=$T(@BGPTEXT+BGPJ) Q:$P(BGPX,";;",2)="END"  S BGPT=$P(BGPX,";;",2) W !,BGPT
  1.  D EOP
  1.  S BGPTEXT="INTROT1" F BGPJ=1:1 S BGPX=$T(@BGPTEXT+BGPJ) Q:$P(BGPX,";;",2)="END"  S BGPT=$P(BGPX,";;",2) W !,BGPT
  1.  S DIR(0)="Y",DIR("A")="Do you wish to continue",DIR("B")="N" KILL DA D ^DIR KILL DIR
  1.  I $D(DIRUT) D XIT Q
  1.  I 'Y D XIT Q
  1.  D TAXCHK^BGP1XTCN
  1.  S X=$$DEMOCHK^BGP1UTL2()
  1.  I 'X W !!,"Exiting Report....." D PAUSE^BGP1CL,XIT Q
  1. TP ;get time period
  1.  D XIT
  1.  S BGPRTYPE=1,BGP1RPTH="",BGPCPPL=1,BGPINDB="G",BGP1GPU=1
  1. SI ;
  1.  K DIRUT
  1.  ;get report type
  1.  I $D(DIRUT) G XIT
  1.  D RT^BGP1DSL I '$D(BGPLIST)!($D(BGPQUIT)) G XIT
  1.  G TP1  ;FOR TESTING COMMENT OUT
  1.  ;BEGIN TEST STUFF
  1.  W !!,"for testing purposes only, please enter a report year",!
  1.  D F
  1.  I BGPPER="" W !!,"no year entered..bye" D XIT Q
  1.  S BGPQTR=3
  1.  S BGPBD=$E(BGPPER,1,3)_"0101",BGPED=$E(BGPPER,1,3)_"1231"
  1.  S BGPPBD=($E(BGPPER,1,3)-1)_"0101",BGPPED=($E(BGPPER,1,3)-1)_"1231"
  1.  W !!,"for testing purposes only, please enter a BASELINE year",!
  1.  ;D B
  1.  I BGPBPER="" W !!,"no year entered..bye" D XIT Q
  1.  S BGPBBD=$E(BGPBPER,1,3)_"0101",BGPBED=$E(BGPBPER,1,3)_"1231"
  1.  ;END TEST STUFF
  1. TP1 S (BGPBD,BGPED,BGPTP)=""
  1.  S DIR(0)="S^1:January 1 - December 31;2:April 1 - March 31;3:July 1 - June 30;4:October 1 - September 30;5:User-Defined Report Period",DIR("A")="Enter the date range for your report" KILL DA D ^DIR KILL DIR
  1.  I $D(DIRUT) D XIT Q
  1.  S BGPQTR=Y
  1.  I BGPQTR=5 D ENDDATE
  1.  I BGPQTR'=5 D F
  1.  I BGPPER="" W !,"Year not entered.",! G TP1
  1.  I BGPQTR=1 S BGPBD=$E(BGPPER,1,3)_"0101",BGPED=$E(BGPPER,1,3)_"1231"
  1.  I BGPQTR=2 S BGPBD=($E(BGPPER,1,3)-1)_"0401",BGPED=$E(BGPPER,1,3)_"0331"
  1.  I BGPQTR=3 S BGPBD=($E(BGPPER,1,3)-1)_"0701",BGPED=$E(BGPPER,1,3)_"0630"
  1.  I BGPQTR=4 S BGPBD=($E(BGPPER,1,3)-1)_"1001",BGPED=$E(BGPPER,1,3)_"0930"
  1.  I BGPQTR=5 S BGPBD=$$FMADD^XLFDT(BGPPER,-364),BGPED=BGPPER,BGPPER=$E(BGPED,1,3)_"0000"
  1.  I BGPED>DT D  G:BGPDO=1 TP1
  1.  .W !!,"You have selected Current Report period ",$$FMTE^XLFDT(BGPBD)," through ",$$FMTE^XLFDT(BGPED),"."
  1.  .W !,"The end date of this report is in the future; your data will not be",!,"complete.",!
  1.  .K DIR S BGPDO=0 S DIR(0)="Y",DIR("A")="Do you want to change your Current Report Dates",DIR("B")="N" KILL DA D ^DIR KILL DIR
  1.  .I $D(DIRUT) S BGPDO=1 Q
  1.  .I Y S BGPDO=1 Q
  1.  .Q
  1. BY ;get baseline year
  1.  S BGPVDT=""
  1.  W !!,"Enter the Baseline Year to compare data to.",!,"Use a 4 digit year, e.g. 1999, 2000"
  1.  S DIR(0)="D^::EP"
  1.  S DIR("A")="Enter Year (e.g. 2000)"
  1.  D ^DIR KILL DIR
  1.  I $D(DIRUT) G TP
  1.  I $D(DUOUT) S DIRUT=1 G TP
  1.  S BGPVDT=Y
  1.  I $E(Y,4,7)'="0000" W !!,"Please enter a year only!",! G BY
  1.  S X=$E(BGPPER,1,3)-$E(BGPVDT,1,3)
  1.  S X=X_"0000"
  1.  S BGPBBD=BGPBD-X,BGPBBD=$E(BGPBBD,1,3)_$E(BGPBD,4,7)
  1.  S BGPBED=BGPED-X,BGPBED=$E(BGPBED,1,3)_$E(BGPED,4,7)
  1.  S BGPPBD=($E(BGPBD,1,3)-1)_$E(BGPBD,4,7)
  1.  S BGPPED=($E(BGPED,1,3)-1)_$E(BGPED,4,7)
  1.  W !!,"The date ranges for this report are:"
  1.  W !?5,"Report Period: ",?31,$$FMTE^XLFDT(BGPBD)," to ",?31,$$FMTE^XLFDT(BGPED)
  1.  W !?5,"Previous Year Period: ",?31,$$FMTE^XLFDT(BGPPBD)," to ",?31,$$FMTE^XLFDT(BGPPED)
  1.  W !?5,"Baseline Period: ",?31,$$FMTE^XLFDT(BGPBBD)," to ",?31,$$FMTE^XLFDT(BGPBED)
  1.  I BGPPBD=BGPBBD,BGPPED=BGPBED K Y D CHKY I Y K BGPBBD,BGPBED,BGPPBD,BGPPED G BY
  1. COMM ;
  1.  W !!,"Specify the community taxonomy to determine which patients will be",!,"included in the report.  You should have created this taxonomy using QMAN.",!
  1.  K BGPTAX
  1.  S BGPTAXI=""
  1.  D ^XBFMK
  1.  S DIC("S")="I $P(^(0),U,15)=9999999.05",DIC="^ATXAX(",DIC(0)="AEMQ",DIC("A")="Enter the Name of the Community Taxonomy: "
  1.  S B=$P($G(^BGPSITE(DUZ(2),0)),U,5) I B S DIC("B")=$P(^ATXAX(B,0),U)
  1.  D ^DIC
  1.  I Y=-1 Q
  1.  S BGPTAXI=+Y
  1. COM1 S X=0
  1.  S X=0
  1.  F  S X=$O(^ATXAX(BGPTAXI,21,X)) Q:'X  D
  1.  .S BGPTAX($P(^ATXAX(BGPTAXI,21,X,0),U))=""
  1.  .Q
  1.  I '$D(BGPTAX) W !!,"There are no communities in that taxonomy." G COMM
  1.  S X=0,G=0
  1.  F  S X=$O(^ATXAX(BGPTAXI,21,X)) Q:'X  D
  1.  .S C=$P(^ATXAX(BGPTAXI,21,X,0),U)
  1.  .I '$D(^AUTTCOM("B",C)) W !!,"***  Warning: Community ",C," is in the taxonomy but was not",!,"found in the standard community table." S G=1
  1.  .Q
  1.  I G D  I BGPQUIT D XIT Q
  1.  .W !!,"These communities may have been renamed or there may be patients"
  1.  .W !,"who have been reassigned from this community to a new community and this"
  1.  .W !,"could reduce your patient population."
  1.  .S BGPQUIT=0
  1.  .S DIR(0)="Y",DIR("A")="Do you want to cancel the report and review the communities" KILL DA D ^DIR KILL DIR
  1.  .I $D(DIRUT) S BGPQUIT=1
  1.  .I Y S BGPQUIT=1
  1.  .Q
  1. MFIC K BGPQUIT
  1.  I $P($G(^BGPSITE(DUZ(2),0)),U,8)=1 D  I BGPMFITI="" G COMM
  1.  .S BGPMFITI=""
  1.  .W !!,"Specify the LOCATION taxonomy to determine which patient visits will be"
  1.  .W !,"used to determine whether a patient is in the denominators for the report."
  1.  .W !,"You should have created this taxonomy using QMAN.",!
  1.  .K BGPMFIT
  1.  .S BGPMFITI=""
  1.  .D ^XBFMK
  1.  .S DIC("S")="I $P(^(0),U,15)=9999999.06",DIC="^ATXAX(",DIC(0)="AEMQ",DIC("A")="Enter the Name of the Location/Facility Taxonomy: "
  1.  .S B=$P($G(^BGPSITE(DUZ(2),0)),U,9) I B S DIC("B")=$P(^ATXAX(B,0),U)
  1.  .D ^DIC
  1.  .I Y=-1 Q
  1.  .S BGPMFITI=+Y
  1. BEN ;
  1.  S BGPBEN=""
  1.  S DIR(0)="S^1:Indian/Alaskan Native (Classification 01);2:Not Indian Alaskan/Native (Not Classification 01);3:All (both Indian/Alaskan Natives and Non 01)",DIR("A")="Select Beneficiary Population to include in this report"
  1.  S DIR("B")="1" KILL DA D ^DIR KILL DIR
  1.  I $D(DIRUT) G COMM
  1.  S BGPBEN=Y
  1. HOME ;
  1.  S BGPHOME=$P($G(^BGPSITE(DUZ(2),0)),U,2)
  1.  ;I BGPHOME="" W !!,"Home Location not found in Site File!!",!,"PHN Visits counts to Home will be calculated using clinic 11 only!!" H 2 G SUM
  1.  ;W !,"Your HOME location is defined as: ",$P(^DIC(4,BGPHOME,0),U)," asufac:  ",$P(^AUTTLOC(BGPHOME,0),U,10)
  1. AI ;gather all gpra measures
  1.  S X=0 F  S X=$O(^BGPINDB("GPRA",1,X)) Q:X'=+X  S BGPIND(X)=""
  1.  S BGPINDB="G"
  1. SUM ;display summary of this report
  1.  W:$D(IOF) @IOF
  1.  W !,$$CTR("SUMMARY OF COMPREHENSIVE NATIONAL GPRA & PART PATIENT "),$$CTR("LIST REPORT TO BE GENERATED")
  1.  W !,$$CTR($$RPTVER^BGP1BAN,80)
  1.  W !!,"The date ranges for this report are:"
  1.  W !?5,"Report Period: ",?31,$$FMTE^XLFDT(BGPBD)," to ",?31,$$FMTE^XLFDT(BGPED)
  1.  W !?5,"Previous Year Period: ",?31,$$FMTE^XLFDT(BGPPBD)," to ",?31,$$FMTE^XLFDT(BGPPED)
  1.  W !?5,"Baseline Period: ",?31,$$FMTE^XLFDT(BGPBBD)," to ",?31,$$FMTE^XLFDT(BGPBED)
  1.  W !!,"The COMMUNITY Taxonomy to be used is: ",$P(^ATXAX(BGPTAXI,0),U)
  1.  I $G(BGPMFITI) W !!,"The MFI Location Taxonomy to be used is: ",$P(^ATXAX(BGPMFITI,0),U)
  1.  ;I BGPHOME W !,"The HOME location is: ",$P(^DIC(4,BGPHOME,0),U)," ",$P(^AUTTLOC(BGPHOME,0),U,10)
  1.  ;I 'BGPHOME W !,"No HOME Location selected."
  1.  D PT^BGP1DSL
  1.  I BGPROT="" G COMM
  1. ZIS ;call to XBDBQUE
  1.  D REPORT^BGP1UTL
  1.  I $G(BGPQUIT) D XIT Q
  1.  I BGPRPT="" D XIT Q
  1.  K IOP,%ZIS I BGPROT="D",BGPDELT="F" D NODEV,XIT Q
  1.  K IOP,%ZIS W !! S %ZIS=$S(BGPDELT'="S":"PQM",1:"PM") D ^%ZIS
  1.  I POP W !,"Report Aborted" S DA=BGPRPT,DIK="^BGPGPDCB(" D ^DIK K DIK D XIT Q
  1.  I POP W !,"Report Aborted" S DA=BGPRPT,DIK="^BGPGPDPB(" D ^DIK K DIK D XIT Q
  1.  I POP W !,"Report Aborted" S DA=BGPRPT,DIK="^BGPGPDBB(" D ^DIK K DIK D XIT Q
  1.  I $D(IO("Q")) G TSKMN
  1. DRIVER ;
  1.  S BGPCPLC=0
  1.  D ^BGP1D1
  1.  U IO
  1.  D ^BGP1DP
  1.  D ^%ZISC
  1.  D XIT
  1.  Q
  1.  ;
  1. NODEV ;
  1.  S XBRP="",XBRC="NODEV1^BGP1DCL",XBRX="XIT^BGP1DCL",XBNS="BGP"
  1.  D ^XBDBQUE
  1.  Q
  1.  ;
  1. NODEV1 ;
  1.  S BGPCPLC=0
  1.  D ^BGP1D1
  1.  D ^BGP1DP
  1.  D ^%ZISC
  1.  D XIT
  1.  Q
  1. TSKMN ;EP ENTRY POINT FROM TASKMAN
  1.  S ZTIO=$S($D(ION):ION,1:IO) I $D(IOST)#2,IOST]"" S ZTIO=ZTIO_";"_IOST
  1.  I $G(IO("DOC"))]"" S ZTIO=ZTIO_";"_$G(IO("DOC"))
  1.  I $D(IOM)#2,IOM S ZTIO=ZTIO_";"_IOM I $D(IOSL)#2,IOSL S ZTIO=ZTIO_";"_IOSL
  1.  K ZTSAVE S ZTSAVE("BGP*")=""
  1.  S ZTCPU=$G(IOCPU),ZTRTN="DRIVER^BGP1DCL",ZTDTH="",ZTDESC="COMPREHENSIVE PT LIST GPRA 06" D ^%ZTLOAD D XIT Q
  1.  Q
  1.  ;
  1. XIT ;
  1.  D ^%ZISC
  1.  D EN^XBVK("BGP") I $D(ZTQUEUED) S ZTREQ="@"
  1.  K DIRUT,DUOUT,DIR,DOD
  1.  K DIADD,DLAYGO
  1.  D KILL^AUPNPAT
  1.  K X,X1,X2,X3,X4,X5,X6
  1.  K A,B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,V,W,X,Y,Z
  1.  K N,N1,N2,N3,N4,N5,N6
  1.  K BD,ED
  1.  D KILL^AUPNPAT
  1.  D ^XBFMK
  1.  Q
  1.  ;
  1. CTR(X,Y) ;EP - Center X in a field Y wide.
  1.  Q $J("",$S($D(Y):Y,1:IOM)-$L(X)\2)_X
  1.  ;----------
  1. EOP ;EP - End of page.
  1.  Q:$E(IOST)'="C"
  1.  ;Q:$D(ZTQUEUED)!'(IOT="TRM")!$D(IO("S"))
  1.  NEW DIR
  1.  K DIR,DIRUT,DFOUT,DLOUT,DTOUT,DUOUT
  1.  S DIR("A")="Press ENTER to Continue"
  1.  S DIR(0)="E" D ^DIR KILL DIR
  1.  Q
  1.  ;----------
  1. USR() ;EP - Return name of current user from ^VA(200.
  1.  Q $S($G(DUZ):$S($D(^VA(200,DUZ,0)):$P(^(0),U),1:"UNKNOWN"),1:"DUZ UNDEFINED OR 0")
  1.  ;----------
  1. LOC() ;EP - Return location name from file 4 based on DUZ(2).
  1.  Q $S($G(DUZ(2)):$S($D(^DIC(4,DUZ(2),0)):$P(^(0),U),1:"UNKNOWN"),1:"DUZ(2) UNDEFINED OR 0")
  1.  ;----------
  1.  ;
  1. CHKY ;
  1.  W !!,"The baseline year and the previous year time periods are the same.",!!
  1.  S DIR(0)="Y",DIR("A")="Do you want to change the baseline year",DIR("B")="N" KILL DA D ^DIR KILL DIR
  1.  I $D(DIRUT) S Y="" Q
  1.  Q
  1. F ;calendar year
  1.  S (BGPPER,BGPVDT)=""
  1.  W !!,"Enter the Calendar Year for the report END date.  Use a 4 digit",!,"year, e.g. 2011"
  1.  S DIR(0)="D^::EP"
  1.  S DIR("A")="Enter Year"
  1.  S DIR("?")="This report is compiled for a period.  Enter a valid date."
  1.  D ^DIR KILL DIR
  1.  I $D(DIRUT) Q
  1.  I $D(DUOUT) S DIRUT=1 Q
  1.  S BGPVDT=Y
  1.  I $E(Y,4,7)'="0000" W !!,"Please enter a year only!",! G F
  1.  S BGPPER=BGPVDT
  1.  Q
  1. ENDDATE ;
  1.  W !!,"When entering dates, if you do not enter a full 4 digit year (e.g. 2011)"
  1.  W !,"will assume a year in the past, if you want to put in a future date,"
  1.  W !,"remember to enter the full 4 digit year.  For example, if today is"
  1.  W !,"January 4, 2010 and you type in 6/30/06 the system will assume the year"
  1.  W !,"as 1906 since that is a date in the past.  You must type 6/30/2010 if you"
  1.  W !,"want a date in the future."
  1.  S (BGPPER,BGPVDT)=""
  1.  W ! K DIR,X,Y S DIR(0)="D^::EP",DIR("A")="Enter End Date for the Report: (e.g. 11/30/2005)" D ^DIR K DIR S:$D(DUOUT) DIRUT=1
  1.  I $D(DIRUT) Q
  1.  S (BGPPER,BGPVDT)=Y
  1.  Q
  1. INTROT ;
  1.  ;;This report will enable users to run a patient list that shows all of the
  1.  ;;National GPRA & PART Report performance measures in which 
  1.  ;;a patient was included but did not meet. Performance measures
  1.  ;;not relevant to a patient will not be listed.  For example, if a male
  1.  ;;patient who is 30 years old, he would not be listed as having not met
  1.  ;;the Child Immunizations or Pap Smear measures.
  1.  ;;
  1.  ;;The list will include the National GPRA & PART Report logic and performance 
  1.  ;;measure rates for Report Period, Previous Year, and Baseline Year for all
  1.  ;;the measures, followed by a list of patients that shows which
  1.  ;;measures each patient did not meet.
  1.  ;;
  1.  ;;You will be asked to provide the community taxonomy to determine
  1.  ;;which patients will be included, the beneficiary populaton of the patients,
  1.  ;;and the Report Period and Baseline Year.
  1.  ;;
  1.  ;;
  1.  ;;END
  1.  ;
  1. INTROT1 ;
  1.  ;;W A R N I N G *** W A R N I N G *** W A R N I N G ***
  1.  ;;
  1.  ;;This report will list every patient in your user population that has
  1.  ;;not met one of the measures.  This report can be very, very lengthy.
  1.  ;;For example, if there are 10,000 patients in your user population
  1.  ;;and at least 8,000 of them have not met one or more measures then
  1.  ;;the report will list 8,000 patients. At approximately 45 patients per
  1.  ;;page, the report will be 177 pages long.  It is highly recommended
  1.  ;;that you use the delimited output for this report rather than print
  1.  ;;it to a printer/paper.
  1.  ;;
  1.  ;;END