Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DGRPTP2

DGRPTP2.m

Go to the documentation of this file. 
  1. DGRPTP2 ;ALB/RMO - Print 10-10T Registration Cont.;10 JAN 1997 09:06 am
  1.  ;;5.3;Registration;**108**;08/13/93
  1.  ;
  1. EN(DFN,DFN1,DGNAM,DGSSN,DGLNE,DGPGE) ;Entry point to print 10-10T cont.
  1.  ; Input  -- DFN      Patient IEN
  1.  ;           DFN1     Disposition multiple IEN  (optional)
  1.  ;           DGNAM    Patient name
  1.  ;           DGSSN    Patient ssn
  1.  ;           DGLNE    Line format array
  1.  ;           DGPGE    Page number
  1.  ; Output -- None
  1.  D INS(DFN,.DGLNE) ;insurance
  1.  D SER(DFN,.DGLNE) ;service branch and number, marital
  1.  D SPO(DFN,.DGLNE) ;spouse, income
  1.  S DGPGE=1 D FT^DGRPTP(DFN,$G(DFN1),.DGLNE,.DGPGE) ;end of first page of form
  1.  D HD^DGRPTP(DGNAM,DGSSN,.DGLNE) ;header
  1.  D EN^DGRPTP3(.DGLNE) ;consent, co-pay, signature block, burden, privacy act
  1.  S DGPGE=2 D FT^DGRPTP(DFN,$G(DFN1),.DGLNE,.DGPGE) ;end of second page of form
  1.  Q
  1.  ;
  1. INS(DFN,DGLNE) ;Insurance
  1.  ; Input  -- DFN      Patient IEN
  1.  ;           DGLNE    Line format array
  1.  ; Output -- None
  1.  N C,DGINS,DGRP,I,Y
  1.  ;
  1.  ;Insurance
  1.  W !,"14A. Do You Have Health Coverage",?40,"|14B. Name of Health Insurance Carrier"
  1.  S DGRP(.31)=$G(^DPT(DFN,.31)) ;insurance
  1.  S Y=$P(DGRP(.31),U,11),C=$P(^DD(2,.3192,0),U,2) D Y^DIQ
  1.  W !,?5,$S(Y'="":Y,1:"UNANSWERED")
  1.  D ALL^IBCNS1(DFN,"DGINS",1,DT)
  1.  S (C,I)=0 F  S I=$O(DGINS(I)) Q:'I  S DGINS=DGINS(I,0) D
  1.  . S C=C+1
  1.  . W:C>1 !
  1.  . W ?40,"|     ",$$POINT^DG1010P0(DGINS,1,36)
  1.  I '$D(DGINS) D
  1.  . W ?40,"|     ","NO ACTIVE (UNEXPIRED) INSURANCE ON FILE FOR THIS APPLICANT"
  1.  W ?131,$C(13) W:DGLNE("ULC")="-" ! W DGLNE("UL")
  1.  Q
  1.  ;
  1. SER(DFN,DGLNE) ;Service branch and number, marital status
  1.  ; Input  -- DFN      Patient IEN
  1.  ;           DGLNE    Line format array
  1.  ; Output -- None
  1.  N C,DGRP,Y
  1.  ;
  1.  ;Service branch and number
  1.  W !,"15. Branch of Service",?33,"|16. Latest Service Number",?65,"|17. Marital Status"
  1.  S DGRP(.32)=$G(^DPT(DFN,.32)) ;military service
  1.  W !?4,$E($$POINT^DG1010P0(DGRP(.32),5,23),1,20)
  1.  W ?33,"|    ",$$DISP^DG1010P0(DGRP(.32),8)
  1.  ;
  1.  ;Marital status
  1.  S DGRP(0)=$G(^DPT(DFN,0)) ;patient
  1.  S Y=$P(DGRP(0),U,5),C=$P(^DD(2,.05,0),U,2) D Y^DIQ
  1.  W ?65,"|    ",$S(Y'="":Y,1:"UNANSWERED")
  1.  W ?131,$C(13) W:DGLNE("ULC")="-" ! W DGLNE("UL")
  1.  Q
  1.  ;
  1. SPO(DFN,DGLNE) ;Spouse and income
  1.  ; Input  -- DFN      Patient IEN
  1.  ;           DGLNE    Line format array
  1.  ; Output -- None
  1.  N C,DGDEP,DGINC,DGINR,DGLYINC,DGREL,DGSP,X,Y
  1.  ;
  1.  ;Spouse's name, ssn
  1.  W !,"18A. Spouse's Name",?65,"|18B. Spouse's Social Security Number"
  1.  D ALL^DGMTU21(DFN,"VS",DT,"IPR")
  1.  S X=$P($G(DGREL("S")),U,2)
  1.  S DGSP(0)=$S(X'="":$G(@(U_$P(X,";",2)_+X_",0)")),1:"")
  1.  I DGSP(0)'="" D
  1.  . W !?5,$$DISP^DG1010P0(DGSP(0),1)
  1.  . S X=$P(DGSP(0),U,9)
  1.  . W ?65,"|     ",$S(X'="":$E(X,1,3)_"-"_$E(X,4,5)_"-"_$E(X,6,10),1:"")
  1.  ELSE  D
  1.  . W !?5,"NOT APPLICABLE"
  1.  . W ?65,"|"
  1.  W ?131,$C(13) W:DGLNE("ULC")="-" ! W DGLNE("UL")
  1.  ;
  1.  ;Year of marriage, number of dependents, income
  1.  W !,"18C. Year of Marriage",?33,"|18D. Number of Dependents",?65,"|19. Last Year's Estimated ""Household"" Taxable Income",!
  1.  I DGSP(0)'="" D
  1.  . W ?5,$$DATENP^DG1010P0($G(^DGPR(408.12,+DGREL("S"),"E",1,0)),1)
  1.  S DGLYINC=$P($G(^DGMT(408.21,+$G(DGINC("V")),0)),U,21)
  1.  W ?33,"|"
  1.  W ?65,"|    ",$S(DGLYINC'="":"$"_DGLYINC,1:"UNANSWERED")
  1.  Q