Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BSDX22

BSDX22.m

Go to the documentation of this file. 
  1. BSDX22 ; IHS/OIT/HMW/MSC/SAT - WINDOWS SCHEDULING RPCS ;
  1.  ;;3.0;IHS WINDOWS SCHEDULING;;DEC 09, 2010
  1.  ;
  1.  ;
  1. DELAGID(BSDXY,BSDXIEN,BSDXIEN1) ;EP
  1.  ;Entry point for debugging
  1.  ;
  1.  ;D DEBUG^%Serenji("DELAGI^BSDX22(.BSDXY,BSDXIEN,BSDXIEN1)")
  1.  Q
  1.  ;
  1. DELAGI(BSDXY,BSDXIEN,BSDXIEN1) ;EP
  1.  ;Deletes entry having Access Group BSDXIEN and Access Type BSDXIEN1 the ACCESS GROUP TYPE file
  1.  ;Return recordset containing error message or "" if no error
  1.  ;Called by BSDX DELETE ACCESS GROUP ITEM
  1.  ;Test Line:
  1.  ;D DELAGI^BSDX22(.RES,99)
  1.  ;
  1.  S X="ERROR^BSDX22",@^%ZOSF("TRAP")
  1.  N BSDXI,DIK,DA,BSDXIEN2
  1.  S BSDXI=0
  1.  S BSDXY="^BSDXTMP("_$J_")"
  1.  S ^BSDXTMP($J,0)="I00020ACCESSGROUPTYPEID^T00030ERRORTEXT"_$C(30)
  1.  I '+BSDXIEN D ERR(0,"BSDX22: Invalid null Access Group ID") Q
  1.  I '+BSDXIEN1 D ERR(0,"BSDX22: Invalid null Access Type ID") Q
  1.  I '$D(^BSDXAGTP("AC",BSDXIEN,BSDXIEN1)) D  Q
  1.  . D ERR(0,"BSDX22: Invalid null Access Group Type ID")
  1.  . Q
  1.  S BSDXIEN2=$O(^BSDXAGTP("AC",BSDXIEN,BSDXIEN1,0))
  1.  I '+BSDXIEN2 D ERR(0,"BSDX22: Invalid null Access Group Type ID") Q
  1.  ;
  1.  ;Delete entry
  1.  S DIK="^BSDXAGTP("
  1.  S DA=BSDXIEN2
  1.  D ^DIK
  1.  ;
  1.  S BSDXI=BSDXI+1
  1.  S ^BSDXTMP($J,BSDXI)=BSDXIEN2_"^"_"-1"_$C(30)_$C(31)
  1.  Q
  1.  ;
  1. ADDAGID(BSDXY,BSDXIEN,BSDXIEN1) ;EP
  1.  ;Entry point for debugging
  1.  ;
  1.  ;D DEBUG^%Serenji("ADDAGI^BSDX22(.BSDXY,BSDXIEN,BSDXIEN1)")
  1.  Q
  1.  ;
  1. ADDAGI(BSDXY,BSDXIEN,BSDXIEN1) ;EP
  1.  ;Adds ACCESS GROUP TYPE file entry having access group BSDXIEN and access type BSDXIEN1
  1.  ;Return recordset containing added entry number error message or "" if no error
  1.  ;Called by BSDX ADD ACCESS GROUP ITEM
  1.  ;Test Line:
  1.  ;D ADDAGI^BSDX22(.RES,1,1)
  1.  ;
  1.  S X="ERROR^BSDX22",@^%ZOSF("TRAP")
  1.  N BSDXI,BSDXIENS,BSDXMSG,BSDXFDA
  1.  S BSDXI=0
  1.  S BSDXY="^BSDXTMP("_$J_")"
  1.  ;S ^BSDXTMP($J,0)="I00020ACCESSGROUPTYPEID^I00020ERRORID"_$C(30)
  1.  S ^BSDXTMP($J,0)="I00020ACCESSGROUPTYPEID^T00030ERRORTEXT"_$C(30)
  1.  I '+BSDXIEN D ERR(0,"BSDX22: Invalid null Access Group ID") Q
  1.  I '+BSDXIEN1 D ERR(0,"BSDX22: Invalid null Access Type ID") Q
  1.  I '$D(^BSDXAGP(BSDXIEN,0)) D ERR(0,"BSDX22: Invalid Access Group ID") Q
  1.  I '$D(^BSDXTYPE(BSDXIEN1,0)) D ERR(0,"BSDX22: Invalid Access Type ID") Q
  1.  I $D(^BSDXAGTP("AC",BSDXIEN,BSDXIEN1)) D  Q
  1.  . S BSDXIENS=$O(^BSDXAGTP("AC",BSDXIEN,BSDXIEN1,0))
  1.  . S ^BSDXTMP($J,BSDXI+1)=+BSDXIENS_"^"_$C(30)_$C(31)
  1.  . Q
  1.  ;
  1.  S BSDXIENS="+1,"
  1.  S BSDXFDA(9002018.39,BSDXIENS,.01)=BSDXIEN ;ACCESS GROUP ID
  1.  S BSDXFDA(9002018.39,BSDXIENS,.02)=BSDXIEN1 ;ACCESS TYPE ID
  1.  K BSDXIEN
  1.  D UPDATE^DIE("","BSDXFDA","BSDXIEN","BSDXMSG")
  1.  S BSDXI=BSDXI+1
  1.  S ^BSDXTMP($J,BSDXI)=+$G(BSDXIEN(1))_"^"_$C(30)_$C(31)
  1.  Q
  1.  ;
  1. ERR(BSDXERID,ERRTXT) ;Error processing
  1.  S:'+$G(BSDXI) BSDXI=999999
  1.  S BSDXI=BSDXI+1
  1.  S ^BSDXTMP($J,BSDXI)=BSDXERID_"^"_ERRTXT_$C(30)
  1.  S BSDXI=BSDXI+1
  1.  S ^BSDXTMP($J,BSDXI)=$C(31)
  1.  Q
  1.  ;
  1. ERROR ;
  1.  D ^%ZTER
  1.  I '+$G(BSDXI) N BSDXI S BSDXI=999999
  1.  S BSDXI=BSDXI+1
  1.  D ERR(0,"BSDX22 M Error: <"_$G(%ZTERROR)_">")
  1.  Q