Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DGVPT

DGVPT.m

Go to the documentation of this file. 
  1. DGVPT ;ALB/MRL - DG POST-INIT DRIVER ; 05 JUN 87
  1.  ;;5.3;Registration;**1015**;Aug 13, 1993;Build 21
  1.  ;
  1. EN ; -- main entry point
  1.  S XQABT4=$H
  1.  I '$D(DGVREL) D VERS^DGVPP G ENQ:'$D(DGVREL)
  1.  S DGVFLD=102 D TIME^DGVPR
  1.  ;
  1.  D LINE^DGVPP,EVTS                   ; protocols
  1.  D LINE^DGVPP,LISTS                  ; list templates
  1.  D EN^DGV53PT                        ; current version specific tasks
  1.  D LINE^DGVPP,TASKS                  ; restore queued times
  1.  D LINE^DGVPP,STAN                   ; std output defaults
  1.  D LINE^DGVPP,^DGVPT2                ; file protection
  1.  D LINE^DGVPP,COMP^DGVPT3            ; re-compile note
  1.  D LINE^DGVPP,OBS                    ; obsolete routine note
  1.  D LINE^DGVPP,CENSUS                 ; annual PTF census dates
  1.  ; -- delete options
  1.  S DGPACK="DG" D LINE^DGVPP,^DGVPT1
  1.  S DGPACK="VA" D ^DGVPT1
  1.  S DGPACK="EDR" D ^DGVPT1
  1.  ;
  1.  S DGVFLD=103 D TIME^DGVPR S ^DG(43,1,"VERSION")=DGVNEW
  1.  S XQABT5=$H
  1.  S X="DGINITY" X ^%ZOSF("TEST") I $T D ^DGINITY
  1.  W !!,*7,">>> Initialization of Version ",DGVNEWVR," of DG Complete."
  1.  W !!,"After you've been up and running for about a week or so we would appreciate"
  1.  W !,"it if you would utilize the 'Transmit/Generate Release Comments' option"
  1.  W !,"of the PIMS package to provide us with your (and your users) initial"
  1.  W !,"impression of this release.  Thank you.",!!
  1. ENQ G Q^DGVPP
  1.  ;
  1. EVTS ;Move DG Options to Protocol File
  1.  S X="" D ^DGONIT
  1.  Q
  1.  ;
  1. LISTS ; -- load list templates
  1.  W !!,">>> List Template installation..."
  1.  D ^DGVLT
  1.  Q
  1.  ;
  1. TASKS ; -- requeue tasked jobs
  1.  I $O(DGTJ(0))'="" W !!,">>> Restoring queued jobs to original state...",! S DGEDIT=1 D RES^DGVPR1 K DGTJ
  1.  K DA,DGI,DIC,DIE,DR,X,Y,DGEDIT
  1.  Q
  1.  ;
  1. STAN ;Set-up standard output template defaults
  1.  W !!,">>> Setting standard output template defaults...",! D STAN^DGTEMP
  1.  Q
  1.  ;
  1.  ;
  1. OBS ;List Obsolete Routines
  1.  Q:'$O(^DG(48,DGVREL,"DR",0))
  1.  W !!,">>> The following routines are considered obsolete with this release and may",!?4,"be removed from your system when time permits.  They are no longer",!?4,"supported by the development ISC.",!!?4
  1.  S C=0 F I=0:0 S I=$O(^DG(48,DGVREL,"DR",I)) Q:'I  S X=$P(^(I,0),"^",1),X=$E(X_"          ",1,10),C=C+1 W:'(C#7) !?4 W X
  1.  W !!,"NOTE:  If you would like to have the module automatically delete these routines,",!?7,"you can call DEL^DGVPT1 after initialization of this version is",!?7,"completed."
  1.  Q
  1.  ;
  1. CENSUS ;--- add new census date
  1.  ;    These dates should be update each year per MAS VACO.
  1.  ;
  1.  N CENDATE,CLOSDATE,OKTOXM,ACTIVE,CPSTART
  1.  ;
  1.  ;-- ALL DATES ARE FOR '93 CENSUS
  1.  ;
  1.  ;-- Census Date 9-30-93
  1.  S CENDATE=2930930
  1.  ;-- Close-out Date 11-1-93
  1.  S CLOSDATE=2931101
  1.  ;-- ok to x-mit PTF date 11-22-93
  1.  S OKTOXM=2931122
  1.  ;-- currently active
  1.  S ACTIVE=1
  1.  ;-- Census Period Start Date 10-1-92
  1.  S CPSTART=2921001
  1.  ;
  1.  W !!,">>> Updating Census Dates..."
  1.  ;
  1.  S X=$O(^DG(45.86,"AC",0)) I X S X=$O(^DG(45.86,"AC",X,0)),DIE="^DG(45.86,",DA=X,DR=".04////0" D ^DIE K DIE,DR,DA
  1.  S DIC="^DG(45.86,",X=CENDATE,DIC(0)="L" K DD,DO D ^DIC K DIC
  1.  S DIE="^DG(45.86,",DA=+Y,DR=".02////"_CLOSDATE_";.03////"_OKTOXM_";.04////"_ACTIVE_";.05////"_CPSTART
  1.  D ^DIE K DIE,DR,DA
  1.  ;
  1.  W "Done."
  1.  Q
  1.  ;