Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BQIMSLST

BQIMSLST.m

Go to the documentation of this file. 
  1. BQIMSLST ;PRXM/HC/ALA-Get list of My Measure values ; 04 May 2007  2:27 PM
  1.  ;;2.3;ICARE MANAGEMENT SYSTEM;;Apr 18, 2012;Build 59
  1.  ;
  1.  Q
  1.  ;
  1. EN(DATA,TYPE) ;EP -- BQI GET MEASURES LIST
  1.  ;
  1.  ; Input
  1.  ;   TYPE - type of measures to list
  1.  ;          'D' for demographics only
  1.  ;          'G' for GPRA only
  1.  ;          'R' for Reminders only
  1.  ;          'H' for HIV/AIDS
  1.  ;          null for all
  1.  ;
  1.  NEW UID,II,TTYPE,SCAT,SCLIN,BQMEAS,CAT,CLIN,TITLE,SDIR
  1.  S UID=$S($G(ZTSK):"Z"_ZTSK,1:$J)
  1.  S DATA=$NA(^TMP("BQIMSLST",UID))
  1.  K @DATA
  1.  ;
  1.  S II=0
  1.  NEW $ESTACK,$ETRAP S $ETRAP="D ERR^BQIMSLST D UNWIND^%ZTER" ; SAC 2006 2.2.3.3.2
  1.  S TYPE=$G(TYPE,"")
  1.  S @DATA@(II)="I00010MEAS_IEN^T00030TYPE^T00030CATEGORY^T00030CLIN_GROUP^T00050DISPLAY_NAME^T00015CODE^T00001VIEW^T00001PER_DIRECT^T00001EXCEPT^I00003SIZE^"
  1.  S @DATA@(II)=@DATA@(II)_"T00003EDIT^T00003BATCH^T00001DEFAULT_SORT^T00001IPC_CAT"_$C(30)
  1.  ;
  1.  K BQISORT
  1.  I TYPE'="" S TTYPE=TYPE D RET G DONE
  1.  ;
  1.  S TTYPE=$G(TYPE,"") S:TTYPE="" TTYPE="M"
  1.  F  S TYPE=$O(^BQI(90506.1,"AC",TYPE)) Q:TYPE=""  D RET
  1.  ;
  1. DONE ;
  1.  S CAT=""
  1.  F  S CAT=$O(BQISORT(CAT)) Q:CAT=""  D
  1.  . S CLIN=""
  1.  . F  S CLIN=$O(BQISORT(CAT,CLIN)) Q:CLIN=""  D
  1.  .. S TITLE=""
  1.  .. F  S TITLE=$O(BQISORT(CAT,CLIN,TITLE)) Q:TITLE=""  D
  1.  ... S BQMEAS=""
  1.  ... F  S BQMEAS=$O(BQISORT(CAT,CLIN,TITLE,BQMEAS)) Q:BQMEAS=""  D
  1.  .... S II=II+1,@DATA@(II)=BQISORT(CAT,CLIN,TITLE,BQMEAS)
  1.  S II=II+1,@DATA@(II)=$C(31)
  1.  K BQISORT
  1.  Q
  1.  ;
  1. ERR ;
  1.  D ^%ZTER
  1.  NEW Y,ERRDTM
  1.  S Y=$$NOW^XLFDT() X ^DD("DD") S ERRDTM=Y
  1.  S BMXSEC="Recording that an error occurred at "_ERRDTM
  1.  I $D(II),$D(DATA) S II=II+1,@DATA@(II)=$C(31)
  1.  Q
  1.  ;
  1. RET ; Data retrieval
  1.  NEW IEN,FDATA,SRC,GCAT,RCAT,DCAT,GCLIN,RCLIN,GVIEW,DVIEW,VIEW,DCLIN
  1.  NEW CAT,CLIN,RVIEW,MVIEW,PDIR,EXCEPT,SIZE,IPCAT,KEY
  1.  S IEN=""
  1.  F  S IEN=$O(^BQI(90506.1,"AC",TYPE,IEN)) Q:IEN=""  D
  1.  . S FDATA=$G(^BQI(90506.1,IEN,0)),EXCEPT="",SIZE=""
  1.  . I $$GET1^DIQ(90506.1,IEN_",",.1,"I")=1 Q
  1.  . I $$GET1^DIQ(90506.1,IEN_",",3.07,"I")=1 Q
  1.  . S KEY=$$GET1^DIQ(90506.1,IEN_",",3.1,"E")
  1.  . I KEY'="",'$$KEYCHK^BQIULSC(KEY,DUZ) Q
  1.  . S SRC=$$GET1^DIQ(90506.1,IEN_",",3.01,"E")
  1.  . S PDIR=$$GET1^DIQ(90506.1,IEN_",",.14,"I")
  1.  . S SIZE=$$GET1^DIQ(90506.1,IEN_",",.15,"E")
  1.  . S EDIT=+$$GET1^DIQ(90506.1,IEN_",",.16,"I")
  1.  . S EDIT=$S(EDIT=1:"YES",1:"NO")
  1.  . S BATCH=+$$GET1^DIQ(90506.1,IEN_",",.17,"I")
  1.  . S BATCH=$S(BATCH=1:"YES",1:"NO")
  1.  . S SDIR=$$GET1^DIQ(90506.1,IEN_",",3.08,"I")
  1.  . S:SDIR="" SDIR="A"
  1.  . S VIEW=$$GET1^DIQ(90506.1,IEN_",",3.04,"I")
  1.  . S:VIEW="" VIEW="O"
  1.  . S DCLIN=""
  1.  . S CAT=$$GET1^DIQ(90506.1,IEN_",",3.03,"E")
  1.  . S CLIN=$$GET1^DIQ(90506.1,IEN_",",3.02,"E")
  1.  . S IPCAT="N"
  1.  . I TYPE="G" D
  1.  .. NEW CODE,BQIH,BQIYR,BQMEAS,VER
  1.  .. S CODE=$P(FDATA,U,1),YEAR=$P(CODE,"_",1)
  1.  .. S BQMEAS=$P(CODE,"_",2)
  1.  .. S BQIH=$$SPM^BQIGPUTL()
  1.  .. S BQIYR=$$LKP^BQIGPUTL(YEAR)
  1.  .. S VER=$$VERSION^XPDUTL("BGP")
  1.  .. I VER>7.0 D
  1.  ... D GFN^BQIGPUTL(BQIH,BQIYR)
  1.  ... S EXCEPT=$$GET1^DIQ(BQIMEASF,BQMEAS_",",1704,"I")
  1.  ... S EXCEPT=$S(EXCEPT="Y":"C",1:"N")
  1.  ... S PDIR=$$GET1^DIQ(BQIMEASF,BQMEAS_",",1705,"E")
  1.  ... S IPCAT=$$GET1^DIQ(BQIMEASF,BQMEAS_",",1707,"I"),IPCAT=$S(IPCAT=1:"Y",1:"N")
  1.  . S SCAT=$S(CAT="":"@",1:CAT),SCLIN=$S(CLIN="":"@",1:CLIN)
  1.  . S BQISORT(SCAT,SCLIN,$P(FDATA,U,3),IEN)=IEN_U_SRC_U_CAT_U_CLIN_U_$P(FDATA,U,3)_U_$P(FDATA,U,1)_U_VIEW_U_$G(PDIR)_U_$G(EXCEPT)_U_SIZE_U_EDIT_U_BATCH_U_SDIR_U_IPCAT_$C(30)
  1.  Q