Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BSTS2P01

BSTS2P01.m

Go to the documentation of this file. 
  1. BSTS2P01 ;GDIT/HS/BEE-Version 2.0 Patch 1 Post (and Pre) Install ; 19 Nov 2012  9:41 AM
  1.  ;;2.0;IHS STANDARD TERMINOLOGY;**1**;Dec 01, 2016;Build 36
  1.  ;
  1. ENV ;EP - Environmental Checking Routine
  1.  ;
  1.  N VERSION,EXEC,BMWDT
  1.  ;
  1.  ;Check for BSTS v2.0
  1.  I $$VERSION^XPDUTL("BSTS")<2 D BMES^XPDUTL("Version 2.0 of BSTS is required!") S XPDQUIT=2 Q
  1.  ;
  1.  ;Make sure a refresh is not running already
  1.  L +^BSTS(9002318.1,0):0 E  D BMES^XPDUTL("A Local BSTS Cache Refresh is Already Running. Please Try Later") S XPDQUIT=2 Q
  1.  L -^BSTS(9002318.1,0)
  1.  ;
  1.  ;Make sure an Description Id fix compile isn't running
  1.  L +^XTMP("BSTSCFIX"):0 E  D BMES^XPDUTL("A Description Id Population Utility Process is Running.  Please Try later") S XPDQUIT=2 Q
  1.  L -^XTMP("BSTSCFIX")
  1.  ;
  1.  ;Make sure an ICD9 to SNOMED compile isn't running
  1.  L +^TMP("BSTSICD2SMD"):0 E  D BMES^XPDUTL("An ICD9 to SNOMED Background Compile is Running.  Please Try later") S XPDQUIT=2 Q
  1.  L -^TMP("BSTSICD2SMD")
  1.  ;
  1.  ;Make sure another install isn't running
  1.  L +^TMP("BSTSINSTALL"):3 E  D BMES^XPDUTL("A BSTS Install is Already Running") S XPDQUIT=2 Q
  1.  L -^TMP("BSTSINSTALL")
  1.  ;
  1.  Q
  1.  ;
  1. EN ;EP
  1.  ;
  1.  ;Load the classes
  1.  ;
  1.  NEW ICONC,ICIEN,INALL,CNT,PIEN
  1.  NEW TRIEN,EXEC,ERR,X,VAR,STS
  1.  ;
  1.  ;For each build, set this to the 9002318.5 entry to load
  1.  S TRIEN=1
  1.  ;
  1.  ;Delete existing BSTS Classes
  1.  S EXEC="DO $SYSTEM.OBJ.DeletePackage(""BSTS"")" X EXEC
  1.  ;
  1.  ; Import BSTS classes
  1.  K ERR
  1.  I $G(TRIEN)'="" D IMPORT^BSTSCLAS(TRIEN,.ERR)
  1.  I $G(ERR) Q
  1.  ;
  1.  ;Set up new BSTS,PROXY USER entry
  1.  S PIEN=$O(^VA(200,"B","BSTS,PROXY USER","")) I PIEN="" D
  1.  . NEW X,DIC,Y,VAUPD,USCLS,DIEN,DA
  1.  . S DIC="^VA(200,",DIC(0)="LX"
  1.  . S X="BSTS,PROXY USER"
  1.  . D ^DIC
  1.  . I '+Y Q
  1.  . S DIEN=+Y
  1.  . ;
  1.  . ;Set up User Class
  1.  . S USCLS=$O(^VA(201,"B","APPLICATION PROXY","")) Q:USCLS=""
  1.  . I $D(^VA(200,DIEN,"USC3","B",USCLS)) Q
  1.  . S DIC(0)="LX",DIC="^VA(200,"_DIEN_",""USC3"","
  1.  . S X="APPLICATION PROXY",DA(1)=DIEN
  1.  . D ^DIC
  1.  ;
  1.  ;Turn on the SEARCH STRING logging
  1.  ;*Decision was made to leave it up to the sites to turn it on
  1.  ;D
  1.  ;. NEW WIEN
  1.  ;. ;
  1.  ;. ;Turn on each WEB SERVICE entry
  1.  ;. S WIEN=0 F  S WIEN=$O(^BSTS(9002318.2,WIEN)) Q:'WIEN  D
  1.  ;.. NEW BSTSUPD,ERROR
  1.  ;.. S BSTSUPD(9002318.2,WIEN_",",.16)="1"
  1.  ;.. D FILE^DIE("","BSTSUPD","ERROR")
  1.  ;
  1.  ;Make a log entry
  1.  D LOG^BSTSAPIL("INST","","PATCH","BSTS*2.0*1")
  1.  ;
  1.  ;Unlock installation entry
  1.  L -^TMP("BSTSINSTALL")
  1.  ;
  1.  ;Kick off update to pull down SNOMED Mapping Advice
  1.  D QUEUE^BSTSVOFL(32777) ;Put it on the queue
  1.  D JOBNOW^BSTSVOFL  ;Kick off now
  1.  ;
  1.  Q
  1.  ;
  1. PRE ;Pre-Install Front End
  1.  ;
  1.  ;Perform Lock so only one install can run and DTS calls will be switched to local
  1.  L +^TMP("BSTSINSTALL"):3 E  D BMES^XPDUTL("A BSTS Install is Already Running - Aborting Installation") S XPDABORT=1 Q
  1.  ;
  1.  N DIU
  1.  ;
  1.  ;Clear out existing transport global and new conversion file
  1.  S DIU="^BSTSCLS(",DIU(0)="DST" D EN^DIU2
  1.  ;
  1.  Q
  1.  ;
  1. INSTALLD(BSTSSTAL) ;EP - Determine if patch BSTSSTAL was installed, where
  1.  ; BSTSSTAL is the name of the INSTALL.  E.g "BSTS*1.0*1".
  1.  ;
  1.  NEW DIC,X,Y,D
  1.  S X=$P(BSTSSTAL,"*",1)
  1.  S DIC="^DIC(9.4,",DIC(0)="FM",D="C"
  1.  D IX^DIC
  1.  I Y<1 Q 0
  1.  S DIC=DIC_+Y_",22,",X=$P(BSTSSTAL,"*",2)
  1.  D ^DIC
  1.  I Y<1 Q 0
  1.  S DIC=DIC_+Y_",""PAH"",",X=$P(BSTSSTAL,"*",3)
  1.  D ^DIC
  1.  Q $S(Y<1:0,1:1)