Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BGP8PCD

BGP8PCD.m

Go to the documentation of this file. 
  1. BGP8PCD ;IHS/CMI/LAB - GPRA REPORT DRIVER;
  1.  ;;18.1;IHS CLINICAL REPORTING;;MAY 25, 2018;Build 66
  1.  ;
  1.  ;
  1.  W:$D(IOF) @IOF
  1.  W !!,$$CTR("2018 IPC Clinical Performance Measure Report",80)
  1. INTRO ;
  1.  D XIT
  1.  W !,"This will produce an IPC performance measures for all IPC performance"
  1.  W !,"measures for a year period you specify.  You will be asked to provide:"
  1.  W !,"1) the measures for the report, 2) the reporting period, 3) the baseline"
  1.  W !,"period to compare data to, 4) the community taxonomy to determine which"
  1.  W !,"patients will be included, and 5) the patient population (i.e. AI/AN only,"
  1.  W !,"non AI/AN, or both) to determine which patients will be included."
  1.  W !!,"There are "_$$CNT()_" measures in the IPC Clinical Performance Measure Report."
  1.  K DIR S DIR(0)="E",DIR("A")="Press enter to continue" D ^DIR K DIR
  1.  D XIT
  1.  K DIR
  1.  S DIR(0)="S^S:Selected set of Measures;A:All Measures",DIR("A")="Run the report on",DIR("B")="S" KILL DA D ^DIR KILL DIR
  1.  I $D(DIRUT) D XIT Q
  1.  S BGPZZ=Y
  1.  I BGPZZ="S" D EN^BGP8PCSI I '$D(BGPIND) W !!,"No measures selected" G INTRO
  1.  I BGPZZ="A" S X=0 F  S X=$O(^BGPINDR("AIPC",X)) Q:X'=+X  S Y=0 F  S Y=$O(^BGPINDR("AIPC",X,Y)) Q:Y'=+Y  S BGPIND(Y)=""
  1.  D TAXCHK^BGP8PCTX  ;check for taxonomies
  1.  S X=$$DEMOCHK^BGP8UTL2()  ;want demo patients?
  1.  I 'X W !!,"Exiting Report....." D PAUSE^BGP8DU,XIT Q
  1. TP ;get time period
  1.  S BGPRTYPE=2,BGPYRPTH="",BGPINDG="I"
  1.  S (BGPBD,BGPED,BGPTP)=""
  1.  S DIR(0)="S^1:January 1 - December 31;2:April 1 - March 31;3:July 1 - June 30;4:October 1 - September 30;5:User defined date range",DIR("A")="Enter the date range for your report" KILL DA D ^DIR KILL DIR
  1.  I $D(DIRUT) D XIT Q
  1.  S BGPQTR=Y
  1.  I BGPQTR=5 D ENDDATE
  1.  I BGPQTR'=5 D F
  1.  I BGPPER="" W !,"Year not entered.",! G TP
  1.  I BGPQTR=1 S BGPBD=$E(BGPPER,1,3)_"0101",BGPED=$E(BGPPER,1,3)_"1231"
  1.  I BGPQTR=2 S BGPBD=($E(BGPPER,1,3)-1)_"0401",BGPED=$E(BGPPER,1,3)_"0331"
  1.  I BGPQTR=3 S BGPBD=($E(BGPPER,1,3)-1)_"0701",BGPED=$E(BGPPER,1,3)_"0630"
  1.  I BGPQTR=4 S BGPBD=($E(BGPPER,1,3)-1)_"1001",BGPED=$E(BGPPER,1,3)_"0930"
  1.  I BGPQTR=5 D
  1.  .S D=$$FMADD^XLFDT(BGPPER,1)
  1.  .I $E(BGPPER,4,7)'=1231 S BGPBD=($E(BGPPER,1,3)-1)_$E(D,4,7),BGPED=BGPPER,BGPPER=$E(BGPED,1,3)_"0000"
  1.  .I $E(BGPPER,4,7)=1231 S BGPBD=$E(BGPPER,1,3)_$E(D,4,7),BGPED=BGPPER,BGPPER=$E(BGPED,1,3)_"0000"
  1.  I BGPED>DT D  G:BGPDO=1 TP
  1.  .W !!,"You have selected Current Report period ",$$FMTE^XLFDT(BGPBD)," through ",$$FMTE^XLFDT(BGPED),"."
  1.  .W !,"The end date of this report is in the future; your data will not be",!,"complete.",!
  1.  .K DIR S BGPDO=0 S DIR(0)="Y",DIR("A")="Do you want to change your Current Report Dates",DIR("B")="N" KILL DA D ^DIR KILL DIR
  1.  .I $D(DIRUT) S BGPDO=1 Q
  1.  .I Y S BGPDO=1 Q
  1.  .Q
  1. BY ;get baseline year
  1.  S BGPVDT=""
  1.  W !!,"Enter the Baseline Year to compare data to.",!,"Use a 4 digit year, e.g. 2016"
  1.  S DIR(0)="D^::EP"
  1.  S DIR("A")="Enter Year (e.g. 2016)"
  1.  D ^DIR KILL DIR
  1.  I $D(DIRUT) G TP
  1.  I $D(DUOUT) S DIRUT=1 G TP
  1.  S BGPVDT=Y
  1.  I $E(Y,4,7)'="0000" W !!,"Please enter a year only!",! G BY
  1.  S X=$E(BGPPER,1,3)-$E(BGPVDT,1,3)
  1.  S X=X_"0000"
  1.  S BGPBBD=BGPBD-X,BGPBBD=$E(BGPBBD,1,3)_$E(BGPBD,4,7)
  1.  S BGPBED=BGPED-X,BGPBED=$E(BGPBED,1,3)_$E(BGPED,4,7)
  1.  S BGPPBD=($E(BGPBD,1,3)-1)_$E(BGPBD,4,7)
  1.  S BGPPED=($E(BGPED,1,3)-1)_$E(BGPED,4,7)
  1.  W !!,"The date ranges for this report are:"
  1.  W !?5,"Report Period: ",?31,$$FMTE^XLFDT(BGPBD)," to ",?31,$$FMTE^XLFDT(BGPED)
  1.  W !?5,"Previous Year Period: ",?31,$$FMTE^XLFDT(BGPPBD)," to ",?31,$$FMTE^XLFDT(BGPPED)
  1.  W !?5,"Baseline Period: ",?31,$$FMTE^XLFDT(BGPBBD)," to ",?31,$$FMTE^XLFDT(BGPBED)
  1.  I BGPPBD=BGPBBD,BGPPED=BGPBED K Y D CHKY I Y K BGPBBD,BGPBED,BGPPBD,BGPPED G BY
  1. GP ;
  1.  ;general population
  1.  S BGPGPDEF="",BGPTAXI="",BGPCOMMI="",BGPBEN="" K BGPALLPT,BGPSEAT  ;GENERAL POPULATION DEFINITION
  1.  S DIR(0)="S^A:ALL Patients;O:One Community;T:A TAXONOMY of Communities;P:A Patient PANEL (Search template)",DIR("A")="Include Patients in what General Population",DIR("B")="T" KILL DA D ^DIR KILL DIR
  1.  I $D(DIRUT) G BY
  1.  S BGPGPDEF=Y,BGPGPEX=Y(0)
  1.  I BGPGPDEF="A" S BGPALLPT=1 G COMQ
  1.  I BGPGPDEF="P" D  G:BGPSEAT="" GP S BGPBEN=3 G LIST
  1.  .S BGPSEAT=""
  1.  .W !!,"Please enter the search template name.  The template will contain a",!,"panel of patients defined by the user.",!
  1.  .S DIC("S")="I $P(^(0),U,4)=2!($P(^(0),U,4)=9000001)" S DIC="^DIBT(",DIC("A")="Enter SEARCH TEMPLATE name: ",DIC(0)="AEMQ" D ^DIC K DIC,DA,DR,DICR
  1.  .I Y=-1 Q
  1.  .S BGPSEAT=+Y
  1.  K BGPTAX
  1.  S BGPTAXI="",BGPCOMMI=""
  1.  D ^XBFMK
  1.  I BGPGPDEF="O" D  G:BGPCOMMI="" GP  G:BGPCOMMI COMQ
  1.  .S DIC="^AUTTCOM(",DIC(0)="AEMQ",DIC("A")="Which Community: " D ^DIC K DIC
  1.  .I Y=-1 Q
  1.  .S BGPCOMMI=+Y
  1.  ;
  1.  S DIC("S")="I $P(^(0),U,15)=9999999.05",DIC="^ATXAX(",DIC(0)="AEMQ",DIC("A")="Enter the Name of the Community Taxonomy: "
  1.  S B=$P($G(^BGPSITE(DUZ(2),0)),U,5) I B S DIC("B")=$P(^ATXAX(B,0),U)
  1.  D ^DIC
  1.  I Y=-1 G GP
  1.  S BGPTAXI=+Y
  1. COM1 ;
  1.  S X=0
  1.  F  S X=$O(^ATXAX(BGPTAXI,21,X)) Q:'X  D
  1.  .S BGPTAX($P(^ATXAX(BGPTAXI,21,X,0),U))=""
  1.  .Q
  1.  I '$D(BGPTAX) W !!,"There are no communities in that taxonomy." G GP
  1.  S X=0,G=0
  1.  F  S X=$O(^ATXAX(BGPTAXI,21,X)) Q:'X  D
  1.  .S C=$P(^ATXAX(BGPTAXI,21,X,0),U)
  1.  .I '$D(^AUTTCOM("B",C)) W !!,"***  Warning: Community ",C," is in the taxonomy but was not",!,"found in the standard community table." S G=1
  1.  .Q
  1.  I G D  I BGPQUIT D XIT Q
  1.  .W !!,"These communities may have been renamed or there may be patients"
  1.  .W !,"who have been reassigned from this community to a new community and this"
  1.  .W !,"could reduce your patient population."
  1.  .S BGPQUIT=0
  1.  .S DIR(0)="Y",DIR("A")="Do you want to cancel the report and review the communities" KILL DA D ^DIR KILL DIR
  1.  .I $D(DIRUT) S BGPQUIT=1
  1.  .I Y S BGPQUIT=1
  1.  .Q
  1. COMQ K BGPQUIT
  1.  ;
  1.  ;
  1. LIST ;
  1.  D LISTS
  1. BEN ;
  1.  I $G(BGPSEAT) G SUM
  1.  S BGPBEN=""
  1.  S DIR(0)="S^1:Indian/Alaskan Native (Classification 01);2:Not Indian Alaskan/Native (Not Classification 01);3:All (both Indian/Alaskan Natives and Non 01)",DIR("A")="Select Beneficiary Population to include in this report"
  1.  S DIR("B")="1" KILL DA D ^DIR KILL DIR
  1.  I $D(DIRUT) G GP
  1.  S BGPBEN=Y
  1. SUM ;display summary of this report
  1.  W:$D(IOF) @IOF
  1.  W !,$$CTR("SUMMARY OF IHS 2018 IPC MEASURES REPORT TO BE GENERATED")
  1.  W !!,"The date ranges for this report are:"
  1.  W !?5,"Report Period: ",?31,$$FMTE^XLFDT(BGPBD)," to ",?31,$$FMTE^XLFDT(BGPED)
  1.  W !?5,"Previous Year Period: ",?31,$$FMTE^XLFDT(BGPPBD)," to ",?31,$$FMTE^XLFDT(BGPPED)
  1.  W !?5,"Baseline Period: ",?31,$$FMTE^XLFDT(BGPBBD)," to ",?31,$$FMTE^XLFDT(BGPBED)
  1.  W !!?5,"General Population: ",BGPGPEX
  1.  I BGPGPDEF="T" W !!,"The COMMUNITY Taxonomy to be used is: ",$P(^ATXAX(BGPTAXI,0),U)
  1.  I BGPGPDEF="O" W !!,"The COMMUNITY is ",$P(^AUTTCOM(BGPCOMMI,0),U,1)
  1.  I BGPGPDEF="P" W !!,"The Patient Panel is ",$P(^DIBT(BGPSEAT,0),U,1)
  1.  D TEXT^BGP8DSL
  1.  I $D(DIRUT) G GP
  1.  D PT^BGP8DSL
  1.  I BGPROT="" G GP
  1. ZIS ;call to XBDBQUE
  1.  D REPORT^BGP8UTL
  1.  I $G(BGPQUIT) D XIT Q
  1.  I BGPRPT="" D XIT Q
  1.  K IOP,%ZIS I BGPROT="D",BGPDELT="F" D NODEV,XIT Q
  1.  K IOP,%ZIS W !! S %ZIS=$S(BGPDELT'="S":"PQM",1:"PM") D ^%ZIS
  1.  I POP W !,"Report Aborted" S DA=BGPRPT,DIK="^BGPGPDCR(" D ^DIK K DIK D XIT Q
  1.  I POP W !,"Report Aborted" S DA=BGPRPT,DIK="^BGPGPDPR(" D ^DIK K DIK D XIT Q
  1.  I POP W !,"Report Aborted" S DA=BGPRPT,DIK="^BGPGPDBR(" D ^DIK K DIK D XIT Q
  1.  I $D(IO("Q")) G TSKMN
  1. DRIVER ;
  1.  D ^BGP8PC1
  1.  U IO
  1.  D ^BGP8DP
  1.  D ^%ZISC
  1.  D XIT
  1.  Q
  1.  ;
  1. CNT() ;
  1.  NEW X,C
  1.  S X=0,C=0 F  S X=$O(^BGPINDR("AIPC",X)) Q:X'=+X  S C=C+1
  1.  Q C
  1. NODEV ;
  1.  S XBRP="",XBRC="NODEV1^BGP8PCD",XBRX="XIT^BGP8PCD",XBNS="BGP"
  1.  D ^XBDBQUE
  1.  Q
  1.  ;
  1. NODEV1 ;
  1.  D ^BGP8PC1
  1.  D ^BGP8DP
  1.  D ^%ZISC
  1.  D XIT
  1.  Q
  1. TSKMN ;EP ENTRY POINT FROM TASKMAN
  1.  S ZTIO=$S($D(ION):ION,1:IO) I $D(IOST)#2,IOST]"" S ZTIO=ZTIO_";"_IOST
  1.  I $G(IO("DOC"))]"" S ZTIO=ZTIO_";"_$G(IO("DOC"))
  1.  I $D(IOM)#2,IOM S ZTIO=ZTIO_";"_IOM I $D(IOSL)#2,IOSL S ZTIO=ZTIO_";"_IOSL
  1.  K ZTSAVE S ZTSAVE("BGP*")=""
  1.  S ZTCPU=$G(IOCPU),ZTRTN="DRIVER^BGP8PCD",ZTDTH="",ZTDESC="IPC REPORT" D ^%ZTLOAD D XIT Q
  1.  Q
  1.  ;
  1. XIT ;
  1.  D ^%ZISC
  1.  D EN^XBVK("BGP") I $D(ZTQUEUED) S ZTREQ="@"
  1.  K DIRUT,DUOUT,DIR,DOD
  1.  K DIADD,DLAYGO
  1.  D KILL^AUPNPAT
  1.  K X,X1,X2,X3,X4,X5,X6
  1.  K A,B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,V,W,X,Y,Z
  1.  K N,N1,N2,N3,N4,N5,N6
  1.  K BD,ED
  1.  D KILL^AUPNPAT
  1.  D ^XBFMK
  1.  Q
  1.  ;
  1. CTR(X,Y) ;EP - Center X in a field Y wide.
  1.  Q $J("",$S($D(Y):Y,1:IOM)-$L(X)\2)_X
  1.  ;----------
  1. EOP ;EP - End of page.
  1.  Q:$E(IOST)'="C"
  1.  Q:$D(ZTQUEUED)!'(IOT="TRM")!$D(IO("S"))
  1.  NEW DIR
  1.  K DIR,DIRUT,DFOUT,DLOUT,DTOUT,DUOUT
  1.  S DIR(0)="E" D ^DIR KILL DIR
  1.  Q
  1.  ;----------
  1. USR() ;EP - Return name of current user from ^VA(200.
  1.  Q $S($G(DUZ):$S($D(^VA(200,DUZ,0)):$P(^(0),U),1:"UNKNOWN"),1:"DUZ UNDEFINED OR 0")
  1.  ;----------
  1. LOC() ;EP - Return location name from file 4 based on DUZ(2).
  1.  Q $S($G(DUZ(2)):$S($D(^DIC(4,DUZ(2),0)):$P(^(0),U),1:"UNKNOWN"),1:"DUZ(2) UNDEFINED OR 0")
  1.  ;----------
  1.  ;
  1. LISTS ;any lists with measures?
  1.  K BGPLIST
  1.  W !!,"PATIENT LISTS"
  1.  I '$D(^XUSEC("BGPZ PATIENT LISTS",DUZ)) W !!,"You do not have the security access to print patient lists.",!,"Please see your supervisor or program manager if you feel you should have",!,"the BGPZ PATIENT LISTS security key.",! D  Q
  1.  .K DIR S DIR(0)="E",DIR("A")="Press enter to continue" D ^DIR K DIR
  1.  S DIR(0)="Y",DIR("A")="Do you want patient lists for any of the measures",DIR("B")="N" KILL DA D ^DIR KILL DIR
  1.  I $D(DIRUT)!(Y="") Q
  1.  I Y=0 Q
  1.  K BGPLIST
  1.  D EN^BGP8PCSL
  1.  I '$D(BGPLIST) W !!,"No lists selected.",!
  1.  I $D(BGPLIST) D RT^BGP8PCSL I '$D(BGPLIST)!($D(BGPQUIT)) G LISTS ;get report type for each list
  1.  Q
  1. CHKY ;
  1.  W !!,"The baseline year and the previous year time periods are the same.",!!
  1.  S DIR(0)="Y",DIR("A")="Do you want to change the baseline year",DIR("B")="N" KILL DA D ^DIR KILL DIR
  1.  I $D(DIRUT) S Y="" Q
  1.  Q
  1. F ;fiscal year
  1.  S (BGPPER,BGPVDT)=""
  1.  W !!,"Enter the Calendar Year for the report END date.  Use a 4 digit",!,"year, e.g. 2018"
  1.  S DIR(0)="D^::EP"
  1.  S DIR("A")="Enter Year"
  1.  S DIR("?")="This report is compiled for a period.  Enter a valid date."
  1.  D ^DIR KILL DIR
  1.  I $D(DIRUT) Q
  1.  I $D(DUOUT) S DIRUT=1 Q
  1.  S BGPVDT=Y
  1.  I $E(Y,4,7)'="0000" W !!,"Please enter a year only!",! G F
  1.  S BGPPER=BGPVDT
  1.  Q
  1. ENDDATE ;
  1.  W !!,"When entering dates, if you do not enter a full 4 digit year (e.g. 2018)"
  1.  W !,"will assume a year in the past, if you want to put in a future date,"
  1.  W !,"remember to enter the full 4 digit year.  For example, if today is"
  1.  W !,"January 4, 2010 and you type in 6/30/05 the system will assume the year"
  1.  W !,"as 1905 since that is a date in the past.  You must type 6/30/2010 if you"
  1.  W !,"want a date in the future."
  1.  S (BGPPER,BGPVDT)=""
  1.  W ! K DIR,X,Y S DIR(0)="D^::EP",DIR("A")="Enter End Date for the Report: (e.g. 11/30/2005)" D ^DIR K DIR S:$D(DUOUT) DIRUT=1
  1.  I $D(DIRUT) Q
  1.  S (BGPPER,BGPVDT)=Y
  1.  Q