Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BQI202PS

BQI202PS.m

Go to the documentation of this file. 
  1. BQI202PS ;VNGT/HS/ALA-Version 2.0 Patch 2 Post-Install ; 11 Dec 2008  1:47 PM
  1.  ;;2.1;ICARE MANAGEMENT SYSTEM;;Feb 07, 2011
  1.  ;
  1. EN ; Entry point
  1.  ;
  1.  NEW IEN
  1.  S IEN=$O(^BQI(90507,"B","ASTHMA",""))
  1.  I IEN'="" S BQIUPD(90507,IEN_",",.01)="Asthma" D FILE^DIE("","BQIUPD","ERROR")
  1.  ;
  1.  ; Set up the new specialty providers
  1.  D DSPM^BQINIGH1
  1.  ;
  1.  ; Update default value to optional
  1.  S DIEN=$O(^BQI(90506.1,"B","PADD",""))
  1.  I DIEN'="" S $P(^BQI(90506.1,DIEN,3),U,4)="O"
  1.  ;
  1.  ; Change NEW CATEGORY value
  1.  D CAT^BQI202PU
  1.  ;
  1.  ; Inactivate Case Manager as it will now be part of the specialty providers
  1.  S DIEN=$O(^BQI(90506.1,"B","CM",""))
  1.  S $P(^BQI(90506.1,DIEN,0),U,10)=1,$P(^BQI(90506.1,DIEN,0),U,11)=DT
  1.  ;
  1.  ; Set Task to clean up old format CRS data
  1.  S ZTDESC="ICARE CRS CLEANUP",ZTRTN="CRS^BQI202PS",ZTIO=""
  1.  S JBDATE=$$FMADD^XLFDT($$NOW^XLFDT(),,,3)
  1.  S ZTDTH=JBDATE
  1.  D ^%ZTLOAD
  1.  K ZTDESC,ZTRTN,ZTIO,JBDATE,ZTDTH,ZTSK
  1.  ;
  1. ASM ; Add Allergy entries to 90506.1 and set up Allergy View
  1.  D EN^DDIOL("Updating new Allergy Care Management View items")
  1.  ; Clean up inactive flags and dates
  1.  NEW NM
  1.  S NM="AS"
  1.  F  S NM=$O(^BQI(90506.1,"B",NM)) Q:NM=""!($E(NM,1,2)'="AS")  D
  1.  . I NM["ASHMR" Q
  1.  . I NM["AST_" Q
  1.  . S IEN=$O(^BQI(90506.1,"B",NM,"")) Q:IEN=""
  1.  . S BQIUPD(90506.1,IEN_",",.1)="@"
  1.  . S BQIUPD(90506.1,IEN_",",.11)="@"
  1.  D FILE^DIE("","BQIUPD","ERROR")
  1.  ;
  1.  NEW TEXT,BQIUPD,ERROR,BI,BJ,NDATA,ND,VAL,TXT,IEN,BK
  1.  F BI=1:1 S TEXT=$P($T(VIEW+BI),";;",2) Q:TEXT=""  D  W "."
  1.  . F BJ=1:1:$L(TEXT,"~") D
  1.  .. S NDATA=$P(TEXT,"~",BJ)
  1.  .. S ND=$P(NDATA,"|",1),VAL=$P(NDATA,"|",2)
  1.  .. I ND=0 D
  1.  ... NEW DIC
  1.  ... S DIC(0)="LQZ",DIC="^BQI(90506.1,",X=$P(VAL,U,1)
  1.  ... D ^DIC
  1.  ... S IEN=+Y
  1.  ... I IEN=-1 K DO,DD D FILE^DICN S IEN=+Y
  1.  .. I ND=1 S BQIUPD(90506.1,IEN_",",1)=VAL Q
  1.  .. I ND=5 S BQIUPD(90506.1,IEN_",",5)=VAL Q
  1.  .. F BK=1:1:$L(VAL,"^") D
  1.  ... S BN=$O(^DD(90506.1,"GL",ND,BK,""))
  1.  ... I $P(VAL,"^",BK)'="" S BQIUPD(90506.1,IEN_",",BN)=$P(VAL,"^",BK)
  1.  . D FILE^DIE("","BQIUPD","ERROR")
  1.  ;
  1.  F TXT="ASCSMGR","ASDD","ASLFEF","ASLPEF","ASMGPLDT","ASSEVDT" D
  1.  . S IEN=$O(^BQI(90506.1,"B",TXT,"")) I IEN="" Q
  1.  . S BQIUPD(90506.1,IEN_",",.1)=1,BQIUPD(90506.1,IEN_",",.11)=DT
  1.  . S BQIUPD(90506.1,IEN_",",3.05)="@"
  1.  ;
  1.  S IEN=$O(^BQI(90506.5,"B","Asthma",""))
  1.  I IEN'="" S BQIUPD(90506.5,IEN_",",.04)=1
  1.  S IEN=$O(^BQI(90507,"B","Asthma",""))
  1.  I IEN'="" S BQIUPD(90507,IEN_",",.16)=1
  1.  D FILE^DIE("","BQIUPD","ERROR")
  1.  ;
  1.  ; Set tooltips
  1.  D TPS^BQI202PU
  1.  ;
  1.  S DIK="^BQI(90506.1,"
  1.  D IXALL^DIK
  1.  ;
  1.  ; Set community taxonomies
  1.  D CTX^BQI202PU
  1.  ;
  1.  ; Check to reset diagnosis code pointers
  1.  D DX^BQI202PU
  1.  ;
  1.  ;Special code to remove H1N1 Associated Community Alert from 90507.6
  1.  N CMIEN,ATIEN,DCIEN,DXCAT
  1.  S CMIEN=0 F  S CMIEN=$O(^BQI(90507.6,CMIEN)) Q:'CMIEN  D
  1.  . S ATIEN=0 F  S ATIEN=$O(^BQI(90507.6,CMIEN,1,ATIEN)) Q:'ATIEN  D
  1.  .. S DCIEN=0 F  S DCIEN=$O(^BQI(90507.6,CMIEN,1,ATIEN,1,DCIEN)) Q:'DCIEN  D
  1.  ... S DXCAT=$P($G(^BQI(90507.6,CMIEN,1,ATIEN,1,DCIEN,0)),U)
  1.  ... Q:DXCAT'["H1N1 Associated"
  1.  ... N DA,DIK
  1.  ... S DA(2)=CMIEN,DA(1)=ATIEN,DA=DCIEN
  1.  ... S DIK="^BQI(90507.6,"_DA(2)_",1,"_DA(1)_",1,"
  1.  ... D ^DIK
  1.  ;
  1.  ;Validate Panel Layout structures
  1.  D PNLFX^BQI202PU
  1.  ;
  1.  ;Set the version number
  1.  NEW DA
  1.  S DA=$O(^BQI(90508,0))
  1.  S BQIUPD(90508,DA_",",.08)="2.0.2.15"
  1.  S BQIUPD(90508,DA_",",.09)="2.0.2T15"
  1.  D FILE^DIE("","BQIUPD","ERROR")
  1.  K BQIUPD
  1.  ;
  1.  ;  Set up Asthma care management data program
  1.  S ZTDESC="ICARE ASTHMA UPDATE",ZTRTN="CMGT^BQITASK3",ZTIO=""
  1.  S JBNOW=$$NOW^XLFDT()
  1.  S JBDATE=$S($E($P(JBNOW,".",2),1,2)<20:DT,1:$$FMADD^XLFDT(DT,+1))
  1.  S ZTDTH=JBDATE_".20"
  1.  D ^%ZTLOAD
  1.  K ZTDESC,ZTRTN,ZTIO,JBNOW,JBDATE,ZTDTH,ZTSK
  1.  ;
  1.  D ^BQISCHED
  1.  ;
  1. CBP ; Update CVD Best Practice Prompts for Health Summary
  1.  NEW BQTIEN,NAME,AIEN,BQIUPD,INACT
  1.  I $O(^APCHSURV("A"),-1)'=$P(^APCHSURV(0),U,3) S $P(^APCHSURV(0),U,3)=$O(^APCHSURV("A"),-1)
  1.  S BQTIEN=0
  1. BP S BQTIEN=$O(^BQI(90508.5,BQTIEN)) Q:'BQTIEN
  1.  S NAME=$P(^BQI(90508.5,BQTIEN,0),U,1),INACT=$P(^(0),U,4)
  1.  S AIEN=$$FIND1^DIC(9001018,"","BX",NAME,"","","ERROR")
  1.  ; If it does not exist and is inactive, go to next one
  1.  I 'AIEN,INACT G BP
  1.  ; If it exists and is inactive, set it to "deleted"
  1.  I AIEN,INACT S BQIUPD(9001018,AIEN_",",.03)="D"
  1.  I 'AIEN D ADD
  1.  S BQIUPD(9001018,AIEN_",",.03)=1
  1.  S BQIUPD(9001018,AIEN_",",.07)="T"
  1.  D FILE^DIE("","BQIUPD","ERROR")
  1.  S BQIUPD(9001018,AIEN_",",.05)="CVD-RELATED"
  1.  S BQIUPD(9001018,AIEN_",",1)="APCH;BQITRPHS"
  1.  D FILE^DIE("E","BQIUPD","ERROR")
  1.  D WP^DIE(9001018,AIEN_",",2,"","^BQI(90508.5,BQTIEN,3)")
  1.  D WP^DIE(9001018,AIEN_",",1300,"","^BQI(90508.5,BQTIEN,4)")
  1.  G BP
  1.  ;
  1. ADD ;
  1.  NEW DIC,DLAYGO,X
  1.  S DIC="^APCHSURV(",DLAYGO=9001018,DIC("P")=DLAYGO,X=NAME,DIC(0)="L"
  1.  K DO,DD D FILE^DICN
  1.  S AIEN=+Y
  1.  Q
  1.  ;
  1. CM ; EP - Replace case manager layout entries with new case manager
  1.  ;        values loaded from DSPM
  1.  NEW CM,BDPCM,CMIEN,BDPIEN,DA,DIK,IENS,BQIUPD,SHRIEN
  1.  S CM=$O(^BQI(90506.1,"B","CM","")) Q:CM=""
  1.  S BDPCM=$O(^BQI(90506.1,"B","BDPCM","")) Q:BDPCM=""
  1.  ;
  1.  S OWNR=0
  1.  F  S OWNR=$O(^BQICARE(OWNR)) Q:'OWNR  D
  1.  . S PLIEN=0
  1.  . F  S PLIEN=$O(^BQICARE(OWNR,1,PLIEN)) Q:'PLIEN  D
  1.  .. S CMIEN=$O(^BQICARE(OWNR,1,PLIEN,20,"B",CM,"")) Q:CMIEN=""
  1.  .. Q:'$D(^BQICARE(OWNR,1,PLIEN,20,CMIEN,0))
  1.  .. K ERROR
  1.  .. S BDPIEN=$O(^BQICARE(OWNR,1,PLIEN,20,"B",BDPCM,""))
  1.  .. D
  1.  ... ; If both exist delete CM entry
  1.  ... I BDPIEN'="",$D(^BQICARE(OWNR,1,PLIEN,20,BDPIEN,0)) D  Q
  1.  ....  S DA(2)=OWNR,DA(1)=PLIEN,DIK="^BQICARE("_DA(2)_",1,"_DA(1)_",20,"
  1.  ....  S DA=CMIEN
  1.  ....  D ^DIK
  1.  ....  K DA,DIK
  1.  ... ;
  1.  ... ; Replace old case manager with new case manager
  1.  ... S DA(2)=OWNR,DA(1)=PLIEN,DA=CMIEN
  1.  ... S IENS=$$IENS^DILF(.DA)
  1.  ... S BQIUPD(90505.05,IENS,.01)=BDPCM
  1.  ... D FILE^DIE("","BQIUPD","ERROR")
  1.  ... K BQIUPD
  1.  .. ;
  1.  .. D PTYP(22,90505.122) ; Reminders View
  1.  .. D PTYP(25,90505.125) ; GPRA View
  1.  .. ;
  1.  .. ; Shared Users
  1.  .. S SHRIEN=0
  1.  .. F  S SHRIEN=$O(^BQICARE(OWNR,1,PLIEN,30,SHRIEN)) Q:'SHRIEN  D
  1.  ... S CMIEN=$O(^BQICARE(OWNR,1,PLIEN,30,SHRIEN,20,"B",CM,"")) Q:CMIEN=""
  1.  ... Q:'$D(^BQICARE(OWNR,1,PLIEN,30,SHRIEN,20,CMIEN,0))
  1.  ... K ERROR
  1.  ... S BDPIEN=$O(^BQICARE(OWNR,1,PLIEN,30,SHRIEN,20,"B",BDPCM,""))
  1.  ... D
  1.  .... ; If both exist delete CM entry
  1.  .... I BDPIEN'="",$D(^BQICARE(OWNR,1,PLIEN,30,SHRIEN,20,BDPIEN,0)) D  Q
  1.  .....  S DA(3)=OWNR,DA(2)=PLIEN,DA(1)=SHRIEN
  1.  .....  S DIK="^BQICARE("_DA(3)_",1,"_DA(2)_",30,"_DA(1)_",20,"
  1.  .....  S DA=CMIEN
  1.  .....  D ^DIK
  1.  .....  K DA,DIK
  1.  .... ;
  1.  .... ; Replace old case manager with new case manager
  1.  .... S DA(3)=OWNR,DA(2)=PLIEN,DA(1)=SHRIEN,DA=CMIEN
  1.  .... S IENS=$$IENS^DILF(.DA)
  1.  .... S BQIUPD(90505.06,IENS,.01)=BDPCM
  1.  .... D FILE^DIE("","BQIUPD","ERROR")
  1.  .... K BQIUPD,IENS
  1.  ... ;
  1.  ... D STYP(22,90505.322) ; Reminders View
  1.  ... D STYP(25,90505.325) ; GPRA View
  1.  Q
  1.  ;
  1. PTYP(ND,FIL) ; EP - PANEL VIEWS
  1.  ;
  1.  ;Input
  1.  ;  ND - Node associated with specified view
  1.  ;  FIL - File number for the view
  1.  ;
  1.  S CMIEN=$O(^BQICARE(OWNR,1,PLIEN,ND,"B","CM","")) Q:CMIEN=""
  1.  Q:'$D(^BQICARE(OWNR,1,PLIEN,ND,CMIEN,0))
  1.  K ERROR
  1.  S BDPIEN=$O(^BQICARE(OWNR,1,PLIEN,ND,"B","BDPCM",""))
  1.  ;
  1.  ; If both exist delete CM entry
  1.  I BDPIEN'="",$D(^BQICARE(OWNR,1,PLIEN,ND,BDPIEN,0)) D  Q
  1.  . S DA(2)=OWNR,DA(1)=PLIEN,DIK="^BQICARE("_DA(2)_",1,"_DA(1)_","_ND_","
  1.  . S DA=CMIEN
  1.  . D ^DIK
  1.  . K DA,DIK
  1.  ;
  1.  ; Replace old case manager with new case manager
  1.  S DA(2)=OWNR,DA(1)=PLIEN,DA=CMIEN
  1.  S IENS=$$IENS^DILF(.DA)
  1.  S BQIUPD(FIL,IENS,.01)="BDPCM"
  1.  D FILE^DIE("","BQIUPD","ERROR")
  1.  K BQIUPD
  1.  Q
  1.  ;
  1. STYP(ND,FIL) ; EP - SHARED USERS VIEWS
  1.  ;
  1.  ;Input
  1.  ;  ND - Node associated with specified view
  1.  ;  FIL - File number for the view
  1.  ;
  1.  S CMIEN=$O(^BQICARE(OWNR,1,PLIEN,30,SHRIEN,ND,"B","CM","")) Q:CMIEN=""
  1.  Q:'$D(^BQICARE(OWNR,1,PLIEN,30,SHRIEN,ND,CMIEN,0))
  1.  S BDPIEN=$O(^BQICARE(OWNR,1,PLIEN,30,SHRIEN,ND,"B","BDPCM",""))
  1.  K ERROR
  1.  ;
  1.  ; If both exist delete CM entry
  1.  I BDPIEN'="",$D(^BQICARE(OWNR,1,PLIEN,30,SHRIEN,ND,BDPIEN,0)) D  Q
  1.  . S DA(3)=OWNR,DA(2)=PLIEN,DA(1)=SHRIEN
  1.  . S DIK="^BQICARE("_DA(3)_",1,"_DA(2)_",30,"_DA(1)_","_ND_","
  1.  . S DA=CMIEN
  1.  . D ^DIK
  1.  . K DA,DIK
  1.  ;
  1.  ; Replace old case manager with new case manager
  1.  S DA(3)=OWNR,DA(2)=PLIEN,DA(1)=SHRIEN,DA=CMIEN
  1.  S IENS=$$IENS^DILF(.DA)
  1.  S BQIUPD(FIL,IENS,.01)="BDPCM"
  1.  D FILE^DIE("","BQIUPD","ERROR")
  1.  K BQIUPD,IENS
  1.  Q
  1.  ;
  1. CRS ;EP - Clean up deceased patient's CRS measures
  1.  NEW DFN,CRSN
  1.  S DFN=0
  1.  F  S DFN=$O(^BQIPAT(DFN)) Q:'DFN  D
  1.  . I $G(^BQIPAT(DFN,0))="" K ^BQIPAT(DFN) Q
  1.  . ; If the CRS version is old, delete it
  1.  . I $P(^BQIPAT(DFN,0),"^",2)<2008 K ^BQIPAT(DFN,30)
  1.  . ; Clean up flag levels
  1.  . NEW FL,DIK,DA
  1.  . S FL=0
  1.  . F  S FL=$O(^BQIPAT(DFN,10,FL)) Q:'FL  D
  1.  .. I $O(^BQIPAT(DFN,10,FL,5,0))="" D
  1.  ... S DA(1)=DFN,DA=FL,DIK="^BQIPAT("_DA(1)_",10," D ^DIK
  1.  . S CRSN=0
  1.  . F  S CRSN=$O(^BQIPAT(DFN,30,CRSN)) Q:'CRSN  D
  1.  .. ; If the first piece is still a strict pointer instead of YEAR_#, then it is the
  1.  .. ; old format and needs to be deleted
  1.  .. I $P(^BQIPAT(DFN,30,CRSN,0),"^",1)?.N K ^BQIPAT(DFN,30) Q
  1.  . ; Check for no data at all
  1.  . NEW DA,DIK
  1.  . S DIK="^BQIPAT("
  1.  . I $O(^BQIPAT(DFN,10,0))="",$O(^BQIPAT(DFN,20,0))="",$O(^BQIPAT(DFN,30,0))="",$O(^BQIPAT(DFN,40,0))="",$O(^BQIPAT(DFN,50,0))="" S DA=DFN D ^DIK
  1.  ; 
  1.  ; Update panels with existing NUMVIS filter to include "'<" since number of
  1.  ; visits was originally a minimum value
  1.  ;
  1.  NEW OWNR,PLIEN,FLTR,NUMVIS
  1.  S OWNR=0
  1.  F  S OWNR=$O(^BQICARE(OWNR)) Q:'OWNR  D
  1.  . S PLIEN=0
  1.  . F  S PLIEN=$O(^BQICARE(OWNR,1,PLIEN)) Q:'PLIEN  D
  1.  .. S FLTR=$O(^BQICARE(OWNR,1,PLIEN,15,"B","NUMVIS","")) Q:FLTR=""
  1.  .. S NUMVIS=$G(^BQICARE(OWNR,1,PLIEN,15,FLTR,0))
  1.  .. Q:NUMVIS'?1"NUMVIS^"1N.N
  1.  .. S NUMVIS=$S(NUMVIS="NUMVIS^0":"NUMVIS^<1",1:"NUMVIS^'<"_$P(NUMVIS,U,2)),^BQICARE(OWNR,1,PLIEN,15,FLTR,0)=NUMVIS
  1.  .. ; Update generated description to reflect change
  1.  .. NEW DA,IENS
  1.  .. S DA(1)=OWNR,DA=PLIEN,IENS=$$IENS^DILF(.DA)
  1.  .. K DESC
  1.  .. D PEN^BQIPLDSC(OWNR,PLIEN,.DESC)
  1.  .. D WP^DIE(90505.01,IENS,5,"","DESC")
  1.  .. K DESC,BMXSEC
  1.  ;
  1.  D CM
  1.  Q
  1.  ;
  1. VIEW ; Add new View Items
  1.  ;;0|EMAIL^^Email Address^^9000001^1802^^T00065EMAIL^^^^^^^^1~1|~3|1^^Address^O^34~5|
  1.  ;;0|COM^9^Community^D^9000001^1117^^T00030COM^O^^^O^O^^95~1|~3|1^^Demographics^D^9~5|
  1.  ;;0|ASACON^^Asthma Control^^^^^T00030ASACON~1|S VAL=$$DSP^BQIRGASU(DFN,STVW)~3|4^^^D^7~5|S VAL="",OTHER="",VISIT="",VAL=$$LASTACON^APCHSMAS(DFN,4),OTHER=$$FMTE^BQIUL1($$LASTACON^APCHSMAS(DFN,2))
  1.  ;;0|ASACT^^Last Action Plan^^^^^T01024ASACT~1|S VAL=$$DSP^BQIRGASU(DFN,STVW)~3|4^^^D^9~5|S VAL=$$FED^BQITRUTL("",DFN,"ASM-SMP"),VISIT=$P(VAL,U,4),VAL=$$FMTE^BQIUL1($P(VAL,U,2)),OTHER=""
  1.  ;;0|ASAQC^^Asthma Quality of Care^^^^^T00003ASAQC~1|S VAL=$$DSP^BQIRGASU(DFN,STVW)~3|4^^^D^^^^^1~5|S VAL=$P($$AQC^BQIRGASU(DFN),U,1)
  1.  ;;0|ASCNTRL^^On Controller Meds^^^^^T00003ASCNTRL~1|S VAL=$$DSP^BQIRGASU(DFN,STVW)~3|4^^^O^18~5|S VAL=$$CNTRL^BQIRGASU(DFN),OTHER=$P(VAL,U,2),VISIT=$P(VAL,U,3),VAL=$P(VAL,U,1)
  1.  ;;0|ASCSMGR^6^Case Manager^O^90181.01^.12^^T00035ASCSMGR^^1^3090317~1|~3|4^^^D^6~5|
  1.  ;;0|ASDD^3^Due Date^O^90181.01^.07^^D00015ASDD^^1^3090317~1|~3|4^^^D^3^^^D~5|
  1.  ;;0|ASFHX^^Asthma Family History^^^^^T01024ASFHX~1|S VAL=$$DSP^BQIRGASU(DFN,STVW)~3|4^^^O^15~5|S VAL=$$ASFHX^BQIRGASU(DFN),OTHER=$P(VAL,U,3),VAL=$P(VAL,U)
  1.  ;;0|ASFLU^^Last Flu Shot^^^^^T01024ASFLU~1|S VAL=$$DSP^BQIRGASU(DFN,STVW)~3|4^^^D^10~5|S VAL=$$LASTFLU^APCLAPI4(DFN,"","","A"),VISIT=$P(VAL,U,4),VAL=$$FMTE^BQIUL1($P(VAL,U))
  1.  ;;0|ASIHSD^^On Inhaled Steroids^^^^^T00003ASIHSD~1|S VAL=$$DSP^BQIRGASU(DFN,STVW)~3|4^^^O^20~5|S VAL=$$INHST^BQIRGASU(DFN),OTHER=$P(VAL,U,2),VISIT=$P(VAL,U,3),VAL=$P(VAL,U,1)
  1.  ;;0|ASLADM^^Work/School Days Missed^^^^^T00003ASLADM~1|S VAL=$$DSP^BQIRGASU(DFN,STVW)~3|4^^^O^13~5|S VAL=$$MEAS^BQIDCUTL(DFN,"ADM"),OTHER=$P(VAL,U,2),VISIT=$P(VAL,U,4),VAL=$P(VAL,U,3)
  1.  ;;0|ASLBPF^^Best Peak Flow^^^^^T00003ASLBPF~1|S VAL=$$DSP^BQIRGASU(DFN,STVW)~3|4^^^D^5~5|S VAL=$$MEAS^BQIDCUTL(DFN,"BPF"),OTHER=$P(VAL,U,2),VISIT=$P(VAL,U,4),VAL=$P(VAL,U,3)
  1.  ;;0|ASLEUV^^Last Asthma ER/UC Visit^^^^^T00030ASLEUV~1|S VAL=$$DSP^BQIRGASU(DFN,STVW)~3|4^^^O^16~5|S VAL=$$LERUC^BQIRGASU(DFN),VISIT=$P(VAL,U,2),VAL=$P(VAL,U,1)
  1.  ;;0|ASLFD^^Symptom Free Days^^^^^T00003ASLFD~1|S VAL=$$DSP^BQIRGASU(DFN,STVW)~3|4^^^O^12~5|S VAL=$$MEAS^BQIDCUTL(DFN,"ASFD"),OTHER=$P(VAL,U,2),VISIT=$P(VAL,U,4),VAL=$P(VAL,U,3)
  1.  ;;0|ASLFEF^9^Last FEF 25^O^^^^N00003ASLFEF^^1^3090317~1|S VAL=$P($$MEAS^BQIDCUTL(DFN,"FEF"),U,3)~3|4^^^^9~5|
  1.  ;;0|ASLFEV^8^FEV1/FVC^O^^^^T00003ASLFEV^^^~1|S VAL=$$DSP^BQIRGASU(DFN,STVW)~3|4^^^D^8~5|S VAL=$$MEAS^BQIDCUTL(DFN,"FVFC"),OTHER=$P(VAL,U,2),VISIT=$P(VAL,U,4),VAL=$P(VAL,U,3)
  1.  ;;0|ASLHSV^^Last Asthma Hospital Visit^^^^^T00030ASLHSV~1|S VAL=$$DSP^BQIRGASU(DFN,STVW)~3|4^^^O^17~5|S VAL=$$LHOSV^BQIRGASU(DFN),VISIT=$P(VAL,U,2),VAL=$P(VAL,U,1)
  1.  ;;0|ASLPEF^10^Last PEF/Best PF^O^^^^T00003ASLPEF^^1^3090317~1|S VAL=$$MEAS^BQIRGUTL(DFN,"PEF",HDR)~3|4^^^^10~5|
  1.  ;;0|ASLPF^^Last Peak Flow^^^^^T00003ASLPF~1|S VAL=$$DSP^BQIRGASU(DFN,STVW)~3|4^^^D^6~5|S VAL=$$MEAS^BQIDCUTL(DFN,"PF"),OTHER=$P(VAL,U,2),VISIT=$P(VAL,U,4),VAL=$P(VAL,U,3)
  1.  ;;0|ASLV^2^Last Asthma Visit^O^^^^T00030ASLV^^^~1|S VAL=$$DSP^BQIRGASU(DFN,STVW)~3|4^^^D^4^^^D~5|S VAL=$$ASVIS^BQIRGASU(DFN),VISIT=$P(VAL,U,2),VAL=$$FMTE^BQIUL1($P(VAL,U,1))
  1.  ;;0|ASMGPLDT^7^Asthma Management Plan Date^O^90181.01^.093^^D00015ASMGPLDT^^1^3090317~1|~3|4^^^^7^^^D~5|
  1.  ;;0|ASRLVR^^On Reliever Meds^^^^^T00003ASRLVR~1|S VAL=$$DSP^BQIRGASU(DFN,STVW)~3|4^^^O^19~5|S VAL=$$RLVR^BQIRGASU(DFN),OTHER=$P(VAL,U,2),VISIT=$P(VAL,U,3),VAL=$P(VAL,U,1)
  1.  ;;0|ASSEV^4^Asthma Severity^O^^^^T00001ASSEV^^^~1|S VAL=$$DSP^BQIRGASU(DFN,STVW)~3|4^^^D^2~5|S VAL=$$LASTSEV^APCHSAST(DFN,1)
  1.  ;;0|ASSEVDT^5^Severity Date^O^^^^T00030ASSEVDT^^1^3090317~1|S VAL=$$FMTE^BQIUL1($$LASTSEV^APCHSAST(DFN,2))~3|4^^^^5^^^D~5|
  1.  ;;0|ASSTAT^^Asthma Tag Status^O^90181.01^.02^^T00001ASSTAT^^^^^^^^1~1|S VAL=$$CTAG^BQITDUTL(DFN,"Asthma")~3|4^^^D^3~5|S VAL=$$CTAG^BQITDUTL(DFN,"Asthma")
  1.  ;;0|ASTBHF^^Last Tobacco Health Factor^^^^^T00030ASTBHF~1|S VAL=$$DSP^BQIRGASU(DFN,STVW)~3|4^^^O^14~5|S VAL=$$TOB^BQIRGASU(DFN),OTHER=$P(VAL,U,2),VAL=$P(VAL,U,1),VISIT=$P(VAL,U,3)
  1.  ;;0|ASTRIG^^Asthma Triggers^^^^^T01024ASTRIG~1|S VAL=$$DSP^BQIRGASU(DFN,STVW)~3|4^^^O^11~5|S VAL=$$ASTRIG^BQIRGASU(DFN),OTHER=$P(VAL,U,2),VAL=$P(VAL,U,1)
  1.  Q