Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BIREPL

BIREPL.m

Go to the documentation of this file. 
  1. BIREPL ;IHS/CMI/MWR - REPORT, ADULT IMM; MAY 10, 2010
  1.  ;;8.5;IMMUNIZATION;;SEP 01,2011
  1.  ;;* MICHAEL REMILLARD, DDS * CIMARRON MEDICAL INFORMATICS, FOR IHS *
  1.  ;;  VIEW ADULT IMMUNIZATION REPORT: PARAMETERS VIEW MENU
  1.  ;
  1.  ;
  1.  ;----------
  1. START ;EP
  1.  ;---> Listman Screen for printing Immunization Due Letters.
  1.  D SETVARS^BIUTL5 N BIRTN
  1.  ;
  1.  ;---> If Vaccine Table is not standard, display Error Text and quit.
  1.  I $D(^BISITE(-1)) D ERRCD^BIUTL2(503,,1) Q
  1.  ;
  1.  D EN
  1.  D EXIT
  1.  Q
  1.  ;
  1.  ;
  1.  ;----------
  1. EN ;EP
  1.  ;---> Main entry point for BI LETTER PRINT DU
  1.  D EN^VALM("BI REPORT ADULT IMM")
  1.  Q
  1.  ;
  1.  ;
  1.  ;----------
  1. INIT ;EP
  1.  ;---> Initialize variables and list array.
  1.  S VALM("TITLE")=$$LMVER^BILOGO
  1.  S VALMSG="Select a left column number to change an item."
  1.  N BILINE,X S BILINE=0
  1.  D WRITE(.BILINE)
  1.  S X=IOUON_"ADULT IMMUNIZATION REPORT" D CENTERT^BIUTL5(.X,42)
  1.  D WRITE(.BILINE,X_IOINORM)
  1.  K X
  1.  ;
  1.  ;---> Date.
  1.  D WRITE(.BILINE)
  1.  S:'$G(BIQDT) BIQDT=$G(DT)
  1.  D DATE^BIREP(.BILINE,"BIREPL",1,BIQDT,"Quarter Ending Date",,,,1)
  1.  ;
  1.  ;---> Current Community.
  1.  D DISP^BIREP(.BILINE,"BIREPL",.BICC,"Community",2,1)
  1.  ;
  1.  ;---> Health Care Facility.
  1.  N A,B S A="Health Care Facility",B="Facilities"
  1.  D DISP^BIREP(.BILINE,"BIREPL",.BIHCF,A,3,2,,,,B) K A,B
  1.  ;
  1.  ;---> Beneficiary Type.
  1.  S:$O(BIBEN(0))="" BIBEN(1)=""   ;vvv83
  1.  D DISP^BIREP(.BILINE,"BIREPL",.BIBEN,"Beneficiary Type",4,4)
  1.  ;
  1.  ;---> Include CPT Coded Visits.
  1.  S:'$D(BICPTI) BICPTI=0
  1.  S X="     5 - Include CPT Coded Visits...: "
  1.  S X=X_$S($G(BICPTI):"YES",1:"NO")
  1.  D WRITE(.BILINE,X,1)
  1.  K X
  1.  ;
  1.  ;---> User Population.
  1.  D:($G(BIUP)="")
  1.  .I $$GPRAIEN^BIUTL6 S BIUP="a" Q
  1.  .S BIUP="u"
  1.  ;
  1.  S X="     6 - Patient Population Group...: "
  1.  D
  1.  .I BIUP="r" S X=X_"Registered Patients (All)" Q
  1.  .I BIUP="i" S X=X_"Immunization Register Patients (Active)" Q
  1.  .I BIUP="u" S X=X_"User Population (1 visit, 3 yrs)" Q
  1.  .I BIUP="a" S X=X_"Active Users (2+ visits, 3 yrs)" Q
  1.  D WRITE(.BILINE,X,1)
  1.  K X
  1.  ;
  1.  ;---> Finish up Listmanager List Count.
  1.  S VALMCNT=BILINE
  1.  S BIRTN="BIREPL"
  1.  Q
  1.  ;
  1.  ;
  1.  ;----------
  1. WRITE(BILINE,BIVAL,BIBLNK) ;EP
  1.  ;---> Write lines to ^TMP (see documentation in ^BIW).
  1.  ;---> Parameters:
  1.  ;     1 - BILINE (ret) Last line# written.
  1.  ;     2 - BIVAL  (opt) Value/text of line (Null=blank line).
  1.  ;     3 - BIBLNK (opt) Number of blank lines to add after line sent.
  1.  ;
  1.  Q:'$D(BILINE)
  1.  D WL^BIW(.BILINE,"BIREPL",$G(BIVAL),$G(BIBLNK))
  1.  Q
  1.  ;
  1.  ;
  1.  ;----------
  1. RESET ;EP
  1.  ;---> Update partition for return to Listmanager.
  1.  I $D(VALMQUIT) S VALMBCK="Q" Q
  1.  D TERM^VALM0 S VALMBCK="R"
  1.  D INIT Q
  1.  ;
  1.  ;
  1.  ;----------
  1. HELP ;EP
  1.  ;---> Help code.
  1.  N BIX S BIX=X
  1.  D FULL^VALM1
  1.  W !!?5,"Enter ""V"" to view this report on screen, ""P"" to print it,"
  1.  W !?5,"or ""H"" to view the Help Text for this report and its parameters."
  1.  D DIRZ^BIUTL3("","     Press ENTER/RETURN to continue")
  1.  D:BIX'="??" RE^VALM4
  1.  Q
  1.  ;
  1.  ;
  1.  ;----------
  1. HELP1 ;EP
  1.  ;----> Explanation of this report.
  1.  N BITEXT D TEXT1(.BITEXT)
  1.  D START^BIHELP("ADULT IMMUNIZATION REPORT - HELP",.BITEXT)
  1.  Q
  1.  ;
  1.  ;
  1.  ;----------
  1. TEXT1(BITEXT) ;EP
  1.  ;;
  1.  ;;This report will provide statistics on Adult Immunizations.
  1.  ;;The population of patients reviewed are those 19 years and older.
  1.  ;;
  1.  ;;Criteria:
  1.  ;;Tetanus:  The patient must have had a tetanus immunization documented
  1.  ;;in the past 10 years.  This includes any of the following CVX Codes:
  1.  ;;1, 9, 20, 22, 28, 50, 106, 107, 110, 113, 115.
  1.  ;;If parameter 5 "Include CPT Coded Visits" is set to "yes", then any
  1.  ;;of the following codes will count: 90701,90718,90700,90720,90702,
  1.  ;;90703,90721,90723.
  1.  ;;
  1.  ;;Pneumovax:  Adults 65 years and older must have had a pneumococcal
  1.  ;;immunization documented at or after age 65 years.  This includes any
  1.  ;;of the following CVX Codes: 33, 100, 109.
  1.  ;;
  1.  ;;When VIEWING the report on-screen, you will be able to view the
  1.  ;;lists of patients who were "Current" or "Not Current."
  1.  ;;In this context, the list of "Current" adults includes those who
  1.  ;;are current for Td/Tdap (within the last 10 years) and for pneumo
  1.  ;;vaccines on the date of the report.
  1.  ;;
  1.  ;;The IMMUNIZATION ADULT REPORT screen allows you to adjust the
  1.  ;;report to your needs.
  1.  ;;
  1.  ;;There are 6 items or "parameters" on the screen that you may
  1.  ;;change in order to select for a specific group of patients.
  1.  ;;To change an item, enter its left column number (1-6) at the
  1.  ;;prompt on the bottom of the screen.  Use "?" at any prompt where
  1.  ;;you would like more information on the parameter you are changing.
  1.  ;;
  1.  ;;Once you have the parameters set to retrieve the group of patients
  1.  ;;you want, select V to View the Adult Report or P to print it.
  1.  ;;
  1.  ;;If it customarily takes a long time for your computer to prepare
  1.  ;;this report, it may be preferable to Print and Queue the report
  1.  ;;to a printer, rather than Viewing it on screen.  (This would avoid
  1.  ;;tying up your screen while the report is being prepared.)
  1.  ;;
  1.  ;;QUARTER ENDING DATE: The report will compile immunization rates
  1.  ;;as of the date entered.  Typically, this date would be the end
  1.  ;;of a Quarter.
  1.  ;;
  1.  ;;COMMUNITIES: If you select for specific Communities, only patients
  1.  ;;whose Current Community matches one of the Communities selected will
  1.  ;;be included in the report.  "Current Community" is refers to Item 6
  1.  ;;on Page 1 of the RPMS Patient Registration.
  1.  ;;NOTE: You may want to select the GPRA set of Communities, in order
  1.  ;;to more closely match the GPRA report produced by the CRS module
  1.  ;;(RPMS Clinical Reporting System).
  1.  ;;
  1.  ;;HEALTH CARE FACILITIES: If you select for specific Health Care
  1.  ;;Facilities, only Patients who have active Chart#'s at one or more
  1.  ;;of the selected Facilities will be included in the report.
  1.  ;;
  1.  ;;BENEFICIARY TYPES: If you select for specific Beneficiary Types,
  1.  ;;only patients whose Beneficiary Type is one of those you select
  1.  ;;will be included in the report.  "Beneficiary Type" refers to
  1.  ;;Item 3 on Page 2 of the RPMS Patient Registration.
  1.  ;;
  1.  ;;INCLUDE CPT CODED VISITS: If you answer "YES" to this question
  1.  ;;the report will search for any immunizations that were only entered
  1.  ;;as CPT Codes, and it will include those immunizations in the
  1.  ;;statistical results of this report.
  1.  ;;
  1.  ;;PATIENT POPULATION GROUP: You may select one of four patient groups
  1.  ;;to be considered in the report: Registered Patients (All),
  1.  ;;Immunization Register Patients (Active), User Population (1+ visits
  1.  ;;in 3 yrs), or Active Clinical Users (2+ visits in 3 yrs).
  1.  ;;Active Clinical Users is the default.
  1.  ;;
  1.  ;;
  1.  D LOADTX("TEXT1",,.BITEXT)
  1.  Q
  1.  ;
  1.  ;
  1.  ;----------
  1. LOADTX(BILINL,BITAB,BITEXT) ;EP
  1.  Q:$G(BILINL)=""
  1.  N I,T,X S T="" S:'$D(BITAB) BITAB=5 F I=1:1:BITAB S T=T_" "
  1.  F I=1:1 S X=$T(@BILINL+I) Q:X'[";;"  S BITEXT(I)=T_$P(X,";;",2)
  1.  Q
  1.  ;
  1.  ;
  1.  ;----------
  1. EXIT ;EP
  1.  ;---> End of job cleanup.
  1.  D KILLALL^BIUTL8(1)
  1.  K ^TMP("BIREPL",$J)
  1.  D CLEAR^VALM1
  1.  D FULL^VALM1
  1.  Q