Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BIREPD

BIREPD.m

Go to the documentation of this file. 
  1. BIREPD ;IHS/CMI/MWR - REPORT, ADOLESCENT RATES; MAY 10, 2010
  1.  ;;8.5;IMMUNIZATION;;SEP 01,2011
  1.  ;;* MICHAEL REMILLARD, DDS * CIMARRON MEDICAL INFORMATICS, FOR IHS *
  1.  ;;  VIEW ADOLESCENT IMMUNIZATION RATES REPORT.
  1.  ;
  1.  ;
  1.  ;----------
  1. START ;EP
  1.  ;---> Listman Screen for Adolescent Immunization Rates.
  1.  D SETVARS^BIUTL5 N BIRTN
  1.  ;
  1.  ;---> If Vaccine Table is not standard, display Error Text and quit.
  1.  I $D(^BISITE(-1)) D ERRCD^BIUTL2(503,,1) Q
  1.  ;
  1.  D EN
  1.  D EXIT
  1.  Q
  1.  ;
  1.  ;
  1.  ;----------
  1. EN ;EP
  1.  ;---> Main entry point for BI REPORT ADOLESCENT RATES.
  1.  D EN^VALM("BI REPORT ADOLESCENT RATES")
  1.  Q
  1.  ;
  1.  ;
  1.  ;----------
  1. INIT ;EP
  1.  ;---> Initialize variables and list array.
  1.  K ^TMP("BIREPD",$J)
  1.  S VALM("TITLE")=$$LMVER^BILOGO
  1.  S VALMSG="Select a left column number to change an item."
  1.  N BILINE,X S BILINE=0
  1.  D WRITE(.BILINE)
  1.  S X=IOUON_"ADOLESCENT IMMUNIZATION RATES REPORT"
  1.  D CENTERT^BIUTL5(.X,42)
  1.  D WRITE(.BILINE,X_IOINORM)
  1.  K X
  1.  ;
  1.  ;---> Date.
  1.  D WRITE(.BILINE)
  1.  S:'$G(BIQDT) BIQDT=$G(DT)
  1.  D DATE^BIREP(.BILINE,"BIREPD",1,$G(BIQDT),"Quarter Ending Date",,,,1)
  1.  ;
  1.  ;---> Current Community.
  1.  D DISP^BIREP(.BILINE,"BIREPD",.BICC,"Community",2,1)
  1.  ;
  1.  ;---> Health Care Facility.
  1.  N A,B S A="Health Care Facility",B="Facilities"
  1.  D DISP^BIREP(.BILINE,"BIREPD",.BIHCF,A,3,2,,,,B) K A,B
  1.  ;
  1.  ;---> Case Manager.
  1.  D DISP^BIREP(.BILINE,"BIREPD",.BICM,"Case Manager",4,3)
  1.  ;
  1.  ;---> Beneficiary Type.
  1.  S:$O(BIBEN(0))="" BIBEN(1)=""
  1.  D DISP^BIREP(.BILINE,"BIREPD",.BIBEN,"Beneficiary Type",5,4)
  1.  ;
  1.  ;---> User Population.
  1.  D:($G(BIUP)="")
  1.  .I $$GPRAIEN^BIUTL6 S BIUP="a" Q
  1.  .S BIUP="u"
  1.  ;
  1.  S X="     6 - Patient Population Group...: "
  1.  D
  1.  .I BIUP="r" S X=X_"Registered Patients (All)" Q
  1.  .I BIUP="i" S X=X_"Immunization Register Patients (Active)" Q
  1.  .I BIUP="u" S X=X_"User Population (1 visit, 3 yrs)" Q
  1.  .I BIUP="a" S X=X_"Active Users (2+ visits, 3 yrs)" Q
  1.  D WRITE(.BILINE,X,1)
  1.  K X
  1.  ;
  1.  ;---> Finish up Listmanager List Count.
  1.  S VALMCNT=BILINE
  1.  S BIRTN="BIREPD"
  1.  Q
  1.  ;
  1.  ;
  1.  ;----------
  1. WRITE(BILINE,BIVAL,BIBLNK) ;EP
  1.  ;---> Write lines to ^TMP (see documentation in ^BIW).
  1.  ;---> Parameters:
  1.  ;     1 - BILINE (ret) Last line# written.
  1.  ;     2 - BIVAL  (opt) Value/text of line (Null=blank line).
  1.  ;     3 - BIBLNK (opt) Number of blank lines to add after line sent.
  1.  ;
  1.  Q:'$D(BILINE)
  1.  D WL^BIW(.BILINE,"BIREPD",$G(BIVAL),$G(BIBLNK))
  1.  Q
  1.  ;
  1.  ;
  1.  ;----------
  1. RESET ;EP
  1.  ;---> Update partition for return to Listmanager.
  1.  I $D(VALMQUIT) S VALMBCK="Q" Q
  1.  D TERM^VALM0 S VALMBCK="R"
  1.  D INIT Q
  1.  ;
  1.  ;
  1.  ;----------
  1. HELP ;EP
  1.  ;---> Help code.
  1.  N BIX S BIX=X
  1.  D FULL^VALM1
  1.  W !!?5,"Enter ""V"" to view this report on screen, ""P"" to print it,"
  1.  W !?5,"or ""H"" to view the Help Text for this report and its parameters."
  1.  D DIRZ^BIUTL3("","     Press ENTER/RETURN to continue")
  1.  D:BIX'="??" RE^VALM4
  1.  Q
  1.  ;
  1.  ;
  1.  ;----------
  1. HELP1 ;EP
  1.  ;----> Explanation of this report.
  1.  N BITEXT D TEXT1(.BITEXT)
  1.  D START^BIHELP("ADOLESCENT IMM RATES - HELP",.BITEXT)
  1.  Q
  1.  ;
  1.  ;
  1.  ;----------
  1. TEXT1(BITEXT) ;EP  vvv83
  1.  ;;
  1.  ;;Adolescent Report
  1.  ;;
  1.  ;;The Adolescent report follows the logic of the National
  1.  ;;Immunization Survey to provide immunization coverage rates for
  1.  ;;single vaccines and groups of vaccines in children  11-12 years,
  1.  ;;13 years and 13-17 years of age by certain key ages  (i.e.
  1.  ;;3 Hep B and 2 MMR and 1-Td/Tdap, 3-HepB, 2-MMR,1-Var) by the
  1.  ;;the date of the report.  Current status is defined as 1-Tdap_Td
  1.  ;;and 1-Mening.
  1.  ;;
  1.  ;;This report displays Active clinical users who are between 11
  1.  ;;years 0 months and 17 years 11 months of age on the selected date
  1.  ;;of the report.  (An Active clinical user is defined as a person
  1.  ;;who has had at least two clinical visits in the past three years.)
  1.  ;;
  1.  ;;The key ages by which vaccines were received are listed across
  1.  ;;the top of the report.  Total patients who received each dose
  1.  ;;of the vaccines  for each age-group are listed in rows beside
  1.  ;;each dose (e.g., the total patients (%) receiving 3-HepB by
  1.  ;;11-12 years.  The date header on far left header signifies
  1.  ;;"doses received by the report date" and includes all doses a
  1.  ;;child received up to the "Quarter Ending Date" chosen.
  1.  ;;All percentages represent a fraction of the total patients as
  1.  ;;noted at the top and bottom of the report.
  1.  ;;
  1.  ;;The ADOLESCENT IMMUNIZATIONS RATES screen allows you to adjust
  1.  ;;the report to your needs.
  1.  ;;
  1.  ;;There are 6 items or "parameters" on the screen that you may
  1.  ;;change in order to select for a specific group of patients.
  1.  ;;To change an item, enter its left column number (1-6) at the
  1.  ;;prompt on the bottom of the screen.  Use "?" at any prompt where
  1.  ;;you would like help or more information on the parameter you are
  1.  ;;changing.
  1.  ;;
  1.  ;;Once you have the parameters set to retrieve the group of patients
  1.  ;;you want, select V to View the Adolescent Report or P to print it.
  1.  ;;
  1.  ;;If it customarily takes a long time for your computer to prepare
  1.  ;;this report, it may be preferable to Print and Queue the report
  1.  ;;to a printer, rather than Viewing it on screen.  (This would avoid
  1.  ;;tying up your screen while the report is being prepared.)
  1.  ;;
  1.  ;;QUARTER ENDING DATE: The report will compile immunization rates
  1.  ;;as of the date entered.  Typically, this date would be the end
  1.  ;;of a Quarter.
  1.  ;;
  1.  ;;COMMUNITY: If you select for specific Communities, only patients
  1.  ;;whose Current Community matches one of the Communities selected will
  1.  ;;be included in the report.  "Current Community" is refers to Item 6
  1.  ;;on Page 1 of the RPMS Patient Registration.
  1.  ;;
  1.  ;;HEALTH CARE FACILITY: If you select for specific Health Care
  1.  ;;Facilities, only Patients who have active Chart#'s at one or more
  1.  ;;of the selected Facilities will be included in the report.
  1.  ;;
  1.  ;;CASE MANAGER: If you select for specific Case Managers, only
  1.  ;;patients who have the selected Case Managers will be included
  1.  ;;in the report.
  1.  ;;
  1.  ;;BENEFICIARY TYPE: If you select for specific Beneficiary Types,
  1.  ;;only patients whose Beneficiary Type is one of those you select
  1.  ;;will be included in the report.  "Beneficiary Type" refers to
  1.  ;;Item 3 on Page 2 of the RPMS Patient Registration.
  1.  ;;
  1.  ;;PATIENT POPULATION GROUP: You may select one of four patient groups
  1.  ;;to be considered in the report: Registered Patients (All),
  1.  ;;Immunization Register Patients (Active), User Population (1+ visits
  1.  ;;in 3 yrs), or Active Clinical Users (2+ visits in 3 yrs).
  1.  ;;Active Clinical Users is the default.
  1.  ;;
  1.  ;;
  1.  D LOADTX("TEXT1",,.BITEXT)
  1.  Q
  1.  ;
  1.  ;
  1.  ;----------
  1. LOADTX(BILINL,BITAB,BITEXT) ;EP
  1.  Q:$G(BILINL)=""
  1.  N I,T,X S T="" S:'$D(BITAB) BITAB=5 F I=1:1:BITAB S T=T_" "
  1.  F I=1:1 S X=$T(@BILINL+I) Q:X'[";;"  S BITEXT(I)=T_$P(X,";;",2)
  1.  Q
  1.  ;
  1.  ;
  1.  ;----------
  1. EXIT ;EP
  1.  ;---> EOJ cleanup.
  1.  D KILLALL^BIUTL8(1)
  1.  K ^TMP("BIREPD",$J)
  1.  D CLEAR^VALM1
  1.  D FULL^VALM1
  1.  Q