Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BIVISIT

BIVISIT.m

Go to the documentation of this file. 
  1. BIVISIT ;IHS/CMI/MWR - ADD/EDIT IMM/SKIN VISITS.; MAY 10, 2010
  1.  ;;8.5;IMMUNIZATION;**10**;MAY 30,2015
  1.  ;;* MICHAEL REMILLARD, DDS * CIMARRON MEDICAL INFORMATICS, FOR IHS *
  1.  ;;  CODE TO ADD V IMMUNIZATION AND V SKIN TEST VISITS.  CALLED BY BIRPC3.
  1.  ;;  PATCH 5: Added BINOM parameter to ADDEDIT P.E.P. for Visit Selection Menu. ADDV+0
  1.  ;;           Added Admin Note, piece 27.  PARSE+36,+66, ADDV+16, VFILE+13,+184
  1.  ;;  PATCH 9: Added save of Admin Date and VIS Presented Date.  VFILE+200
  1.  ;;           If >19yrs on date of immunization and Elig="", set Elig-V01.  VFILE+188
  1.  ;;  PATCH 10: Added save of Skin Test Lot Number.  VFILE+143
  1.  ;
  1.  ;
  1.  ;----------
  1. PARSE(Y,Z) ;EP
  1.  ;---> Parse out passed Visit and V File data into local variables.
  1.  ;---> Parameters:
  1.  ;     1 - Y (req) String of data for the Visit to be added.
  1.  ;     2 - Z (opt) If Z=1 do NOT set BIVSIT (call from VFILE below must
  1.  ;                 preserve new Visit IEN sent to it).
  1.  ;
  1.  ;---> Pieces of Y delimited by "|":
  1.  ;     -----------------------------
  1.  ;     1 - BIVTYPE (req) "I"=Immunization Visit, "S"=Skin Text Visit.
  1.  ;     2 - BIDFN   (req) DFN of patient.
  1.  ;     3 - BIPTR   (req) Vaccine or Skin Test .01 pointer.
  1.  ;     4 - BIDOSE  (opt) Dose# number for this Immunization.
  1.  ;     5 - BILOT   (opt) Lot Number IEN for this Immunization.
  1.  ;     6 - BIDATE  (req) Date.Time of Visit.
  1.  ;     7 - BILOC   (req) Location of encounter IEN.
  1.  ;     8 - BIOLOC  (opt) Other Location of encounter.
  1.  ;     9 - BICAT   (req) Category: A (Ambul), I (Inpat), E (Event/Hist)
  1.  ;    10 - BIVSIT  (opt) Visit IEN.
  1.  ;    11 - BIOIEN  (opt) Old V File IEN (for edits).
  1.  ;    12 - BIRES   (req) Skin Test Result: P,N,D,O.
  1.  ;    13 - BIREA   (req) Skin Test Reading: 0-40.
  1.  ;    14 - BIDTR   (req) Skin Test Date Read.
  1.  ;    15 - BIREC   (opt) Vaccine Reaction.
  1.  ;    16 - BIVFC   (opt) VFC Eligibility.  vvv83
  1.  ;    17 - BIVISD  (opt) Release/Revision Date of VIS (YYYMMDD).
  1.  ;    18 - BIPROV  (opt) IEN of Provider of Immunization/Skin Test.
  1.  ;    19 - BIOVRD  (opt) Dose Override.
  1.  ;    20 - BIINJS  (opt) Injection Site.
  1.  ;    21 - BIVOL   (opt) Volume.
  1.  ;    22 - BIREDR  (opt) IEN of Reader of Skin Test.
  1.  ;    23 - BISITE  (opt) Passed DUZ(2) for Site Parameters.
  1.  ;    24 - BICCPT  (opt) If created from CPT ^DD BICCPT=1 or IEN; otherwise=""
  1.  ;                       (called from BIRPC6
  1.  ;    25 - BIMPRT  (opt) If =1 it was imported.
  1.  ;    26 - BINDC   (opt) NDC Code IEN pointer to file #9002084.95.
  1.  ;    27 - BIANOT  (opt) Administrative Note (<161 chars).
  1.  ;
  1.  ;********** PATCH 9, v8.5, OCT 01,2014, IHS/CMI/MWR
  1.  ;---> Add Admin Date and VIS Presented Date to data being saved.
  1.  ;    28 - BIADMIN (opt) Admin Date (Date shot admin'd to patient.
  1.  ;    29 - BIVPRES (opt) Date VIS Presented to Patient.
  1.  ;
  1.  ;********** PATCH 10, v8.5, MAY 30,2015, IHS/CMI/MWR
  1.  ;    30 - BILOTSK (opt) Skin Test Lot Number.
  1.  ;
  1.  N V S V="|"
  1.  ;
  1.  S BIVTYPE=$P(Y,V,1)
  1.  S BIDFN=$P(Y,V,2)
  1.  S BIPTR=$P(Y,V,3)
  1.  S BIDOSE=$P(Y,V,4)
  1.  S BILOT=$P(Y,V,5)
  1.  S BIDATE=$P(Y,V,6) S:$P(BIDATE,".",2)="" BIDATE=BIDATE_".12"
  1.  S BILOC=$P(Y,V,7)
  1.  S BIOLOC=$P(Y,V,8)
  1.  S BICAT=$P(Y,V,9)
  1.  S:'$G(Z) BIVSIT=$P(Y,V,10)
  1.  S BIOIEN=$P(Y,V,11)
  1.  S BIRES=$P(Y,V,12)
  1.  S BIREA=$P(Y,V,13)
  1.  S BIDTR=$P(Y,V,14) S:BIDTR<1 BIDTR=""
  1.  S BIREC=$P(Y,V,15)
  1.  S BIVFC=$P(Y,V,16)
  1.  S BIVISD=$P(Y,V,17)
  1.  S BIPROV=$P(Y,V,18)
  1.  S BIOVRD=$P(Y,V,19)
  1.  S BIINJS=$P(Y,V,20)
  1.  S BIVOL=$P(Y,V,21)
  1.  S BIREDR=$P(Y,V,22)
  1.  S BISITE=$P(Y,V,23)
  1.  S BICCPT=$P(Y,V,24)
  1.  S BIMPRT=$P(Y,V,25)
  1.  S BINDC=$P(Y,V,26)
  1.  S BIANOT=$P(Y,V,27)
  1.  S BIADMIN=$P(Y,V,28)
  1.  S BIVPRES=$P(Y,V,29)
  1.  S BILOTSK=$P(Y,V,30)
  1.  ;**********
  1.  Q
  1.  ;
  1.  ;
  1.  ;********** PATCH 5, v8.5, JUL 01,2013, IHS/CMI/MWR
  1.  ;---> Added BINOM parameter to control Visit Menu display.
  1.  ;----------
  1. ADDV(BIERR,BIDATA,BIOIEN,BINOM) ;EP
  1.  ;---> Add a Visit (if necessary) and V FILE entry for this patient.
  1.  ;---> Called exclusively by ^BIRPC3.
  1.  ;---> Parameters:
  1.  ;     1 - BIERR  (ret) 1^Text of Error Code if any, otherwise null.
  1.  ;     2 - BIDATA (req) String of data for the Visit to be added.
  1.  ;                      See BIDATA definition at linelabel PARSE (above).
  1.  ;     3 - BIOIEN (opt) IEN of V IMM or V SKIN being edited (if
  1.  ;                      not new).
  1.  ;     4 - BINOM  (opt) 0=Allow display of Visit Selection Menu if site
  1.  ;                       parameter is set. 1=No display (for export).
  1.  ;
  1.  I BIDATA="" D ERRCD^BIUTL2(437,.BIERR) S BIERR="1^"_BIERR Q
  1.  ;
  1.  N BIVTYPE,BIDFN,BIPTR,BIDOSE,BILOT,BIDATE,BILOC,BIOLOC,BICAT,BIVSIT
  1.  N BIOIEN,BIRES,BIREA,BIDTR,BIREC,BIVISD,BIPROV,BIOVRD,BIINJS,BIVOL
  1.  N BIREDR,BISITE,BICCPT,BIMPRT,BIANOT,BILOTSK
  1.  ;
  1.  ;---> See BIDATA definition at linelabel PARSE.
  1.  D PARSE(BIDATA)
  1.  ;
  1.  N APCDALVR,APCDANE,AUPNTALK,BITEST,DLAYGO,X
  1.  S BIERR=0
  1.  ;
  1.  ;---> Set BITEST=1 To display VISIT and V IMM pointers after sets.
  1.  ;---> NOTE: This will write directly to IO.  Should be turned OFF
  1.  ;---> (BITEST=0) when not testing in M Programmer mode.
  1.  S BITEST=0
  1.  ;
  1.  ;---> If this is an edit, check or set BIVSIT=IEN of Parent Visit.
  1.  D:$G(BIOIEN)
  1.  .I (BIVTYPE'="I"&(BIVTYPE'="S")) D  Q
  1.  ..D ERRCD^BIUTL2(410,.BIERR) S BIERR="1^"_BIERR
  1.  .;
  1.  .;---> Quit if valid Visit IEN passed.
  1.  .Q:$G(^AUPNVSIT(+$G(BIVSIT),0))
  1.  .;
  1.  .;---> Get Visit IEN from V File entry (and set in BIDATA).
  1.  .N BIGBL S BIGBL=$S(BIVTYPE="I":"^AUPNVIMM(",1:"^AUPNVSK(")
  1.  .S BIGBL=BIGBL_BIOIEN_",0)"
  1.  .;---> Get IEN of VISIT.
  1.  .S BIVSIT=$P($G(@BIGBL),U,3)
  1.  Q:BIERR
  1.  ;
  1.  ;---> Create or edit Visit if necessary.
  1.  ;---> NOTE: BIVSIT, even if sent, might come backed changed (due to
  1.  ;---> change in Date, Category, etc.)
  1.  ;********** PATCH 5, v8.5, JUL 01,2013, IHS/CMI/MWR
  1.  ;---> Added BINOM parameter to control Visit Menu display.
  1.  S:($G(BINOM)="") BINOM=0
  1.  D VISIT^BIVISIT1(BIDFN,BIDATE,BICAT,BILOC,BIOLOC,BISITE,.BIVSIT,.BIERR,BINOM)
  1.  ;**********
  1.  Q:BIERR
  1.  ;
  1.  ;---> Create V FILE entry.
  1.  D VFILE($G(BIVSIT),BIDATA,.BIERR)
  1.  Q:BIERR
  1.  ;
  1.  ;---> If this was a mod to an existing Visit, update VISIT Field .13.
  1.  D:($G(BIOIEN)&($G(BIVSIT)))
  1.  .N AUPNVSIT,DA,DIE,DLAYGO
  1.  .S AUPNVSIT=BIVSIT,DLAYGO=9000010
  1.  .D MOD^AUPNVSIT
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1.  ;----------
  1. VFILE(BIVSIT,BIDATA,BIERR) ;EP
  1.  ;---> Add (create) V IMMUNIZATION or V SKIN TEST entry for this Visit.
  1.  ;---> Parameters:
  1.  ;     1 - BIVSIT (req) IEN of Parent Visit.
  1.  ;     2 - BIDATA (req) String of data for the Visit to be added.
  1.  ;                      See BIDATA definition at linelabel PARSE.
  1.  ;     3 - BIERR  (ret) Text of Error Code if any, otherwise null.
  1.  ;
  1.  ;
  1.  I BIDATA="" D ERRCD^BIUTL2(437,.BIERR) S BIERR="1^"_BIERR Q
  1.  ;
  1.  N BIVTYPE,BIDFN,BIPTR,BIDOSE,BILOT,BIDATE,BILOC,BIOLOC,BICAT
  1.  N BIOIEN,BIRES,BIREA,BIDTR,BIREC,BIVISD,BIPROV,BIOVRD,BIINJS,BIVOL
  1.  N BIREDR,BISITE,BICCPT,BIMPRT,BIANOT,BILOTSK
  1.  ;
  1.  ;---> See BIDATA definition at linelabel PARSE (above).
  1.  D PARSE(BIDATA,1)
  1.  ;
  1.  ;---> Fields in V IMMUNIZATION File are as follows:
  1.  ;
  1.  ;       .01 APCDTIMM  Pointer to IMMUNIZATION File (Vaccine)
  1.  ;       .02 APCDPAT   Patient
  1.  ;       .03 APCDVSIT  IEN of Visit
  1.  ;       .04 APCDTSER  Dose# (Series#)
  1.  ;       .05 APCDTLOT  Lot# IEN, Pointer to IMMUNIZATION LOT File
  1.  ;       .06 APCDTREC  Reaction
  1.  ;
  1.  ;       This will no longer be used:
  1.  ;       .07 APCDTCON  Contraindication (Stored in ^BIP.)
  1.  ;
  1.  ;       .12 APCDTVSD  VIS Date (Lori will put in a future template.)
  1.  ;      1204 APCDTEPR  Immunization Provider
  1.  ;
  1.  ;---> Fields in V SKIN TEST File are as follows:
  1.  ;
  1.  ;       .01 APCDTSK   Pointer to IMMUNIZATION File
  1.  ;       .02 APCDPAT   Patient
  1.  ;       .03 APCDVSIT  IEN of Visit
  1.  ;       .04 APCDTRES  Result
  1.  ;       .05 APCDTREA  Reading
  1.  ;       .06 APCDTDR   Date read
  1.  ;      1204 APCDTEPR  Skin Test Provider
  1.  ;
  1.  ;---> Check that a Parent VISIT exists.
  1.  I '$D(^AUPNVSIT(+$G(BIVSIT),0)) D  Q
  1.  .D ERRCD^BIUTL2(432,.BIERR) S BIERR="1^"_BIERR
  1.  ;
  1.  N APCDALVR
  1.  ;
  1.  ;---> Set Visit pointer.
  1.  S APCDALVR("APCDVSIT")=BIVSIT
  1.  ;
  1.  ;---> Set Patient.
  1.  S APCDALVR("APCDPAT")=BIDFN
  1.  ;
  1.  ;
  1.  ;
  1.  ;---> * * * If this is an IMMUNIZATION, set APCD array for Immunizations. * * *
  1.  ;
  1.  I BIVTYPE="I" D
  1.  .;
  1.  .;---> Set permission override for this file.
  1.  .S DLAYGO=9000010.11
  1.  .;
  1.  .;---> Immunization/vaccine name.
  1.  .S APCDALVR("APCDTIMM")="`"_BIPTR
  1.  .;
  1.  .;---> Dose# for this immunization.
  1.  .;S:'$G(BIDOSE) BIDOSE=""
  1.  .;S APCDALVR("APCDTSER")=BIDOSE
  1.  .;
  1.  .;---> Lot Number IEN for this immunization.
  1.  .S:'$G(BILOT) BILOT=""
  1.  .;---> Lot Number passed to PCC more reliably if prepend "`".
  1.  .;---> Imm v8.5: Handle Lot Number below
  1.  .;S:BILOT BILOT="`"_BILOT
  1.  .;S APCDALVR("APCDTLOT")=BILOT
  1.  .;
  1.  .;---> Reaction to this vaccine on this Visit.
  1.  .S:'$G(BIREC) BIREC=""
  1.  .S APCDALVR("APCDTREC")=BIREC
  1.  .;
  1.  .;---> Immunization Provider ("Shot giver").
  1.  .S:$G(BIPROV) APCDALVR("APCDTEPR")="`"_BIPROV
  1.  .;
  1.  .;---> User who last edited this Immunization.
  1.  .S:$G(DUZ) APCDALVR("APCDTULU")="`"_DUZ
  1.  .;
  1.  .;---> Template to add encounter to V IMMUNIZATION File.
  1.  .S APCDALVR("APCDATMP")="[APCDALVR 9000010.11 (ADD)]"
  1.  ;
  1.  ;
  1.  ;
  1.  ;---> * * * If this is a SKIN TEST, set APCD array for Skin Tests.  * * *
  1.  ;
  1.  I BIVTYPE="S" D
  1.  .;
  1.  .;---> Set permission override for this file.
  1.  .S DLAYGO=9000010.12
  1.  .;
  1.  .;---> Skin Test name.
  1.  .S APCDALVR("APCDTSK")="`"_BIPTR
  1.  .;
  1.  .;---> Skin Test Result.
  1.  .S APCDALVR("APCDTRES")=BIRES
  1.  .;
  1.  .;---> Skin Test Reading (mm).
  1.  .S APCDALVR("APCDTREA")=BIREA
  1.  .;
  1.  .;---> Skin Test Date Read.
  1.  .S APCDALVR("APCDTDR")=BIDTR
  1.  .;
  1.  .;---> Skin Test Provider (Person who administered the test).
  1.  .S:$G(BIPROV) APCDALVR("APCDTEPR")="`"_BIPROV
  1.  .;
  1.  .;---> Template to add encounter to V SKIN TEST File.
  1.  .S APCDALVR("APCDATMP")="[APCDALVR 9000010.12 (ADD)]"
  1.  ;
  1.  ;
  1.  ;---> * * *  CALL TO APCDALVR.  * * *
  1.  D EN^APCDALVR
  1.  D:$G(BITEST) DISPLAY2^BIPCC
  1.  ;
  1.  ;---> Quit if a V File entry was not created.
  1.  I '$G(APCDALVR("APCDADFN"))!($D(APCDALVR("APCDAFLG"))) D  Q
  1.  .I BIVTYPE="I" D ERRCD^BIUTL2(402,.BIERR) S BIERR="1^"_BIERR Q
  1.  .I BIVTYPE="S" D ERRCD^BIUTL2(413,.BIERR) S BIERR="1^"_BIERR
  1.  ;
  1.  ;Returns:  APCDADFN - IEN of V IMMUNIZATION File entry.
  1.  ;          APCDAFLG - =2 If FAILED to create a V FILE entry.
  1.  ;
  1.  ;
  1.  ;---> Save IEN of V IMMUNIZATION just created.
  1.  N BIADFN S BIADFN=APCDALVR("APCDADFN")
  1.  ;
  1.  ;
  1.  ;---> ADD OTHER V SKIN TEST FIELDS:
  1.  ;---> If this is a Skin Test, add Skin Test Reader and Quit.
  1.  I BIVTYPE="S" D  Q
  1.  .;---> Store Additional data.
  1.  .N BIFLD
  1.  .S BIFLD(.08)=BIREDR,BIFLD(.09)=BIINJS,BIFLD(.11)=BIVOL
  1.  .;
  1.  .;********** PATCH 10, v8.5, MAY 30,2015, IHS/CMI
  1.  .;---> BILOTSK (opt) Skin Test Lot Number.
  1.  .S BIFLD(.14)=BILOTSK
  1.  .;
  1.  .;---> Set DATE/TIME LAST MODIFIED, per Lori Butcher, 5/26/12
  1.  .S:$G(BIOIEN) BIFLD(1218)=$$NOW^XLFDT
  1.  .;
  1.  .D FDIE^BIFMAN(9000010.12,BIADFN,.BIFLD,.BIERR)
  1.  .I BIERR=1 D ERRCD^BIUTL2(421,.BIERR) S BIERR="1^"_BIERR
  1.  .;
  1.  .;---> If Skin Test is a PPD and result is Positive, add Contraindication
  1.  .;---> to further TST-PPD tests.
  1.  .I $$SKNAME^BIUTL6($G(BIPTR))="PPD",$E($G(BIRES))="P" D
  1.  ..;---> Set date equal to either Date Read, or Date of Visit, or Today.
  1.  ..N BIDTC S BIDTC=$S($G(BIDTR):BIDTR,$G(BIDATE):$P(BIDATE,"."),1:$G(DT))
  1.  ..S BIDATA=BIDFN_"|"_203_"|"_17_"|"_BIDTC
  1.  ..D ADDCONT^BIRPC4(,BIDATA)
  1.  ;
  1.  ;
  1.  ;---> ADD OTHER V IMMUNIZATION FIELDS:
  1.  ;---> Quit if this is not an Immunization.
  1.  Q:BIVTYPE'="I"
  1.  ;
  1.  ;---> Add VIS, Dose Override, Injection Site and Volume data.
  1.  ;---> Build DR string.
  1.  ;
  1.  S:(BIVISD<1) BIVISD="@" S:BIOVRD="" BIOVRD="@"
  1.  ;
  1.  S:BIINJS="" BIINJS="@" S:BIVOL="" BIVOL="@"
  1.  S:BILOT="" BIILOT="@" S:BINDC="" BINDC="@"
  1.  ;
  1.  ;---> Store Additional data.
  1.  N BIFLD
  1.  S BIFLD(.05)=BILOT
  1.  S BIFLD(.08)=BIOVRD,BIFLD(.09)=BIINJS
  1.  S BIFLD(.11)=BIVOL,BIFLD(.12)=BIVISD,BIFLD(.13)=BICCPT
  1.  ;
  1.  ;********** PATCH 9, v8.5, OCT 01,2014, IHS/CMI/MWR
  1.  ;---> If patient is 19yrs or older at the time of the immunization,
  1.  ;---> and Eligibility is null, set Eligibility=V01.
  1.  D
  1.  .Q:(BIVFC]"")
  1.  .N BIAGDT S BIAGDT=$S($G(BIADMIN):BIADMIN,1:BIDATE)
  1.  .I $$AGE^BIUTL1(BIDFN,1,BIAGDT)>18 S BIVFC=$O(^BIELIG("B","V01",0))
  1.  ;**********
  1.  ;
  1.  S BIFLD(.14)=BIVFC
  1.  S BIFLD(.15)=$S(BIMPRT>0:2,1:"")
  1.  S BIFLD(.16)=BINDC
  1.  ;********** PATCH 5, v8.5, JUL 01,2013, IHS/CMI/MWR
  1.  ;---> Added Admin Note, piece 27.
  1.  S:($G(BIANOT)]"") BIFLD(1)=BIANOT
  1.  ;**********
  1.  ;
  1.  ;********** PATCH 3, v8.5, SEP 10,2012, IHS/CMI/MWR
  1.  ;---> Set DATE/TIME LAST MODIFIED, per Lori Butcher, 5/26/12
  1.  S:$G(BIOIEN) BIFLD(1218)=$$NOW^XLFDT
  1.  ;**********
  1.  ;
  1.  ;********** PATCH 9, v8.5, OCT 01,2014, IHS/CMI/MWR
  1.  ;---> Add Admin Date and VIS Presented Date to data being saved.
  1.  ;    28 - BIADMIN  Admin Date (Date shot admin'd to patient.
  1.  ;    29 - BIVPRES  Date VIS Presented to Patient.
  1.  ;
  1.  S BIFLD(1201)=BIADMIN
  1.  S BIFLD(.17)=BIVPRES
  1.  ;**********
  1.  ;
  1.  D FDIE^BIFMAN(9000010.11,BIADFN,.BIFLD,.BIERR)
  1.  I BIERR=1 D  Q
  1.  .D ERRCD^BIUTL2(421,.BIERR) S BIERR="1^"_BIERR
  1.  ;
  1.  ;
  1.  ;---> If there was an anaphylactic reaction to this vaccine,
  1.  ;---> add it as a contraindication for this patient.
  1.  D:BIREC=9
  1.  .Q:'$G(BIDFN)  Q:'$G(BIPTR)  Q:'$G(BIDATE)
  1.  .N BIREAS S BIREAS=$O(^BICONT("B","Anaphylaxis",0))
  1.  .Q:'BIREAS
  1.  .;
  1.  .N BIADD,N,V S N=0,BIADD=1,V="|"
  1.  .;---> Loop through patient's existing contraindications.
  1.  .F  S N=$O(^BIPC("B",BIDFN,N)) Q:'N  Q:'BIADD  D
  1.  ..N X S X=$G(^BIPC(N,0))
  1.  ..Q:'X
  1.  ..;---> Quit (BIADD=0) if this contra/reason/date already exists.
  1.  ..I $P(X,U,2)=BIPTR&($P(X,U,3)=BIREAS)&($P(X,U,4)=BIDATE) S BIADD=0
  1.  .Q:'BIADD
  1.  .;
  1.  .D ADDCONT^BIRPC4(.BIERR,BIDFN_V_BIPTR_V_BIREAS_V_BIDATE)
  1.  .I $G(BIERR)]"" S BIERR="1^"_BIERR
  1.  ;
  1.  ;---> Now trigger New Immunization Trigger Event.
  1.  D TRIGADD
  1.  Q
  1.  ;
  1.  ;
  1.  ;----------
  1. TRIGADD ;EP
  1.  ;---> Immunization Added Trigger Event call to Protocol File.
  1.  D TRIGADD^BIVISIT2
  1.  Q
  1.  ;
  1.  ;
  1.  ;----------
  1. VFILE1 ;EP
  1.  ;---> Add (create) V IMMUNIZATION from ^DD of V CPT.
  1.  ;---> Called from EN^XBNEW, from CPTIMM^BIRPC6
  1.  ;---> Local Variables:
  1.  ;     1 - BIVSIT (req) IEN of Parent Visit.
  1.  ;     2 - BIDATA (req) String of data for the Visit to be added.
  1.  ;                      See BIDATA definition at linelabel PARSE.
  1.  ;
  1.  Q:'$G(BIVSIT)  Q:'$D(BIDATA)
  1.  D VFILE(BIVSIT,BIDATA)
  1.  Q
  1.  ;
  1.  ;
  1.  ;----------
  1. IMPORT(APCDALVR) ;PEP - Code to flag V Imm as "Imported."
  1.  ;---> Code for Tom Love to flag entry as Imported From Outside Registry.
  1.  ;---> Parameters:
  1.  ;     1 - APCDALVR (req) Array returned from call to EN^APCDALVR.
  1.  ;                   APCDALVR("APCDADFN") - IEN of V IMMUNIZATION File entry.
  1.  ;                   APCDALVR("APCDAFLG") - =2 If FAILED to create a V FILE entry.
  1.  ;
  1.  Q:($G(APCDALVR("APCDAFLG")))
  1.  Q:('$G(APCDALVR("APCDADFN")))
  1.  N BIADFN S BIADFN=APCDALVR("APCDADFN")
  1.  ;
  1.  ;---> Add Import From Outside.
  1.  N BIFLD S BIFLD(.15)=1
  1.  D FDIE^BIFMAN(9000010.11,BIADFN,.BIFLD,.BIERR)
  1.  Q