Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BMXADOV

BMXADOV.m

Go to the documentation of this file. 
  1. BMXADOV ; CIHA/CIHA/GIS - RPC CALL: GENERATE DATA FOR AN ADO DATASET 
  1.  ;;4.0;BMX;;JUN 28, 2010
  1.  ; 
  1.  ; 
  1.  ; 
  1.  ; VSTG = VIEW STRING: SCHEMA NAME OR IEN~DAS~INDEX~START~STOP~MAX~FORMAT~TAG~ROUTINE~PARAM~JOIN
  1.  ;  SCHEMA NAME/IEN: FROM THE BMX ADO SCHEMA FILE
  1.  ;  DAS: THE DA STRING.  HIGHEST LEVEL IS FIRST, FOLLOWED BY SUBFILE IENS.  CAN BE CONVERTED TO AN 'IENS' STRING.
  1.  ;   IF THE LAST ',' PIECE OF DAS IS DEFINED, THAT IS USED AS THE CURRENT STARTING SEED POINT FOR THE ITERATOR
  1.  ;   THE NEXT INDEX VALUE AFTER THE SEED POINT WILL BE THE FIRST ENTRY SELECTED FOR THE CURRENT TRANSACTION
  1.  ;  INDEX: THE INDEX THAT RUNS THE ITERATOR. IF NULL, THE ITERATOR WULL CYCLE BY IEN
  1.  ;  START: STARTING LOOKUP VALUE IN THE OVERALL ITERATION (THE FIRST VALUE THAT CAN BE USED IN SPECIFIED INDEX)
  1.  ;  STOP: THE LAST LOOKUP VALUE IN THE OVERALL ITERATION (THE LAST VALUE USED IN SPECIFIED INDEX)
  1.  ;   START AND STOP MUST BE IN THE FORMAT (INTERNAL OR EXTERNAL) USED BY THE INDEX
  1.  ;   IF THE INDEX IS ON A POINTER FIELD, AND POINTED TO FILED IS DINUMNED, THEN THE EXTERNAL VALUE CAN BE USED
  1.  ;  MAX: MAXIMUM NUMBER OF ENTRIES REURNED IN THE TRANSACTION
  1.  ;  FORMAT: RETURN INTERNAL OR EXTERNAL VALUES IN THE DATASET
  1.  ;  TAG AND ROUTINE: ENTRY POINT FOR CUSTOM/COMPLEX ITERATION
  1.  ;  PARAM: PARAMETER STRING PASSED TO THE ITERATOR ENTRY POINT.
  1.  ;   ALSO USED WITH THE AA INDEX TO DEFINE PATIENT DFN, V FILE ATTRIBUTE TYPE AND SORT ORDER (C OR R)
  1.  ;   E.G., 1|WT|R COULD BE PATIENT #1, MEASUREMENT TYPE="WEIGHT" AND REVERSE CHRONOLICAL PRESENTATION OF DATA 
  1.  ;  JOIN: JOIN INSTRUCTIONS; E.G., ...~2,4,.04|2,5,.07|4,9,SUB"
  1.  ; 
  1.  ; 
  1. VIEW(OUT,VSTG,TOT) ; EP-VIEW A DATA SET ; GATEWAY TO ALL ITERATORS
  1.  ;
  1.  ; DON'T CALL THIS EP UNLESS YOU WANT DATA RETURNED WITH THE SCHEMA!
  1.  ; INPUT: VSTG AND THE TOTAL NUMBER OF NODES IN THE SCHEMA ARRAY
  1.  ; OUTPUT: THE DATA NODES AND THE SEED (SEED IS STUFFED INTO 3RD PIECE OF INTRODUCTORY NODE OF SCHEMA ARRAY)
  1.  ; RETURNS THE ADO DATASET IN THE ARRAY SPECIFIED BY 'OUT'
  1.  ; THE SEED IS ALWAYS RETURNED IN 'LDA' REGARDLESS OF WHAT ITERATOR IS USED
  1.  ; IF ITERATION IS COMPLETED THE SEED WILL HAVE A NULL VALUE
  1.  ;
  1.  ;
  1.  ;
  1.  N DAS,DA,IX,START,STOP,MAX,FMT,EP,IENS,OREF,CREF,FIEN,TAG,ROUTINE,X,Y,%,PARAM,NUM,FINFO,LIEN,LDA,LFILE,%DT,T
  1.  S SIEN=+$G(VSTG) I SIEN,'$D(^BMXADO(SIEN,0)) S ERR="Invalid schema IEN" D ERR^BMXADO(ERR) Q
  1.  I $G(TOT)<2 S ERR="Missing schema string" D ERR^BMXADO(ERR) Q  ; MUST HAVE A VALID SCHEMA STRING FOR EACH TRANSACTION
  1. INIT ; INITIALIZE VARIABLES
  1.  S T="~"
  1.  S FIEN=$P(^BMXADO(SIEN,0),U,2) I '$D(^DD(FIEN,0)) S ERR="Invalid file number in schema file" D ERR^BMXADO(ERR) Q
  1.  S DAS=$P(VSTG,T,2),IX=$P(VSTG,T,3)
  1.  S START=$P(VSTG,T,4),STOP=$P(VSTG,T,5),MAX=$P(VSTG,T,6)
  1.  I $L(START),$L(STOP),START,START=+START,STOP,STOP=+STOP
  1.  S %=$T ; NUMERIC START AND STOP
  1.  I %,START>STOP S ERR="Invalid start stop pair" D ERR^BMXADO(ERR) Q
  1.  I '%,$L(START),$L(STOP),START]STOP S ERR="Invalid start stop pair" D ERR^BMXADO(ERR) Q
  1.  I $L(MAX),(MAX'>0!(MAX'=MAX\1)) S ERR="Invalid MAX parameter" D ERR^BMXADO(ERR) Q
  1.  S FMT=$P(VSTG,T,7),TAG=$P(VSTG,T,8),ROUTINE=$P(VSTG,T,9),PARAM=$P(VSTG,T,10),NUM=0
  1.  I $L(TAG),'$L(ROUTINE) S ERR="Invalid EP info" D ERR^BMXADO(ERR) Q
  1.  S EP=TAG_U_ROUTINE I EP=U S EP=""
  1.  I $L(EP) X ("S %=$L($T("_EP_"))") I '% S ERR="Invalid EP info" D ERR^BMXADO(ERR) Q
  1.  I FMT='"I" S FMT=""
  1.  I MAX="" S MAX=100
  1.  I $G(JOIN) S MAX=999999999 ; MAX IS UNLIMITED FOR SECONDARY DATA SETS DURING JOINS
  1.  S IENS=$$IENS(DAS) ; CONVERT DA STRING TO IEN STRING ; DAS AND IENS MUST BE AVAILABLE TO ALL ITERATORS
  1.  S OREF=$$ROOT^DILFD(FIEN,IENS) I '$L(OREF) S ERR="Unable to generate a vaild open reference" D ERR^BMXADO(ERR) Q
  1.  S CREF=$$CREF^DILF(OREF) I '$L(CREF) S ERR="Unable to generate a vaild closed reference" D ERR^BMXADO(ERR) Q
  1. DATA ; GET DATA
  1. SPEC I $L(EP) D  Q  ; SPECIAL CASE: USE CUSTOM ITERATOR
  1.  . I '$G(LDA) S LDA=""
  1.  . X ("S LDA=$$"_EP_"(PARAM,IENS,MAX,.OUT,.TOT)")
  1.  . D SEED(LDA)
  1.  . Q
  1.  I IX="" S LDA=$$NUMIT^BMXADOV1(+$G(DA)) D SEED(LDA) Q  ; NO INDEX USED: ITERATE IN IEN ORDER
  1.  I IX="AA",FIEN=9000013!(FIEN=9000019) S IX="AC" ; 'AA' ITERATION UNNECESSARY FOR SOME FILES. BETTER TO USE 'AC'
  1.  I '$L($O(@CREF@(IX,""))) Q  ; NO INDEXED DATA AVAILABLE, SO QUIT NOW
  1.  I IX="AA" D  Q  ; SPECIAL CASE:  AA INDEX
  1.  . I FIEN=9000011 S LDA=$$AAP^BMXADOV1 Q  ; THE AA INDEX FOR 'PROBLEMS'; LDA ALWAYS NULL
  1.  . S LDA=$$AA^BMXADOV1 D SEED(LDA) ; THE VISIT/V-FILE AA INDEX
  1.  . Q
  1.  S FINFO=$$IXFLD(FIEN,IX) I FINFO="" Q  ; FILE INFO: IX FIELD NUMBER, TYPE, AND DINUM SUBTYPE
  1.  I $P(FINFO,U,2)="D" D  ; PREP FOR DATE INDEX LOOKUP
  1.  . I $L(START) S X=START D ^%DT S START=+Y
  1.  . I $L(STOP) S X=STOP D ^%DT S STOP=+Y
  1.  . Q
  1.  I $P(FINFO,U,2)="P",$E(START)="`" D  Q  ; SPECIAL CASE: SHORTCUT TO POINTER LOOKUP FOR A SINGLE, SPECIFIC IEN.
  1.  . S LIEN=+$E(START,2,99)
  1.  . S LDA=$$LOOK^BMXADOV1(LIEN)
  1.  . D SEED(LDA)
  1.  . Q
  1.  I $P(FINFO,U,4) S LFILE=$P(FINFO,U,3) I LFILE D  Q  ; SPECIAL CASE: DINUM -> TEXT LOOKUP.
  1.  . S LDA=$$LOOK2^BMXADOV1(LFILE)
  1.  . D SEED(LDA)
  1.  . Q
  1.  S LDA=$$LOOK1^BMXADOV1 ; STD INDEX LOOKUP: START FROM SCRATCH
  1.  D SEED(LDA) ; CAPTURE RE-ENTRY SEED
  1.  Q
  1.  ; 
  1. SEED(LDA) ; UPDATE THE SCHEMA STRING WITH THE SEED PARAMETER
  1.  N X,Y
  1.  S X=@OUT@(1)
  1.  S Y=$P(X,U)
  1.  S $P(Y,"|",3)=LDA
  1.  S $P(X,U,1)=Y
  1.  S @OUT@(1)=X
  1.  Q
  1.  ;
  1. IENS(DAS) ;EP - CONVERT DAS STRING TO IENS STRING
  1.  N I,L,IENS
  1.  S DAS=$G(DAS)
  1.  S DAS=$TR(DAS,"+","")
  1.  S DAS=$TR(DAS,"-","")
  1.  I '$L(DAS) Q ","
  1.  I DAS="," S DAS=""
  1.  S L=$L(DAS,C)
  1.  S IENS=""
  1.  F I=L:-1:1 S IENS=IENS_$P(DAS,C,I)_C
  1.  Q IENS
  1.  ;
  1. IXFLD(FIEN,IX) ;EP - GIVEN AN FILE NUMMER AND INDEX NAME, RETURIN THE FIELD NUMBER, TYPE, AND DINUM SUBTYPE
  1.  N FLD,TYPES,T,X,I
  1.  I '$G(FIEN) Q ""
  1.  I '$L($G(IX)) Q ""
  1.  S FLD=$O(^DD(FIEN,0,"IX",IX,FIEN,0))
  1.  I 'FLD Q FLD
  1.  S TYPES="DNSFWCPVM",T=$P($G(^DD(FIEN,FLD,0)),U,2)
  1.  F I=1:1 S X=$E(TYPES,I) Q:'$L(X)  I T[X Q
  1.  I X="P" S X=X_U_+$P(T,"P",2) I $P(^DD(FIEN,FLD,0),U,5)["DINUM" S X=X_U_1
  1.  S FLD=FLD_U_X
  1.  Q FLD
  1.  ;