Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DGQESC1

DGQESC1.m

Go to the documentation of this file. 
  1. DGQESC1 ;ALB/JFP - VIC INPATIENT SCAN ROUTINE ; 01/09/96
  1.  ;;5.3;REGISTRATION;**73,1015**;DEC 11,1996;Build 21
  1.  ;;Per VHA Directive 10-93-142, this routine should not be modified.
  1.  ;
  1. ENI ; -- Entry Point
  1.  N DIR,Y
  1.  S DIR(0)="YA"
  1.  S DIR("A")="Download all current Inpatients to the VIC card station "
  1.  S DIR("B")="NO"
  1.  S DIR("?")="Enter yes to download data."
  1.  D ^DIR
  1.  I Y D  Q
  1.  .; -- New varaibles
  1.  .N DATE,DFNARR,CLINIC,DFN,ZTSTOP,CNT,RESULTS
  1.  .N VAUTD,VAUTNI
  1.  .N DGSUB,DGJ,DGUTP,DGWD,DGDV
  1.  .N DIVFLAG,DIVISION,SELDIV
  1.  .; -- Set variables
  1.  .S VAUTD=1 ; -- All divisions selected
  1.  .S CNT=0
  1.  .D NOW^%DTC S DATE=%
  1.  .S DFNARR="^TMP(""DGQE-DFN"","_$J_")"
  1.  .K @DFNARR
  1.  .; -- Check for multi divisional hospital
  1.  .I $P(^DG(43,1,"GL"),"^",2)=1 D  Q:Y=-1
  1.  ..D DIVISION^VAUTOMA
  1.  .; -- Check for wards within division or all
  1.  .S VAUTNI=2
  1.  .D WARD^VAUTOMA
  1.  .I Y=-1 Q
  1.  .; -- Task off job
  1.  .S DIR(0)="YA"
  1.  .S DIR("A")="Queue job: "
  1.  .S DIR("B")="YES"
  1.  .S DIR("?")="Enter YES or NO to have job run in background"
  1.  .D ^DIR
  1.  .Q:$D(DIRUT)
  1.  .I Y D  Q
  1.  ..D BATCH
  1.  ..I '$D(ZTSK) Q
  1.  ..W !,"Card(s) queued, task number = "_ZTSK
  1.  .; -- Builds an array of inpatients to download
  1.  .D INSCAN
  1.  Q
  1.  ;
  1. EXIT ; -- Finish processing
  1.  I '$D(ZTQUEUED)&($P(RESULTS,"^",1)=0) W !!,CNT_" Inpatients down loaded to VIC work station"
  1.  K @DFNARR
  1.  Q
  1.  ;
  1. INSCAN ; -- Scans all ward locations for inpatients
  1.  I '$D(ZTQUEUED) W !!,"Note: Each dot equals a ward",!,"."
  1.  ; -- scan INPATIENT clinics
  1.  S (CLINIC,DFN)=""
  1.  F  S CLINIC=$O(^DPT("CN",CLINIC)) Q:(CLINIC="")  D
  1.  .; -- Check to see if users wants task to stop
  1.  .I $$S^%ZTLOAD D  Q
  1.  ..S ZTSTOP=1
  1.  .I VAUTD=0 D CHKDIV  Q:'DIVFLAG
  1.  .I '$D(ZTQUEUED) W "."
  1.  .S DFN=""
  1.  .F  S DFN=$O(^DPT("CN",CLINIC,DFN)) Q:(DFN="")  D
  1.  ..;W !,"DFN = ",DFN
  1.  ..S @DFNARR@(DFN)=""
  1. HL7 ; -- Builds HL7 batch message
  1.  S DFN=""
  1.  F  S DFN=$O(@DFNARR@(DFN)) Q:'DFN  S CNT=CNT+1
  1.  S RESULTS=$$EVENT^DGQEHL72("A08",DFNARR)
  1.  I '$D(ZTQUEUED)&($P(RESULTS,"^",1)=-1) D
  1.  .W !,"Inpatient data not downloaded.  Error - ",$P(RESULTS,"^",2)
  1.  ; -- Clean up variables
  1.  D EXIT
  1.  Q
  1.  ;
  1. CHKDIV ; -- Check to see if clinic is part of Division selected
  1.  ; -- re-sequences array
  1.  S DGSUB="" F DGJ=1:1 S DGSUB=$O(VAUTD(DGSUB)) Q:DGSUB=""  S DGUTD(DGJ)=$G(VAUTD(DGSUB))
  1.  ;
  1.  S DIVFLAG=0
  1.  S DGWD=$O(^DIC(42,"B",CLINIC,0))
  1.  I DGWD S DGDV=$S('$D(^DIC(42,DGWD,0)):0,+$P(^(0),"^",11):$P(^(0),"^",11),1:$O(^DG(40.8,0)))
  1.  I DGDV=0 S DIVFLAG=0 Q
  1.  S DIVISION=$P($G(^DG(40.8,DGDV,0)),U,1)
  1.  I DIVISION="" S DIVFLAG=0 Q
  1.  ;W !,"DIVISION = ",DIVISION
  1.  F DGJ=1:1 S SELDIV=DGUTD(DGJ) D  Q:'$D(DGUTD(DGJ+1))
  1.  .;W !,"SELDIV = ",SELDIV
  1.  .I SELDIV=DIVISION S DIVFLAG=1 Q 
  1.  Q
  1.  ;
  1. BATCH ; -- Entry point for placing cards on hold
  1.  N ZTRTN,ZTDESCO,ZTIO,ZTDTH,ZTSAVE,G
  1.  ;
  1.  S ZTRTN="INSCAN^DGQESC1"
  1.  S ZTDESC="Download Inpatients to VIC work station via HL7"
  1.  S ZTIO=""
  1.  K ZTDTH
  1.  ;D NOW^%DTC S ZTDTH=%
  1.  F G="VAUTD","DFNARR","CNT" S:$D(@G) ZTSAVE(G)=""
  1.  S ZTSAVE("VAUTD(")=""
  1.  D ^%ZTLOAD
  1.  Q
  1.  ;
  1. END ; -- End of Code
  1.  Q
  1.  ;