Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DIEH

DIEH.m

Go to the documentation of this file. 
  1. DIEH ;SFISC/DPC-HELP ;11/9/94  14:23
  1.  ;;22.0;VA FileMan;;Mar 30, 1999
  1.  ;Per VHA Directive 10-93-142, this routine should not be modified.
  1. GET(DIEHF,DIEHIEN,DIEHFLD,DIEHFLG,DIEHOUT) ;
  1. GETX ;
  1.  N DIEHZ,DIEHD,DIEHEXIT,DIEHPF,DIEHUFLG
  1.  S DIEHUFLG=$G(DIEHFLG)
  1.  I '$G(DIQUIET) N DIQUIET S DIQUIET=1
  1.  I '$G(DIFM) N DIFM S DIFM=1 D INIZE^DIEFU
  1.  I $G(DIEHIEN)]"" N DA,C,D,I D DA^DIEFU(DIEHIEN,.DA) S C=$L(DIEHIEN,",")-1 F I=1:1:C S D="D"_(C-I) N @D S @D=$P(DIEHIEN,",",I)
  1.  S DIEHZ=$$ZERO(DIEHF,DIEHFLD) I DIEHZ=0 G GETOUT
  1.  S DIEHD=$P(DIEHZ,U,2)
  1.  D BLDFLGS G:$G(DIEHEXIT) GETOUT
  1.  I DIEHD["P" S DIEHPF=+$P(DIEHD,"P",2)
  1.  S DIHELP=+$O(^TMP("DIHELP",$J,""),-1)
  1.  I DIEHUFLG["F",DIEHFLD=.01 D PXREFS(DIEHF,DIEHFLD)
  1.  I DIEHUFLG["H" D HPROMPT(DIEHF,DIEHFLD)
  1.  I DIEHUFLG["X" D XHLP(DIEHF,DIEHFLD)
  1.  I DIEHUFLG["D" D DESCR(DIEHF,DIEHFLD)
  1.  I DIEHUFLG["P" D SCRNDES(DIEHF,DIEHFLD)
  1.  I DIEHUFLG["C" D SCRNDES(DIEHF,DIEHFLD)
  1.  I DIEHUFLG["T" N DIEHDT S DIEHDT=$P($P($P(DIEHZ,U,5,99),"%DT=""",2),"""",1)  D DT^DIEH1(DIEHDT)
  1.  I DIEHUFLG["S" D SCRNCD(DIEHF,DIEHFLD,DIEHZ)
  1.  I DIEHUFLG["U" D UNSCRNCD(DIEHZ)
  1.  I DIEHUFLG["V" D VPMSG(DIEHF,DIEHFLD)
  1.  I DIEHUFLG["B",DIEHUFLG'["b" D BLD^DIALOG(9115)
  1.  I DIEHUFLG["M" D BLD^DIALOG(9116)
  1.  I DIEHUFLG["G",DIEHFLG'["g",$G(DIEHPF) D FOLLOW(DIEHPF,DIEHFLG)
  1.  I '$G(DIHELP) K DIHELP
  1. GETOUT I $D(DIEHOUT) D CALLOUT^DIEFU(DIEHOUT)
  1.  Q
  1.  ;
  1. BLDFLGS ;
  1.  N A1,A2,C1,C2,DIEHGFLG
  1.  S C1="HX",C2="XD",(A1,A2)=""
  1.  I DIEHD S DIEHF=+DIEHD,DIEHFLD=.01,DIEHD=$P(^DD(DIEHF,.01,0),U,2)
  1.  I DIEHD["W" S (A1,A2)="HD"
  1.  E  I DIEHD["D" S (A1,A2)="T"
  1.  E  I DIEHD["S" S A1="CS",A2="S",DIEHGFLG="U"
  1.  E  I DIEHD["P" S A1="PG",A2="G",DIEHGFLG="F"
  1.  E  I DIEHD="V" S A1="VB",A2="VMB"
  1.  I DIEHFLD=.01,'$D(^DD(DIEHF,0,"UP")) S A1=A1_"F",A2=A2_"F"
  1.  I DIEHUFLG'["r",'$$VERFLG^DIEFU(DIEHUFLG,"bgA?"_C1_C2_A1_A2_$G(DIEHGFLG)) S DIEHEXIT=1
  1.  I DIEHUFLG["??" S DIEHUFLG=DIEHUFLG_C2_A2
  1.  E  I DIEHUFLG["?" S DIEHUFLG=DIEHUFLG_C1_A1
  1.  E  I DIEHUFLG["A" S DIEHUFLG=$TR(C1_C2_A1_A2,"S","U")
  1.  Q
  1.  ;
  1. ZERO(F,D) ;
  1.  I '$$VFILE^DIEFU(F,"D") Q 0
  1.  I '$$VFIELD^DIEFU(F,D,"D") Q 0
  1.  Q ^DD(F,D,0)
  1.  ;
  1. BN ;Insert blank node.
  1.  S:DIHELP DIHELP=DIHELP+1,^TMP("DIHELP",$J,DIHELP)=""
  1.  Q
  1.  ;
  1. HPROMPT(F,D) ;
  1.  N T
  1.  S T=$G(^DD(F,D,3))
  1.  I $L(T) D
  1.  . D BN
  1.  . S DIHELP=DIHELP+1,^TMP("DIHELP",$J,DIHELP)=T
  1.  Q
  1.  ;
  1. XHLP(DIEHF,DIEHFLD) ;
  1.  ;DA() and D0,D1,etc. passed thru symbol table.
  1.  N DIEHXH S DIEHXH=$G(^DD(DIEHF,DIEHFLD,4))
  1.  I $L(DIEHXH) D
  1.  . D BN
  1.  . N DIEHECNT S DIEHECNT=$G(DIERR)
  1.  . N DDIOLFLG S DDIOLFLG="H" X DIEHXH
  1.  . I DIEHECNT'=$G(DIERR) D HKERR^DILIBF(DIEHF,"",DIEHFLD,"Xecutable Help")
  1.  Q
  1.  ;
  1. DESCR(F,D) ;
  1.  N L
  1.  S L=$P($G(^DD(F,D,21,0)),U,3)
  1.  I L D
  1.  . D BN
  1.  . N I F I=1:1:L S DIHELP=DIHELP+1,^TMP("DIHELP",$J,DIHELP)=^DD(F,D,21,I,0)
  1.  . Q
  1.  Q
  1.  ;
  1. PXREFS(DIEHF,DIEHFLD) ;
  1.  N DIF,DIFD,DIEHROOT,DIEHIXID,DIEHIXP,DIEHIXNM,DIFULL
  1.  S DIEHIXP=$$FILENM^DIEFU(DIEHF)_" "
  1.  D GETIXNM(DIEHF,.DIEHIXNM)
  1.  S DIF=""
  1.  F  S DIF=$O(DIEHIXNM(DIF)) Q:DIF=""  D  Q:$D(DIFULL)
  1.  . S DIFD=""
  1.  . F  S DIFD=$O(DIEHIXNM(DIF,DIFD)) Q:DIFD=""  D  Q:$D(DIFULL)
  1.  . . I $L(DIEHIXP)+$L(DIEHIXNM(DIF,DIFD))>240 D  Q
  1.  . . . S DIEHIXP=DIEHIXP_", etc     "
  1.  . . . S DIFULL=1
  1.  . . S DIEHIXP=DIEHIXP_DIEHIXNM(DIF,DIFD)_", or "
  1.  S DIEHIXP=$E(DIEHIXP,1,$L(DIEHIXP)-5)
  1.  D BLD^DIALOG(9105,DIEHIXP)
  1.  Q
  1.  ;
  1. GETIXNM(DIEHF,DIEHIXNM) ;
  1.  S DIEHROOT=$$ROOT^DIQGU(DIEHF,"",1)
  1.  S DIEHIXID="Az"
  1.  F  S DIEHIXID=$O(@DIEHROOT@(DIEHIXID)) Q:DIEHIXID=""  D
  1.  . N DIEHIXF,DIEHIXFD
  1.  . S DIEHIXF=$O(^DD(DIEHF,0,"IX",DIEHIXID,"")) Q:DIEHIXF=""
  1.  . S DIEHIXFD=$O(^DD(DIEHF,0,"IX",DIEHIXID,DIEHIXF,"")) Q:DIEHIXFD=""
  1.  . S DIEHIXNM(DIEHIXF,DIEHIXFD)=$$FLDNM^DIEFU(DIEHIXF,DIEHIXFD)
  1.  Q
  1.  ;
  1. SCRNDES(F,D) ;
  1.  N T
  1.  S T=$G(^DD(F,D,12))
  1.  I $L(T) D
  1.  . D BN
  1.  . S DIHELP=DIHELP+1,^TMP("DIHELP",$J,DIHELP)=T
  1.  . Q
  1.  Q
  1.  ;
  1. SCRNCD(F,D,DIEHZ) ;
  1.  N S,DIC,Y,A,T,I
  1.  I $P(DIEHZ,U,2)'["*" D UNSCRNCD(DIEHZ) Q
  1.  S S=$G(^DD(F,D,12.1))
  1.  I S="" D UNSCRNCD(DIEHZ) Q
  1.  D CODES
  1.  I $D(Y) D
  1.  . N DIEHECNT S DIEHECNT=$G(DIERR)
  1.  . X S
  1.  . D BLD^DIALOG(9101)
  1.  . F I=1:1:T D
  1.  . . S Y=$P(Y(I),";",1)
  1.  . . X DIC("S") I  D CODESOUT
  1.  . I DIEHECNT'=$G(DIERR) D HKERR^DILIBF(F,"",D,"set of codes screen")
  1.  Q
  1. UNSCRNCD(DIEHZ) ;
  1.  N Y,A,T,I
  1.  D CODES
  1.  I $D(Y) D
  1.  . D BLD^DIALOG(9101)
  1.  . F I=1:1:T D CODESOUT
  1.  . Q
  1.  Q
  1.  ;
  1. CODES ;
  1.  S A=$P(DIEHZ,U,3)
  1.  I A]"" D
  1.  . S T=$L(A,";")-1
  1.  . F I=1:1:T S Y(I)=$P(A,";",I)
  1.  . Q
  1.  Q
  1.  ;
  1. CODESOUT ;
  1.  S DIHELP=DIHELP+1,^TMP("DIHELP",$J,DIHELP)=$P(Y(I),":",1)_"        "_$P(Y(I),":",2)
  1.  Q
  1.  ;
  1. VPMSG(F,D) ;
  1.  N I,N,P,L
  1.  D BLD^DIALOG(9103)
  1.  S I=0 F  S I=$O(^DD(F,D,"V",I)) Q:I="B"  S N=^(I,0) D
  1.  . S P(1)=$P(N,U,4),P(2)=$P(N,U,2),L=$S(I=1:"",1:"S")
  1.  . D BLD^DIALOG(9117,.P,.P,"",L)
  1.  . Q
  1.  Q
  1.  ;
  1. FOLLOW(DIEHPF,DIEHUFLG) ;
  1.  D GET(DIEHPF,"",.01,DIEHUFLG_"r")
  1.  Q