Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DGRPECE

DGRPECE.m

Go to the documentation of this file. 
  1. DGRPECE ;ALB/MRY,ERC,BAJ - REGISTRATION CATASTROPHIC EDITS ; 10/4/06 3:27pm
  1.  ;;5.3;PIMS;**638,682,700,720,653,688,1015,1016**;JUN 30, 2012;Build 20
  1.  ;
  1. CEDITS(DFN) ;catastrophic edits  - buffer values, save after check
  1.  ;Input;
  1.  ;  DFN  := patient ien
  1.  ;Catastrophic edits will prompt for name, ssn, dob, and sex.  Placing
  1.  ;responses into a buffer space.  User will be alerted on catastrophic
  1.  ;edits on the following conditions:
  1.  ; 1. Two or more catastrophic edits will generate a warning message.
  1.  ; 2. Acceptance of two or more catastrophic edits will generate an alert
  1.  ; to appropriate supervising staff holding the DG CATASTROPHIC EDIT key.
  1.  ; 3. Acceptance of <2 catastrophic edits will process normally.
  1.  ;
  1.  ; Arrays: BEFORE - Holds patient values before the edit process
  1.  ;                  (before snapshot).
  1.  ;         BUFFER - initialized with BEFORE array, holds edited changes
  1.  ;                  (after snapshot).
  1.  ;         SAVE   - holds only edited changes for filing into file #2.
  1.  ;
  1.  N DA,DIR,DIRUT,Y,BUFFER,BEFORE,SAVE,DG20IEN,XUNOTRIG
  1.  D BEFORE(DFN,.BEFORE,.BUFFER) ;retrieve before patient values
  1.  ;buffer - get name
  1.  K DG20NAME
  1.  S BUFFER("NAME")=$$NCEDIT^DPTNAME(DFN,,.DG20NAME)
  1.  I BUFFER("NAME")="" S BUFFER("NAME")=BEFORE("NAME")
  1.  I $D(DG20NAME("FAMILY")) S BUFFER("FAMILY")=DG20NAME("FAMILY")
  1.  I $D(DG20NAME("GIVEN")) S BUFFER("GIVEN")=DG20NAME("GIVEN")
  1.  I $D(DG20NAME("MIDDLE")) S BUFFER("MIDDLE")=DG20NAME("MIDDLE")
  1.  I $D(DG20NAME("SUFFIX")) S BUFFER("SUFFIX")=DG20NAME("SUFFIX")
  1.  ; the formal name is last name, first name, middle name and suffix
  1.  ; the prefix and degree are only stored in file 20
  1.  I $D(DG20NAME("PREFIX")) S BUFFER("PREFIX")=DG20NAME("PREFIX")
  1.  I $D(DG20NAME("DEGREE")) S BUFFER("DEGREE")=DG20NAME("DEGREE")
  1.  K DG20NAME
  1.  ;DG*5.3*688 BAJ if SSN is verified, do not allow edits
  1.  I BEFORE("SSNV")="VERIFIED" D  G DOB
  1.  . S BUFFER("SSN")=BEFORE("SSN")
  1.  . W !,"SSN: "_BUFFER("SSN")
  1.  . W !,"SOCIAL SECURITY NUMBER "_BUFFER("SSN")_" has been verified by SSA --NO EDITING"
  1.  ;
  1.  ;buffer - get ssn
  1.  S DIR(0)="2,.09^^"
  1.  S DA=DFN D ^DIR
  1.  I $D(DIRUT) D CECHECK Q
  1.  S BUFFER("SSN")=Y
  1.  ;if SSN is pseudo, Pseudo SSN Reason is req. - DG*5.3*653, ERC
  1.  I $G(BUFFER("SSN"))["P" D  I $D(DIRUT) D CECHECK Q
  1. REAS . ;
  1.  . N DGREA,DGQSSN,DIR
  1.  . S DGQSSN=0
  1.  . S DGREA=$P($G(^DPT(DFN,"SSN")),U)
  1.  . S DIR(0)="2,.0906^^"
  1.  . S DA=DFN
  1.  . D ^DIR
  1.  . I ($D(DUOUT)!($D(DTOUT))!($D(DIRUT))),($G(BUFFER("SSNREAS"))']"") D
  1.  . . W !?10,"PSSN Reason Required if SSN is a Pseudo."
  1.  . . I $G(BEFORE("SSN"))["P" G REAS
  1.  . . I $G(BEFORE("SSN"))']"" G REAS
  1.  . . S DIR(0)="YA",DIR("A")="          Delete Pseudo SSN?: ",DIR("?")="If the SSN is a Pseudo SSN there must be a Pseudo SSN Reason.",DIR("B")="YES"
  1.  . . D ^DIR
  1.  . . I Y=1 S BUFFER("SSN")=BEFORE("SSN"),DGQSSN=1,Y="" Q
  1.  . . G REAS
  1.  . I DGQSSN=1 Q
  1.  . S BUFFER("SSNREAS")=Y
  1.  . I $D(DIRUT)!('$D(BUFFER("SSN"))) D CECHECK Q
  1. DOB ;buffer - get dob
  1.  S DIR(0)="2,.03^^"
  1.  S DA=DFN D ^DIR
  1.  I $D(DIRUT) D CECHECK Q
  1.  S BUFFER("DOB")=Y
  1. SEX ;buffer - get sex
  1.  S DIR(0)="2,.02^^"
  1.  S DA=DFN D ^DIR
  1.  I $D(DIRUT) D CECHECK Q
  1.  S BUFFER("SEX")=Y
  1. MBI ; buffer - get MBI (multiple birth indicator)
  1.  S DIR(0)="2,994^^"
  1.  S DA=DFN D ^DIR
  1.  S BUFFER("MBI")=Y
  1.  I $D(DIRUT) D CECHECK Q
  1. CECHECK ;do catastrophic edit checks, alert, and save
  1.  N DGCNT,DGCEFLG
  1.  ;Compare before/buffer arrays, putting edits into save array.
  1.  S DGCNT=$$AFTER(.BEFORE,.BUFFER,.SAVE)
  1.  ;   DGCNT:  0  = no changes
  1.  ;           1  = only one edit change, ok to save w/o CE message
  1.  ;           >1 = more then 1 edit, give CE message
  1.  I DGCNT>1 D  ;give CE message
  1.  . S DGCEFLG=$$WARNING()
  1.  . ;    DGCEFLG: 0  = exit without saving changes
  1.  . ;             1  = send alert and save
  1.  . I DGCEFLG=0 S DGCNT=0
  1.  I DGCNT>0 D SAVE(DFN) I $D(DGCEFLG),DGCEFLG D ALERT
  1.  Q
  1.  ;
  1. SAVE(DFN) ;store accepted/edited values into patient file
  1.  N FDATA,DIERR
  1.  I $D(SAVE("NAME")) S FDATA(2,+DFN_",",.01)=SAVE("NAME")
  1.  I $D(SAVE("DOB")) S FDATA(2,+DFN_",",.03)=SAVE("DOB")
  1.  I $D(SAVE("SEX")) S FDATA(2,+DFN_",",.02)=SAVE("SEX")
  1.  I $D(SAVE("SSN")) S FDATA(2,+DFN_",",.09)=SAVE("SSN")
  1.  I $D(SAVE("SSNREAS")) S FDATA(2,+DFN_",",.0906)=SAVE("SSNREAS")
  1.  I $D(SAVE("MBI")) S FDATA(2,+DFN_",",994)=SAVE("MBI")
  1.  D FILE^DIE("","FDATA","DIERR")
  1.  K FDATA,DIERR
  1.  I '$D(^VA(20,DG20IEN)) S DG20IEN=$$GET1^DIQ(2,+DFN_",",1.01,"I")
  1.  I $D(SAVE("NAME")) D
  1.  .S FDATA(20,+DG20IEN_",",1)=BUFFER("FAMILY")
  1.  .S FDATA(20,+DG20IEN_",",2)=BUFFER("GIVEN")
  1.  .S FDATA(20,+DG20IEN_",",3)=BUFFER("MIDDLE")
  1.  .S FDATA(20,+DG20IEN_",",5)=BUFFER("SUFFIX")
  1.  .S XUNOTRIG=1
  1.  .D FILE^DIE("","FDATA","DIERR")
  1.  .K FDATA,DIERR
  1.  I $D(BUFFER("PREFIX")) S FDATA(20,+DG20IEN_",",4)=BUFFER("PREFIX")
  1.  I $D(BUFFER("DEGREE")) S FDATA(20,+DG20IEN_",",6)=BUFFER("DEGREE")
  1.  I $D(SAVE("PREFIX")) S FDATA(20,+DG20IEN_",",4)=SAVE("PREFIX")
  1.  I $D(SAVE("DEGREE")) S FDATA(20,+DG20IEN_",",6)=SAVE("DEGREE")
  1.  D FILE^DIE("","FDATA","DIERR")
  1.  K FDATA,DIERR
  1.  Q
  1.  ;
  1. BEFORE(IEN,BEF,BUF) ;save original name, ssn, dob, sex, mbi, prefix, degree
  1.  N DG20
  1.  S BEF("NAME")=$$GET1^DIQ(2,+IEN_",",.01),BUF("NAME")=BEF("NAME")
  1.  S BEF("SSN")=$$GET1^DIQ(2,+IEN_",",.09),BUF("SSN")=BEF("SSN")
  1.  ;Get SSN Verification flag DG*5.3*688 BAJ 11/22/2005
  1.  S BEF("SSNV")=$$GET1^DIQ(2,+IEN_",",.0907),BUF("SSNV")=BEF("SSNV")
  1.  S BEF("SSNREAS")=$$GET1^DIQ(2,+IEN_",",.0906),BUF("SSNREAS")=BEF("SSNREAS")
  1.  S BEF("DOB")=$$GET1^DIQ(2,+IEN_",",.03,"I"),BUF("DOB")=BEF("DOB")
  1.  S BEF("SEX")=$$GET1^DIQ(2,+IEN_",",.02,"I"),BUF("SEX")=BEF("SEX")
  1.  S BEF("MBI")=$$GET1^DIQ(2,+IEN_",",994,"I"),BUF("MBI")=BEF("MBI")
  1.  D GETS^DIQ(2,+IEN_",",1.01,"I","DG20")
  1.  S BEF("FAMILY")="",BEF("GIVEN")="",BUF("FAMILY")="",BUF("GIVEN")=""
  1.  S BEF("MIDDLE")="",BEF("SUFFIX")="",BUF("MIDDLE")="",BUF("SUFFIX")=""
  1.  S BEF("PREFIX")="",BEF("DEGREE")="",BUF("PREFIX")="",BUF("DEGREE")=""
  1.  S DG20IEN=DG20(2,+IEN_",",1.01,"I")
  1.  I $$GET1^DIQ(20,+DG20IEN_",",.03)[+IEN D
  1.  . S BEF("FAMILY")=$$GET1^DIQ(20,+DG20IEN_",",1),BUF("FAMILY")=BEF("FAMILY")
  1.  . S BEF("GIVEN")=$$GET1^DIQ(20,+DG20IEN_",",2),BUF("GIVEN")=BEF("GIVEN")
  1.  . S BEF("MIDDLE")=$$GET1^DIQ(20,+DG20IEN_",",3),BUF("MIDDLE")=BEF("MIDDLE")
  1.  . S BEF("SUFFIX")=$$GET1^DIQ(20,+DG20IEN_",",5),BUF("SUFFIX")=BEF("SUFFIX")
  1.  . S BEF("PREFIX")=$$GET1^DIQ(20,+DG20IEN_",",4),BUF("PREFIX")=BEF("PREFIX")
  1.  . S BEF("DEGREE")=$$GET1^DIQ(20,+DG20IEN_",",6),BUF("DEGREE")=BEF("DEGREE")
  1.  ;add some demographic information (before snapshot)
  1.  S BEF("MAIDEN")=$E($$GET1^DIQ(2,+IEN_",",.2403),1,17)
  1.  S BEF("POBCITY")=$E($$GET1^DIQ(2,+IEN_",",.092),1,15)
  1.  S BEF("POBSTATE")=$$GET1^DIQ(2,+IEN_",",.093,"I")
  1.  Q
  1.  ;
  1. AFTER(BEF,BUF,SAV) ;prevent catastrophic edit checks
  1.  N DGCNT,DG20CNT S (DGCNT,DG20CNT)=0
  1.  I $D(BUF("FAMILY")),BUF("FAMILY")'="",BUF("FAMILY")'=BEF("FAMILY") D
  1.  . S DG20CNT=DG20CNT+1
  1.  . S SAV("NAME")=BUF("NAME")
  1.  I $D(BUF("GIVEN")),BUF("GIVEN")'="",BUF("GIVEN")'=BEF("GIVEN") D
  1.  . S DG20CNT=DG20CNT+1
  1.  . S SAV("NAME")=BUF("NAME")
  1.  I $D(BUF("MIDDLE")),BUF("MIDDLE")'=BEF("MIDDLE") D
  1.  . S SAV("NAME")=BUF("NAME") ; minor change doesn't count
  1.  I $D(BUF("SUFFIX")),BUF("SUFFIX")'=BEF("SUFFIX") D
  1.  . S SAV("NAME")=BUF("NAME") ; minor change doesn't count
  1.  I DG20CNT>0 S DGCNT=1
  1.  I $D(BUF("PREFIX")),BUF("PREFIX")'=BEF("PREFIX") D
  1.  . S SAV("PREFIX")=BUF("PREFIX")
  1.  I $D(BUF("DEGREE")),BUF("DEGREE")'=BEF("DEGREE") D
  1.  . S SAV("DEGREE")=BUF("DEGREE")
  1.  I $D(BUF("DOB")),BUF("DOB")'="",BUF("DOB")'=BEF("DOB") D
  1.  . S SAV("DOB")=BUF("DOB"),DGCNT=DGCNT+1
  1.  I $D(BUF("SEX")),BUF("SEX")'="",BUF("SEX")'=BEF("SEX") D
  1.  . S SAV("SEX")=BUF("SEX"),DGCNT=DGCNT+1
  1.  I $D(BUF("SSN")),BUF("SSN")'="",BUF("SSN")'=BEF("SSN") D
  1.  . S SAV("SSN")=BUF("SSN"),DGCNT=DGCNT+1
  1.  I $D(BUF("SSNREAS")),BUF("SSNREAS")'="",BUF("SSNREAS")'=BEF("SSNREAS") D
  1.  . S SAV("SSNREAS")=BUF("SSNREAS")
  1.  I $D(BUF("MBI")),BUF("MBI")'=BEF("MBI") D
  1.  . S SAV("MBI")=BUF("MBI")
  1.  I DGCNT=0,$D(SAV("NAME")) Q 1 ;minor name change (i.e. middle name or suffix)
  1.  I DGCNT=0,$D(SAV("PREFIX"))!($D(SAV("DEGREE"))) Q 1 ; prefix or degree change
  1.  I DGCNT=0,$D(SAV("MBI")) Q 1 ; multiple birth indicator change
  1.  I DGCNT=0 Q 0 ;no changes
  1.  ;DG*750 check audit file for previous changes made during the current day
  1.  I DGCNT=1 D DGAUD^DGRPAUD(DFN,.DGCNT)
  1.  ;Use temp file created in DGRPAUD to get information for other changes
  1.  ;that were made during the day to print on the alert.
  1.  N DGAUDIEN,DGFLD,DGTYP
  1.  S DGAUDIEN=0
  1.  F   S DGAUDIEN=$O(^TMP("DGRPAUD",$J,DFN,DGAUDIEN)) Q:'DGAUDIEN  D
  1.  .S DGFLD=$P(^TMP("DGRPAUD",$J,DFN,DGAUDIEN),U,2),DGTYP=$P(^TMP("DGRPAUD",$J,DFN,DGAUDIEN),U,5)
  1.  .I DGFLD=.01 S BEF("NAME")=DGTYP
  1.  .I DGFLD=.09 S BEF("SSN")=DGTYP
  1.  .I DGFLD=.02 S BEF("SEX")=DGTYP
  1.  .I DGFLD=.03 S BEF("DOB")=DGTYP
  1.  I DGCNT<2 Q 1 ;make one change w/o CE message
  1.  I DGCNT>1 Q 2 ;more than 1 change, send CE message
  1.  K ^TMP("DGRPAUD")
  1.  ;
  1. WARNING() ;CE warning message
  1.  ;Output     0  = exit without saving changes
  1.  ;           1  = send alert and save
  1.  W !!,?25,"**WARNING!!**"
  1.  W !!,"The edits you are about to make, may potentially change the identity of"
  1.  W !,"this patient.  Please verify that you have selected the correct patient"
  1.  W !,"and ensure that supporting documentation exists for these changes.  If"
  1.  W !,"you continue with these edits, an alert will be generated and sent to"
  1.  W !,"your Supervisor and ADPAC, notifying them of the changes."
  1.  N DIR,DGANS,Y
  1.  S DIR(0)="Y",DIR("A")="Do you wish to continue and save your edits:"
  1.  S DIR("B")="NO" D ^DIR K DIR S DGANS=Y
  1.  S DGANS=$S(Y=1:1,1:0) ;0=don't save, 1=save with CE alert
  1.  Q DGANS
  1.  ;
  1. ALERT ;Queue alert
  1.  X ^%ZOSF("UCI") S ZTUCI=Y,ZTRTN="ALERT^DGRPECE1",ZTDTH=$H,ZTIO="",IEN=DFN
  1.  F V="IEN","BEFORE(","BUFFER(","SAVE(","XQY" S ZTSAVE(V)=""
  1.  S ZTDESC="Patient Catastrophic Edits alert" K V,ZTSK N X D ^%ZTLOAD  Q
  1.  ;D ALERT^DGRPECE1(DFN,.BEFORE,.BUFFER,.SAVE)
  1.  Q