Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BMXADOX1

BMXADOX1.m

Go to the documentation of this file. 
  1. BMXADOX1 ; IHS/CIHA/GIS - RPC CALL: GENERATE AN ADO SCHEMA STRING AND DATA SET ;
  1.  ;;2.0;BMX;;FEB 26, 2007
  1.  ; EXMAPLES OF FILEMAN SCHEMA GENERATION
  1.  ;
  1.  ;
  1.  ; N OUT,DAX,% S DAX=0 D SS^BMXADO(.OUT,1,DAX,"^^^5^I^^^^3,XSUB,2160010.03") D DISP(OUT) Q  ; TEST EXTENDED SUBJOIN
  1.  ;
  1. DISP(OUT) ;
  1.  D DISP^BMXADOX(OUT)
  1.  Q
  1.  ;
  1. SCHEMA(NAME) ; GIVEN SCHEMA NAME, RETURN THE IEN
  1.  N IEN
  1.  S IEN=$O(^BMXADO("B",NAME,0))
  1.  Q IEN
  1.  ;
  1. NUM ; ITERATE BY IEN
  1.  ; IX="",START WITH IEN=1, STOP AFTER IEN=20, MAX # RECORDS RETURNED = 5
  1.  ; TO VIEW INTERNAL VALUES SET VSTG="~1~20~5~I"
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("IHS PATIENT")
  1.  D SS^BMXADO(.OUT,SIEN,"","~1~20~5")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. IX ; ITERATE BY INDEX
  1.  ; ITERATE USING THE "B" INDEX
  1.  ; START WITH PT NAME "C", STOP AFTER PATIENT NAME = "D", MAX # RECORDS RETURNED = 5
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("IHS PATIENT")
  1.  D SS^BMXADO(.OUT,SIEN,"","B~C~D~5")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. VCN ; SHOW VALUES FOR A SINGLE VISIT THAT AS A DEFINED VCN
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("BMXADO DATA ENTRY IDENTIFIERS")
  1.  D SS^BMXADO(.OUT,SIEN,"","VCN~1.242A~1.242A~")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. MT ; MEASUREMNT TYPES
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("BMXADO MEASUREMENT TYPES")
  1.  D SS^BMXADO(.OUT,SIEN,"","B~~")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. PROB ; PATIENT PROBLEMS
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("BMXADO PROBLEMS")
  1.  D SS^BMXADO(.OUT,SIEN,"","AA~53~53")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. PB1 ; ALT PROB RETRIEVAL TEST
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("BMXADO PROBLEMS")
  1.  D SS^BMXADO(.OUT,SIEN,"","~221~221~")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ; 
  1. POV ; RETURN THE POV SCHEMA
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("BMXADO ADD POV")
  1.  D SS^BMXADO(.OUT,SIEN,"","")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. NOTES ; RETURN NOTES FOR A SPECIFIC PATIENT PROBLEMS
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("BMXADO NOTES")
  1.  D SS^BMXADO(.OUT,SIEN,"","~~~~~NOTES~BMXADOFD~53")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. RENT ; ITERATE IN CHUNKS
  1.  ; RE-ITERATE USING THE "B" INDEX
  1.  ; START WITH PT IEN 5 AS THE "SEED", STOP AFTER PATIENT NAME = "D", MAX # RECORDS RETURNED = 5
  1.  N OUT,%,SIEN,SEED,LSEED,X,Y
  1.  S SEED=0,LSEED=""
  1.  S SIEN=$$SCHEMA("IHS PATIENT")
  1. RIT F  D  I '$G(SEED) Q
  1.  . ; D SS^BMXADO(.OUT,SIEN,SEED,"B~CA~CB~5")
  1.  . D SS^BMXADO(.OUT,SIEN,SEED,"~~~5")
  1.  . D DISP(OUT) R %:$G(DTIME,60) E  S SEED="" Q
  1.  . I %?1"^" S SEED="" Q
  1.  . S X=$P(@OUT@(1),U,1)
  1.  . S SEED=$P(X,"|",3)
  1.  . I SEED=LSEED S SEED="" Q
  1.  . S LSEED=SEED
  1.  . K ^TMP("BMX ADO",$J)
  1.  . Q
  1.  Q
  1.  ;
  1. SUB ; SUBFILE ITERATION
  1.  ; THE SCHEMA IS ATTACHED TO THE MEDICARE ELIGIBILITY FILE/ELIG DATE SUBFILE
  1.  ; THE DA STRING HAS A VALUE OF '1,',: THE IEN IN THE PARENT FILE.
  1.  ; NOTE THE COMMA IN THE DA STRING.  THIS INDICATES THAT THE FILE IEN IS 1 BUT THE SUBFILE IEN IS UNSPECIFIED 
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("UPDATE MEDICARE DATES")
  1.  D SS^BMXADO(.OUT,SIEN,"1,","~~~")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. DINUM ; DINUMED POINTER ITERATION
  1.  ; THE SCHEMA IS ATTACHED TO THE IHS PATIENT FILE (9000001)
  1.  ; THE IHS PATIENT FILE IS DINUM'D AND ITS .01 FIELD POINTS TO THE VA PATIENT FILE (2)
  1.  ; BECAUSE OF THE SPECIAL RELATIONSHIP BETWEEN THE FILES, WE CAN USE THE B INDEX OF FILE 2 TO ITERATE FILE 9000001.
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("IHS PATIENT")
  1.  D SS^BMXADO(.OUT,SIEN,"","B~A~B~5")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. IXP ; INDEXED POINTER ITERATION
  1.  ; THE SCHEMA IS ATTACHED TO THE V POV FILE
  1.  ; THE AC CROSS REFERENCE INDEXES THE PATIENT FIELD
  1.  ; BY STARTING AND STOPING WITH PATIENT 1 (MAX=5) WE COLLECT THE FIRST 5 POVS FOR PATIENT 1 IN THE FILE
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("VIEW POVS")
  1.  D SS^BMXADO(.OUT,SIEN,"","AC~1~1~5")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. AA ; ITERATE USING AA INDEX
  1.  ; INDEX IS 'AA"  THE START AND STOP DATES ARE SPECIFIED IN EXTERNAL FORMAT.  MAX=10
  1.  ; THE FOLLOWING FILTERS ARE SPECIFIED IN THE LAST PARAMETER ("1|WT|C"):
  1.  ;   1=PATIENT DFN #1
  1.  ;   WT=RETURN ONLY WEIGHTS. MEASUREMENT TYPE MUST BE SPECIFIED WITH A VALID, UNAMBIGUOUS LOOKUP VALUE.
  1.  ;   C=RETRUN VALUES IN CHRONOLOGICAL ORDER USE 'R' INSTEAD OF 'C' FOR REVERSE CHRONOLOGICAL ORDER. DEFAULT=C
  1.  ;   THE SEED PARAMTER IS SET AND CAN BE USED TO RETURN DATA IN CHUNKS
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("VIEW MEASUREMENTS")
  1.  D SS^BMXADO(.OUT,SIEN,"","AA~3/21/1985~6/4/1986~5~~~~1|WT|C")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. AA2 ; ITERATE USING AA INDEX
  1.  ; THIS SCHEMA IS ATTACHED TO THE VISIT FILE (9000010)
  1.  ; IN THIS CASE THERE IS NO ATTRIBUTE TYPE SO THE FILTER PARAM HAS ONLY 2 PIECES "1|R"
  1.  ;   1=PATIENT DFN
  1.  ;   R=RETURN DATA IN REVERSE CHRONOLOGICAL ORDER
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("VISITS")
  1.  D SS^BMXADO(.OUT,SIEN,"","AA~3/21/1985~6/4/1986~5~~~~1|R")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. CIT ; CUSTOM ITERATOR
  1.  ; IF COMPLEX OR UNUSUAL SORTING/FILTERING IS REQUITED, USE A CUSTOM ITERATOR
  1.  ; THE CUSTOM ITERATOR IS DEFINED BY 6TH, 7TH AND 8TH PIECES IN THE VSTG
  1.  ;   PIECE 8=TAG, PIECE 9=ROUTINE, PIECE 8=A PARAMETER PASSED TO THE ENTRY POINT
  1.  ;   THE 9TH PIECE CONTAINS PT DFN, TIMESTAMP, VISIT TYPE, LOC IEN, AND SERVICE CATEGORY IN A "|" DELIMTED STRING
  1.  ;   THE ITERATOR CALL TAG^ROUTINE(PARAM) TO GENERATE IENS
  1.  ; IN THIS CASE THE SCHEMA IS ATTACHED TO THE VISIT FILE.
  1.  ; GIVEN THE INFORMATION IN THE PARAMETER, THE CUSTOM ITERATOR RETURNS POSSIBLE DUPLICATE VISITS
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("VISITS")
  1.  D SS^BMXADO(.OUT,SIEN,"","~~~~~DUPV~BMXADOV2~1|4/19/04@1PM|I|4585|A~")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. TRIGGER ; TEXT TRIGGER FUNCTION
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("PATIENT DEMOGRAPHICS")
  1.  D SS^BMXADO(.OUT,SIEN,"","~1~5")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. ID ; IDENTIFIER FIELD
  1.  ; THE SCHEMA IS ATTACHED TO THE VA PATIENT FILE (2)
  1.  ; THE SCHEMA HAS A BUILT IN FIELD (.01ID) THAT RETURNS THE IDENTIFIERS
  1.  ; THE ENTRY POINT THAT GENERATES THE IDETIFIERS IS STORED IN THE BMX ADO SCHEMA FILE
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("UPDATE PATIENT DEMOGRAPHICS")
  1.  D SS^BMXADO(.OUT,SIEN,"","~1~1~")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. JMD ; JOIN MASTER TO DETAIL
  1.  N OUT,%,SIEN1,SIEN2,VSTG,SIEN3,JSTG
  1.  S SIEN1=$$SCHEMA("PATIENT DEMOGRAPHICS")
  1.  S SIEN2=$$SCHEMA("VIEW MEASUREMENTS")
  1.  S SIEN3=$$SCHEMA("VIEW MEDS")
  1.  S VSTG="~1~5" ; INSTRUCTIONS FOR GATHERING DATA SET FOR PTS 1-5 FROM THE MASTER FILE
  1.  S JSTG=SIEN3_",.001,.02IEN,AA~1/1/1960~6/30/2004~~~~~|C" ; + INSTRUCTIONS FOR 1ST JOIN TO GET MEDS
  1.  S JSTG=JSTG_"@JOIN@"_SIEN2_",.001,.02IEN,AA~1/1/1988~12/31/1988~~~~~|WT|R" ; + INSTRUCTIONS FOR 2ND JOIN TO GET MSRMNTS
  1.  D SS^BMXADO(.OUT,SIEN1,"",VSTG,JSTG)
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ; 
  1. JVPT ; JOIN PT DEMOG TO VISIT
  1.  N OUT,%,SIEN1,SIEN2,VSTG,JSTG
  1.  S SIEN1=$$SCHEMA("PATIENT DEMOGRAPHICS")
  1.  S SIEN2=$$SCHEMA("VISITS")
  1.  S VSTG="~1~1" ; INSTRUCTIONS FOR GATHERING DATA SET FOR PT 5 FROM THE MASTER FILE
  1.  S JSTG=SIEN2_",.05IEN,.001,AC" ; + INSTRUCTIONS FOR 1ST JOIN TO GET VISIT INFO
  1.  D SS^BMXADO(.OUT,SIEN1,"",VSTG,JSTG)
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. JAC ; TEST AC INDEX
  1.  N OUT,%,SIEN1,SIEN2
  1.  S SIEN1=$$SCHEMA("PATIENT DEMOGRAPHICS")
  1.  S SIEN2=$$SCHEMA("VIEW LABS")
  1.  S SIEN3=$$SCHEMA("VIEW MEASUREMENTS")
  1.  D SS^BMXADO(.OUT,SIEN1,"","~3~5~~~~~~"_SIEN2_",.001,.02IEN,AC@JOIN@"_SIEN3_",.001,.02IEN,AC")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ; 
  1. JPB ; TEST AA INDEX JOINS FOR PROBLEM LIST
  1.  N OUT,%,SIEN1,SIEN2
  1.  S SIEN1=$$SCHEMA("PATIENT DEMOGRAPHICS")
  1.  S SIEN2=$$SCHEMA("VIEW PROBLEMS")
  1.  D SS^BMXADO(.OUT,SIEN1,"","~1~5~~~~~~"_SIEN2_",.001,.02IEN,AA")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ; 
  1. JSUB ; SUBFILE JOIN
  1.  ; IN THIS CASE THE RECORDS IN A PARENT FILE ARE "JOINED" TO THE RECORDS IN ONE OF ITS SUB FILES
  1.  ; THE SCHEMA IS ATTACHED TO THE "MEDICARE ELIGIBLE" FILE
  1.  ; IT IS JOINED TO ITS SUBFILE, "ELIG DATES", VIA THE UPDATE MEDICARE DATES SCHEMA
  1.  N OUT,%,SIEN1,SIEN2
  1.  S SIEN1=$$SCHEMA("UPDATE MEDICARE INFO")
  1.  S SIEN2=$$SCHEMA("UPDATE MEDICARE DATES")
  1.  D SS^BMXADO(.OUT,SIEN1,"","~1~5~~~~~~"_SIEN2_",SUB")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. ADD ; ADD A NEW ENTRY
  1.  ; THIS IS A 2 STEP PROCESS:
  1.  ;   FIRST GET THE SCHEMA FOR THE FILE YOU WISH TO UPDATE
  1.  ;     THIS SCHEMA TYPICALLY BEGINS WITH THE WORD "UPDATE"
  1.  ;     IT CONTAINS NO ID IR IEN FIELDS
  1.  ;   SECOND ADD THE DATA NODE TO THE ARRAY
  1.  ;     IT HAS THE SAME FORMAT AS A DATA STRING ASSOCIATED WITH THE SCHEMA EXCEPT THE FIRST "^" PIECE IS NULL
  1.  ;     THIS PIECE CORRESPONDS TO THE IEN OF THE RECORD.  SINCE THE RECORD HASNOT BEEN ADDED YET, IT IS NULL.
  1.  ;     IN THE DATA STRING, ALL POINTER VALUES ARE PRECEDED BY THE '`' CHARACTER AND EA. STRING ENDS IN $C(30)
  1.  ;     MULTIPLE DATA STRINGS CAN BE APPENDED AS NEW NODES AT THE BOTTOM OF THE ARRAY
  1.  ;     IN THIS CASE WE ARE ADDING A RECORD TO THE V MEASUREMENT FILE
  1.  ;     DATA STRING="^MEASUREMENT TYPE IEN^PATIENT DFN^VISIT IEN^RESULT"_$C(30)
  1.  ;   THERE ARE 2 INPUT PARAMS:
  1.  ;     THE CLOSED REF WHERE THE INPUT ARRAY IS STORED
  1.  ;     SINCE IT IS PASSED BY REFERENCE "OUT" CAN BE NULL OR UNDEFIEND.
  1.  ;     OUT WILL BE DEFINED AT THE CONCLUSION OF THE TRANSACTION.
  1.  ;   THE OUTPUT IS IN THE OUT ARRAY
  1.  ;   OUT(1)="OK|ien" WHERE ien IS THE IEN OF THE RECORD THAT HAS BEE ADDED.
  1.  ;   IF THE TRANSACTION FAILED, AN ERROR MSG WILL BE IN THE OUT ARRAY
  1.  ;
  1.  N OUT,%,SIEN,NODE
  1.  S SIEN=$$SCHEMA("UPDATE MEASUREMENTS")
  1.  D SS^BMXADO(.OUT,SIEN,"","") ; GET SCHEMA
  1.  S NODE=$O(^TMP("BMX ADO",$J,999999),-1)+1
  1.  S ^TMP("BMX ADO",$J,NODE)="^`2^`1^`71164^175.75"_$C(30)
  1.  D DISP(OUT) R %:$G(DTIME,60) ; DISPLAY THE INPUT ARRAY BEFORE UPDATING THE RECORD
  1.  D BAFM^BMXADOF1(.OUT,$NA(^TMP("BMX ADO",$J))) ; EP FOR UPDAING THE RECORD
  1.  K ^TMP("BMX ADO",$J)
  1.  W !!,OUT S %=0 F  S %=$O(OUT(%)) Q:'%  W !,OUT(%) ; SEND BACK AN ACKNOWLEDGEMENT OR ERROR MSG
  1.  Q
  1.  ;
  1. DELREC ; DELETE AN ENTRY
  1.  ; THE SIMPLEST WAY TO DELETE AN ENTRY IS TO PUT THE RECORD IEN IN THE DA STRING PRECEDED BY A MINUS SIGN
  1.  ; YOU CAN ALSO SET THE VALUE OF THE .01 FIELD TO "@"
  1.  ; IF THE VALUE OF THE .01 FIELD IS NULL AND THE DA STRING IS NOT PRECEDED BY A MINUS SIGN, THE TRANSACTION WILL BE CANCELLED
  1.  ; IF THE DA STRING IS NULL, THE TRANSACTION WILL BE CANCELLED
  1.  N OUT,%,SIEN,NODE,DEL
  1.  S DEL=51385
  1.  S SIEN=$$SCHEMA("UPDATE MEASUREMENTS")
  1.  D SS^BMXADO(.OUT,SIEN,"","") ; GET SCHEMA
  1.  S NODE=$O(^TMP("BMX ADO",$J,999999),-1)+1
  1.  S ^TMP("BMX ADO",$J,NODE)="-"_DEL_$C(30)
  1.  D DISP(OUT) R %:$G(DTIME,60) ; DISPLAY THE INPUT ARRAY BEFORE UPDATING THE RECORD
  1.  D BAFM^BMXADOF1(.OUT,$NA(^TMP("BMX ADO",$J))) ; EP FOR UPDAING THE RECORD
  1.  K ^TMP("BMX ADO",$J)
  1.  W !!,OUT S %=0 F  S %=$O(OUT(%)) Q:'%  W !,OUT(%) ; SEND BACK AN ACKNOWLEDGEMENT OR ERROR MSG
  1.  Q
  1.  ;
  1. EDIT ; EDIT AN EXISTING ENTRY
  1.  ; SIMILAR TO ABOVE EXCEPT THAT THE FIRST "^" PIECE OF THE DATA NODE IS THE IEN OF THE RECORD TO BE EDITIED
  1.  ; NOTE THAT THERE IS NO '`' IN FRONT OF THE FIRST PIECE.  IT IS A PURE INTEGER
  1.  N OUT,%,SIEN,NODE
  1.  S SIEN=$$SCHEMA("UPDATE MEASUREMENTS")
  1.  D SS^BMXADO(.OUT,SIEN,"","") ; GET SCHEMA
  1.  S NODE=$O(^TMP("BMX ADO",$J,999999),-1)+1
  1.  S ^TMP("BMX ADO",$J,NODE)="51385^^^^176^`6"_$C(30)
  1.  D DISP(OUT) R %:$G(DTIME,60) ; DISPLAY THE INPUT ARRAY BEFORE UPDATING THE RECORD
  1.  D BAFM^BMXADOF1(.OUT,$NA(^TMP("BMX ADO",$J))) ; EP FOR UPDAING THE RECORD
  1.  K ^TMP("BMX ADO",$J)
  1.  W !!,OUT S %=0 F  S %=$O(OUT(%)) Q:'%  W !,OUT(%) ; SEND BACK AN ACKNOWLEDGEMENT OR ERROR MSG
  1.  Q
  1.  ;
  1. DELVAL ; DELETE A VALUE IN A FIELD
  1.  ; SIMILAR TO EDIT EXCEPT THE VALUE IS "@"
  1.  N OUT,%,SIEN,NODE
  1.  S SIEN=$$SCHEMA("UPDATE MEASUREMENTS")
  1.  D SS^BMXADO(.OUT,SIEN,"","") ; GET SCHEMA
  1.  S NODE=$O(^TMP("BMX ADO",$J,999999),-1)+1
  1.  S ^TMP("BMX ADO",$J,NODE)="51385^^^^^@"_$C(30)
  1.  D DISP(OUT) R %:$G(DTIME,60) ; DISPLAY THE INPUT ARRAY BEFORE UPDATING THE RECORD
  1.  D BAFM^BMXADOF1(.OUT,$NA(^TMP("BMX ADO",$J))) ; EP FOR UPDAING THE RECORD
  1.  K ^TMP("BMX ADO",$J)
  1.  W !!,OUT S %=0 F  S %=$O(OUT(%)) Q:'%  W !,OUT(%) ; SEND BACK AN ACKNOWLEDGEMENT OR ERROR MSG
  1.  Q