Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BSDRCLN

BSDRCLN.m

Go to the documentation of this file.
  1. BSDRCLN ;cmi/flag/maw - BSD Print Restricted Clinic List by Division 10/12/2009 2:40:25 PM
  1. ;;5.3;PIMS;**1011**;FEB 27,2007;
  1. ;
  1. ;
  1. ;
  1. ;this report will list restricted clinics by division
  1. Q
  1. ;
  1. MAIN ;EP - this is the main routine driver
  1. S BSDDIV=$$GETDIV()
  1. I '$G(BSDDIV) W !,"You must select a division" D EOJ Q
  1. D LOOP(.BSDRC,BSDDIV)
  1. D PRINT(.BSDRC,BSDDIV)
  1. D EOJ
  1. Q
  1. ;
  1. GETDIV() ;-- get the division the user wants
  1. S DIC("A")="Select DIVISION:"
  1. D ASK^SDDIV
  1. I $G(Y)<0 K DIV
  1. Q $G(DIV)
  1. ;
  1. LOOP(BSDRC,DV) ;-- loop through the HOSPITAL LOCATION file, screen on DIV and get Restricted Clinic
  1. N BSDDA,BSDATA,BSDDV,BSDRS,BSDCLN,BSDTYP,BSDINS,BSDTYPI
  1. S BSDDA=0 F S BSDDA=$O(^SC(BSDDA)) Q:'BSDDA D
  1. . S BSDATA=$G(^SC(BSDDA,0))
  1. . S BSDDV=$P(BSDATA,U,15)
  1. . Q:BSDDV'=DV
  1. . Q:$P($G(^SC(BSDDA,"SDPROT")),U)'="Y"
  1. . S BSDCLN=$$GET1^DIQ(44,BSDDA,.01)
  1. . S BSDTYPI=$$GET1^DIQ(44,BSDDA,8,"I")
  1. . S BSDTYP=$S(BSDTYPI:$P($G(^DIC(40.7,BSDTYPI,0)),U,2),1:"")
  1. . S BSDINS=$$GET1^DIQ(44,BSDDA,3)
  1. . S BSDRC(BSDDA)=BSDCLN_U_BSDTYP_U_BSDINS
  1. Q
  1. ;
  1. PRINT(RC,DV) ;-- print the report
  1. D ^%ZIS
  1. Q:POP
  1. U IO
  1. D XHDR(DV)
  1. N BSDTDA,BSDTDATA,BSDTCLN,BSDTTYP,BSDTINS
  1. S BSDTDA=0 F S BSDTDA=$O(RC(BSDTDA)) Q:BSDTDA=""!($D(DIRUT)) D
  1. . S BSDTDATA=$G(RC(BSDTDA))
  1. . S BSDTCLN=$P(BSDTDATA,U)
  1. . S BSDTTYP=$P(BSDTDATA,U,2)
  1. . S BSDTINS=$P(BSDTDATA,U,3)
  1. . D:$Y+2>IOSL HDR(DV) Q:$G(DIRUT)
  1. . W !,BSDTCLN,?35,BSDTTYP,?55,BSDTINS
  1. Q
  1. ;
  1. HDR(ID) ;-- do the charge header
  1. K DIRUT
  1. I $E(IOST,1,1)="C" S DIR(0)="E" D ^DIR
  1. I Y=1 D XHDR(ID) Q
  1. S DIRUT=1
  1. Q
  1. ;
  1. XHDR(ID) ;
  1. W @IOF
  1. S ID=$$GET1^DIQ(40.8,ID,.01)
  1. W "Restricted Clinic List by Division: "_ID,?60,"Date: "_$$FMTE^XLFDT(DT)
  1. W !!,"Clinic",?35,"Clinic Code",?55,"Institution"
  1. W !
  1. F I=1:1:80 W "-"
  1. Q
  1. ;
  1. EOJ ;-- kill variables and quit
  1. D ^%ZISC
  1. K BSDDIV,BSDRC
  1. Q
  1. ;