Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DDS2

DDS2.m

Go to the documentation of this file. 
  1. DDS2 ;SFISC/MLH-UP ARROW JUMP, BRANCH ;10:46 AM  17 Jun 1997
  1.  ;;22.0;VA FileMan;;Mar 30, 1999
  1.  ;Per VHA Directive 10-93-142, this routine should not be modified.
  1. UPA ;Up-arrow jump
  1.  Q:$E(X)'=U
  1.  I X?1"^"1.E,X'="^^",$G(DDSDN) D MSG^DDSMSG("No jumping allowed.",1) Q
  1.  I X?1"^"1.E,X'="^^" D JMP Q
  1.  ;
  1.  ;Up-arrow only
  1.  I 'DDO D E^DDS3 Q
  1.  I $D(DDSREP),DA D POSTACT D:$D(DDSBR)[0 END^DDSM Q
  1.  I $G(DDSDN)=1 D MSG^DDSMSG("No exit allowed, since navigation for the block is disabled.",1) Q
  1.  D POSTACT S:$D(DDSBR)[0 DDSOSV=DDO,DDO=0 Q
  1.  Q
  1.  ;
  1. POSTACT ;Execute post action
  1.  Q:$G(DDSO(12))?." "
  1.  N X
  1.  S X=$G(DDSOLD) X DDSO(12)
  1.  D:$D(DDSBR)#2 BR
  1.  Q
  1.  ;
  1. JMP ;Up-arrow jump
  1.  S DDS2X=X,X=$P(X,U,2) I X="" W $C(7) G KILL
  1.  K DDH,DDQ S DDH=0
  1.  S (X,DDSX)=$$UPCASE($E(X,1,63))
  1.  ;
  1.  ;Find exact matches
  1.  D:$D(@DDSREFS@("CAP",X)) CAP
  1.  D:$D(@DDSREFT@("XCAP",DDSPG,X)) XCAP
  1.  ;
  1.  ;Find partial matches
  1.  S:X="?" (X,DDSX)=""
  1.  F  S DDSX=$O(@DDSREFS@("CAP",DDSX)) Q:DDSX=""!($P(DDSX,X)]"")  D CAP
  1.  S DDSX=X F  S DDSX=$O(@DDSREFT@("XCAP",DDSPG,DDSX)) Q:DDSX=""!($P(DDSX,X)]"")  D XCAP
  1.  ;
  1.  I 'DDH D MSG^DDSMSG($P(DDS2X,U,2)_" not found.",1) G KILL
  1.  S DDS2O=DDO
  1.  I DDH=1 S DDO=$O(DDH(DDH,""))
  1.  E  S DDD="J" D SC^DDSU
  1.  ;
  1.  S DDS2B=$P(DDO,",",2),DDS2P=$P(DDO,",",3),DDO=+DDO
  1.  G:'DDS2B KILL
  1.  ;
  1.  S DDS2DA=DDSDA
  1.  I DDS2P'=DDSPG D
  1.  . D:'$D(@DDSREFT@(DDS2P,DDS2B)) ^DDS1(DDS2P)
  1.  . S DDS2DA=@DDSREFT@(DDS2P,DDS2B)
  1.  . I DDS2DA="" D
  1.  .. D MSG^DDSMSG($C(7)_$P($T(ERR),";;",2))
  1.  .. S DDO=DDS2O
  1.  . E  D CKUNED D:'$G(DDS2UNED)
  1.  .. D POSTACT
  1.  .. S:$D(DDSBR)[0 DDACT="NP",DDSPG=DDS2P,DDSBK=DDS2B,DDSBR=""
  1.  ;
  1.  E  I DDS2B'=DDSBK D
  1.  . S DDS2DA=@DDSREFT@(DDS2P,DDS2B)
  1.  . I DDS2DA="" D
  1.  .. D MSG^DDSMSG($C(7)_$P($T(ERR),";;",2))
  1.  .. S DDO=DDS2O
  1.  . E  I $P($G(@DDSREFS@(DDS2P,DDS2B)),U,4) D
  1.  .. D MSG^DDSMSG($C(7)_$P($T(ERR1),";;",2))
  1.  .. S DDO=DDS2O
  1.  . E  D CKUNED D:'$G(DDS2UNED)
  1.  .. D POSTACT
  1.  .. S:$D(DDSBR)[0 DDACT="NB",DDSBK=DDS2B,DDSBR=""
  1.  ;
  1.  E  D CKUNED D:'$G(DDS2UNED)
  1.  . D POSTACT
  1.  . S:$D(DDSBR)[0 DDACT="N"
  1.  ;
  1. KILL S X=DDS2X
  1.  K DDH,DDSI,DDSPGRP,DDSX
  1.  K DDS2ATT,DDS2B,DDS2DA,DDS2F,DDS2O,DDS2P,DDS2UNED,DDS2X
  1.  Q
  1.  ;
  1. CKUNED ;Check uneditable status
  1.  N DDP,DDSFLD
  1.  ;
  1.  I $P($G(^DIST(.404,DDS2B,40,+DDO,0)),U,3)=2 D
  1.  . S DDP=0
  1.  . S DDSFLD=+DDO_","_DDS2B
  1.  E  D
  1.  . S DDP=$P($G(@DDSREFS@(DDS2P,DDS2B)),U,3)
  1.  . S DDSFLD=$P($G(^DIST(.404,DDS2B,40,+DDO,1)),U)
  1.  ;
  1.  S DDS2ATT=$P($G(@DDSREFT@("F"_DDP,DDS2DA,DDSFLD,"A")),U,4)
  1.  ;
  1.  I DDO,$S(DDS2ATT="":$P($G(^DIST(.404,DDS2B,40,+DDO,4)),U,4)=1,1:DDS2ATT=1),'$P(@DDSREFS@(DDS2P,DDS2B,+DDO,"N"),U,11) D
  1.  . D MSG^DDSMSG($P(^DIST(.404,DDS2B,40,+DDO,0),U,2)_" is uneditable.",1)
  1.  . S DDS2UNED=1,DDO=DDS2O
  1.  Q
  1.  ;
  1. CAP ;Find all captions that match DDSX
  1.  S DDSPGRP="" F  S DDSPGRP=$O(@DDSREFS@("CAP",DDSX,DDSPGRP)) Q:DDSPGRP=""  D
  1.  . Q:U_DDSPGRP_U'[(U_DDSPG_U)
  1.  . S DDS2P="" F  S DDS2P=$O(@DDSREFS@("CAP",DDSX,DDSPGRP,DDS2P)) Q:'DDS2P  D
  1.  .. S DDS2B="" F  S DDS2B=$O(@DDSREFS@("CAP",DDSX,DDSPGRP,DDS2P,DDS2B)) Q:'DDS2B  D
  1.  ... S DDS2F="" F  S DDS2F=$O(@DDSREFS@("CAP",DDSX,DDSPGRP,DDS2P,DDS2B,DDS2F)) Q:'DDS2F  D FILL
  1.  Q
  1.  ;
  1. XCAP ;Find all xecutable captions that match DDSX
  1.  S DDS2P=DDSPG
  1.  S DDS2B=0 F  S DDS2B=$O(@DDSREFT@("XCAP",DDSPG,DDSX,DDS2B)) Q:'DDS2B  D
  1.  . S DDS2F=0 F  S DDS2F=+$O(@DDSREFT@("XCAP",DDSPG,DDSX,DDS2B,DDS2F)) Q:'DDS2F  D
  1.  .. I $D(^DIST(.404,DDS2B,40,DDS2F,0))#2,$P(^(0),U,3)'=1 D FILL
  1.  Q
  1.  ;
  1. FILL ;Fill DDH array with possible choices
  1.  S DDS2V=DDSX_$S($P(^DIST(.404,DDS2B,40,DDS2F,0),U,4)]"":" ("_$P(^(0),U,4)_")",1:"")
  1.  S:DDS2P'=DDSPG DDS2V=DDS2V_" ("_$S($P($G(^DIST(.403,+DDS,40,DDS2P,1)),U)]"":$P(^(1),U),1:"Page "_$P(^(0),U))_")"
  1.  S DDH=DDH+1,DDH(DDH,DDS2F_","_DDS2B_","_DDS2P)=DDS2V
  1.  K DDS2V
  1.  Q
  1.  ;
  1. BR ;Evaluate DDSBR
  1.  N B,B1,F,F1,P,P1,E,X Q:$D(DDSBR)[0
  1.  S P=$P($G(DDSOPB),U),B=$P($G(DDSOPB),U,2),F=$G(DDO),E=1
  1.  S:'B B=+$P(@DDSREFS@(+P,"FIRST"),",",2)
  1.  S P1=$P(DDSBR,U,3),B1=$P(DDSBR,U,2),F1=$P(DDSBR,U)
  1.  ;
  1.  D @$S(P1]"":"PG",B1]"":"BK",1:"FD")
  1.  S:'E DDACT=$S(P'=+DDSOPB:"NP",B'=$P(DDSOPB,U,2):"NB",1:"N"),DDSPG=P,DDSBK=B,DDO=F
  1.  K:E DDSBR
  1.  Q
  1. PG ;
  1.  I P1=+$P(P1,"E") S P=$O(^DIST(.403,+DDS,40,"B",P1,""))
  1.  E  S P=$O(^DIST(.403,+DDS,40,"C",$$UPCASE(P1),""))
  1.  Q:'P
  1.  S:B1="" B1=$O(^DIST(.403,+DDS,40,P,40,"AC","")) Q:B1=""
  1. BK ;
  1.  I B1=+$P(B1,"E") D
  1.  . S B=$O(^DIST(.403,+DDS,40,P,40,"AC",B1,""))
  1.  E  D
  1.  . S B=$O(^DIST(.404,"B",B1,"")) Q:B=""
  1.  . S B=$O(^DIST(.403,+DDS,40,P,40,"B",B,""))
  1.  Q:'B
  1.  S:F1="" F1=$O(^DIST(.404,B,40,"B",""))
  1. FD ;
  1.  Q:F1=""
  1.  I F1="COM" S (E,F)=0 Q
  1.  I F1=+$P(F1,"E") S X="B"
  1.  E  S F1=$$UPCASE(F1),X=$S($D(^DIST(.404,B,40,"D",F1)):"D",1:"C")
  1.  S F=$O(^DIST(.404,B,40,X,F1,""))
  1.  S:F E=0
  1.  Q
  1.  ;
  1. UPCASE(X) ;
  1.  ;Return X in uppercase
  1.  Q $TR(X,"abcdefghijklmnopqrstuvwxyz","ABCDEFGHIJKLMNOPQRSTUVWXYZ")
  1.  ;
  1. ERR ;;Unable to jump to that field.  The block on which that field is located has no record associated with it.
  1.  ;
  1. ERR1 ;;Unable to jump to that field.  The block on which that field is located has navigation disabled.