Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BSTS10P4

BSTS10P4.m

Go to the documentation of this file. 
  1. BSTS10P4 ;GDIT/HS/BEE-Version 1.0 Patch 4 Post (and Pre) Install ; 19 Nov 2012  9:41 AM
  1.  ;;1.0;IHS STANDARD TERMINOLOGY;**4**;Sep 10, 2014;Build 32
  1.  ;
  1. ENV ;EP - Environmental Checking Routine
  1.  ;
  1.  N VERSION,EXEC,BMWDT
  1.  ;
  1.  ;Check for BSTS*1.0*3
  1.  I '$$INSTALLD("BSTS*1.0*3") D BMES^XPDUTL("Version 1.0 Patch 3 of BSTS is required!") S XPDQUIT=2 Q
  1.  ;
  1.  ;Make sure a refresh is not running already
  1.  L +^BSTS(9002318.1,0):0 E  D BMES^XPDUTL("A Local BSTS Cache Refresh is Already Running. Please Try Later") S XPDQUIT=2 Q
  1.  L -^BSTS(9002318.1,0)
  1.  ;
  1.  ;Make sure an ICD9 to SNOMED compile isn't running
  1.  L +^TMP("BSTSICD2SMD"):0 E  D BMES^XPDUTL("An ICD9 to SNOMED Background Compile is Running.  Please Try later") S XPDQUIT=2 Q
  1.  L -^TMP("BSTSICD2SMD")
  1.  ;
  1.  ;Make sure another install isn't running
  1.  L +^TMP("BSTSINSTALL"):3 E  D BMES^XPDUTL("A BSTS Install is Already Running") S XPDQUIT=2 Q
  1.  L -^TMP("BSTSINSTALL")
  1.  ;
  1.  Q
  1.  ;
  1. EN ;EP
  1.  ;
  1.  ;Load the classes
  1.  ;
  1.  N TRIEN,EXEC,ERR
  1.  ;
  1.  ;For each build, set this to the 9002318.5 entry to load
  1.  S TRIEN=1
  1.  ;
  1.  ;Delete existing BSTS Classes
  1.  S EXEC="DO $SYSTEM.OBJ.DeletePackage(""BSTS"")" X EXEC
  1.  ;
  1.  ; Import BSTS classes
  1.  K ERR
  1.  I $G(TRIEN)'="" D IMPORT^BSTSCLAS(TRIEN,.ERR)
  1.  I $G(ERR) Q
  1.  ; 
  1.  ;Display install message
  1.  D BMES^XPDUTL("Kicking off process to retrieve terms for Description Ids")
  1.  ;
  1. RESTART ;Restart from here if check below fails
  1.  ;
  1.  ;Kick off process if not already running
  1.  L +^XTMP("BSTSCFIX"):0 E  G XEN
  1.  ;
  1.  ;Verify that DTS is working
  1.  NEW STS,VAR
  1.  D RESET^BSTSWSV1  ;Reset the DTS link to on
  1.  S STS=$$VERSIONS^BSTSAPI("VAR",36)
  1.  I (+STS'=2)!$G(ERR) D  W !!,"DTS is not working properly. Please contact the BSTS Support Group - Aborting Installation" H 10 S XPDABORT=1 Q
  1.  . ;
  1.  . ;Quit if a restart
  1.  . Q:'$G(KIDS)
  1.  . ;
  1.  . ;Allow logins again
  1.  . NEW LIEN,LOG,ERR
  1.  . S LIEN=$O(^%ZIS(14.5,0)) Q:'+LIEN
  1.  . S LOG(14.5,LIEN_",",1)="N"
  1.  . D FILE^DIE("","LOG","ERR")
  1.  ;
  1.  ;Kick off background process
  1.  D FIX1^BSTSCFIX
  1.  ;
  1. XEN ;Unlock installation entry
  1.  L -^TMP("BSTSINSTALL")
  1.  ;
  1.  Q
  1.  ;
  1. PRE ;Pre-Install Front End
  1.  ;
  1.  ;Perform Lock so only one install can run and DTS calls will be switched to local
  1.  L +^TMP("BSTSINSTALL"):3 E  D BMES^XPDUTL("A BSTS Install is Already Running - Aborting Installation") S XPDABORT=1 Q
  1.  ;
  1.  N DIU
  1.  ;
  1.  ;Clear out existing transport global
  1.  S DIU="^BSTSCLS(",DIU(0)="DST" D EN^DIU2
  1.  ;
  1.  Q
  1.  ;
  1. INSTALLD(BSTSSTAL) ;EP - Determine if patch BSTSSTAL was installed, where
  1.  ; BSTSSTAL is the name of the INSTALL.  E.g "BSTS*1.0*1".
  1.  ;
  1.  NEW DIC,X,Y,D
  1.  S X=$P(BSTSSTAL,"*",1)
  1.  S DIC="^DIC(9.4,",DIC(0)="FM",D="C"
  1.  D IX^DIC
  1.  I Y<1 Q 0
  1.  S DIC=DIC_+Y_",22,",X=$P(BSTSSTAL,"*",2)
  1.  D ^DIC
  1.  I Y<1 Q 0
  1.  S DIC=DIC_+Y_",""PAH"",",X=$P(BSTSSTAL,"*",3)
  1.  D ^DIC
  1.  Q $S(Y<1:0,1:1)