Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: FHSELA1

FHSELA1.m

Go to the documentation of this file. 
  1. FHSELA1 ;Hines OIFO/RTK - Map GMR Allergy file to Food Prefs ;3/07/2007
  1.  ;;5.5;DIETETICS;**8,12**;Jan 28, 2005;Build 3
  1.  ;
  1.  ;10/16/2007 BAY/KAM FH*5.5*12 Remedy Call 210385 Do not allow
  1.  ;                             user to change Food Preference name or
  1.  ;                             LIKE/DISLIKE field
  1.  ;
  1. CREATE ; Check for any missing Allergy-type FP's or one's not renamed in 115.2
  1.  ; and allow user to create the FP on the fly
  1.  D ^FHSELA2 S NUM=0,FHQUIT=0
  1.  W !!!,"The following Allergy Food Preference titles are not on file."
  1.  W !,"You may use this option to create these Food Preference entries:"
  1.  D CRLIST I NUM=0 W !,"No Food Preferences need to be mapped." D EXIT Q
  1.  I FHQUIT=1 D EXIT Q
  1.  I FHRESP=""!(FHRESP="M") D EXIT Q
  1.  S FHAFPNM=$P(FHLIST(FHRESP),"^",1)
  1.  W !,FHAFPNM," "
  1.  K DIR S DIR("A")="Add to Food Preference file",DIR(0)="Y" D ^DIR
  1.  I $D(DIRUT) D EXIT Q
  1.  I Y'=1 D CREATE Q
  1.  D ADD
  1.  W !!,"  ...done.  ",FHAFPNM," Food Preference has been added!" H 1
  1.  D CREATE Q
  1.  D EXIT Q
  1. CRLIST ;
  1.  W !!?5,"MISSING FOOD PREFERENCE LIST"
  1.  W !?5,"============================"
  1.  S FHSEL=0,FHK=""
  1.  F  S FHK=$O(^TMP($J,"FHALG",FHK)) Q:FHK=""!(FHQUIT=1)!(FHSEL=1)  D
  1.  .S FHFPS=$P(^TMP($J,"FHALG",FHK),";",1,99)
  1.  .S FHZ1="ALLERGY - "_$P(FHFPS,";",1)
  1.  .I $D(^FH(115.2,"B",FHZ1)) Q
  1.  .S NUM=NUM+1,PAD=$S($L(NUM)=1:" ",1:"") W !,PAD,NUM
  1.  .W ?8,FHZ1
  1.  .S FHLIST(NUM)=FHZ1_"^"_FHFPS
  1.  .I NUM#5=0!($O(^TMP($J,"FHALG",FHK))="") D PG Q
  1.  .Q
  1.  I FHQUIT=0,FHSEL=0,NUM#5'=0 D PG Q
  1.  Q
  1. ADD ;
  1.  S FHALGMZ=1
  1.  S X=FHAFPNM K DIC,DO
  1.  S (DIC,DIE)="^FH(115.2,",DIC(0)="L" D FILE^DICN
  1.  ; 10/16/2007 BP/KAM FH*5.5*12 Default DISLIKE and prevent Food Preference name change in the next line
  1.  S (FHDA,DA)=+Y,DR="26;1////D"
  1.  D ^DIE K DA,DIE,DR
  1.  D TRAN^FHSEL1
  1.  Q
  1. PG ;
  1.  S FHRESP="" W ! K DIR
  1.  S DIR("A")="Select Food Preference or 'M' to see more ('^' to EXIT)"
  1.  S DIR(0)="F",DIR("B")="M" D ^DIR I $D(DIRUT) S FHQUIT=1 Q
  1.  S FHRESP=Y
  1.  I FHRESP?1"M" Q
  1.  I FHRESP?1.3N,FHRESP>0,FHRESP<(NUM+1) S FHSEL=1 Q
  1.  W !!,"Select from 1 to ",NUM D PG Q
  1.  Q
  1. MAP ; Map allergies by setting pointers in 115.2 to correct entries in 120.82
  1.  D ^FHSELA2
  1.  S FHK=""
  1.  F  S FHK=$O(^TMP($J,"FHALG",FHK)) Q:FHK=""  D
  1.  .S FHFPS=$P(^TMP($J,"FHALG",FHK),";",1,99)
  1.  .S FHZ1="ALLERGY - "_$P(FHFPS,";",1)
  1.  .I '$D(^FH(115.2,"B",FHZ1)) Q  ;not set-up in 115.2, can't map
  1.  .S FHFPIEN=$O(^FH(115.2,"B",FHZ1,""))
  1.  .S FHALMP=$P(FHFPS,";",2,99) I FHALMP="" Q  ;no allergies to map
  1.  .S FHZ=0 F  S FHZ=FHZ+1 S FHANAM=$P(FHALMP,";",FHZ) Q:FHANAM=""  D
  1.  ..D LOOKUP
  1.  Q
  1. LOOKUP ; Look-up the Allergy in 120.82 and set the pointer
  1.  S FHX=FHANAM
  1.  F FHVAL=0:0 S FHVAL=$O(^GMRD(120.82,"B",FHX,FHVAL)) Q:FHVAL'>0  D
  1.  .I $D(^FH(115.2,FHFPIEN,"ALG","B",FHVAL)) Q  ;pointer already exists
  1.  .S Y=FHVAL K DIC,DO S DA(1)=FHFPIEN,DIC="^FH(115.2,"_DA(1)_",""ALG"","
  1.  .S DIC(0)="L",DIC("P")=$P(^DD(115.2,25,0),U,2),X=+Y
  1.  .D FILE^DICN
  1.  Q
  1. DISPMAP ;
  1.  W !!,"This option can be used to display the Standard GMR Allergy"
  1.  W !,"entries and the Food Preferences they map to.",!! K DIR
  1.  S DIR("A")="Display Map by Allergies or by Food Preferences (A/F): "
  1.  S DIR(0)="SA^A:Allergies;F:Food Preferences" D ^DIR
  1.  I $D(DIRUT) D EXIT Q
  1.  S FHSEL=Y
  1.  D DEV
  1.  Q
  1. DEV ;get device and set up queue
  1.  W ! K %ZIS,IOP S %ZIS="Q" D ^%ZIS Q:POP
  1.  I '$D(IO("Q")) U IO D LISTMAP,^%ZISC,EXIT Q
  1.  S ZTRTN="LISTMAP^FHSELA1",ZTSAVE("FHSEL")=""
  1.  S ZTDESC="GMR Allergy/Food Preference Map Display" D ^%ZTLOAD
  1.  D ^%ZISC K %ZIS,IOP
  1.  D EXIT
  1.  Q
  1. LISTMAP ; List Map by Allergies or by Food Preferences
  1.  I FHSEL="A" D LISTAL Q
  1.  I FHSEL="F" D LISTFP Q
  1.  Q
  1. LISTFP ; List all the Allergy-type Food Pref's and corresponding GMR Allergies
  1.  D ^FHSELA2
  1.  S FHK="" W !!,"ALLERGY TYPE FOOD PREFERENCE MAP"
  1.  W !!,"NFS Food Preference Title",?40,"GMR Standard Allergy(s)"
  1.  W !,"==================================="
  1.  W ?40,"==================================="
  1.  F  S FHK=$O(^TMP($J,"FHALG",FHK)) Q:FHK=""  D
  1.  .S FHFPS=$P(^TMP($J,"FHALG",FHK),";",1,99),FHZ1=$P(FHFPS,";",1)
  1.  .W !,"ALLERGY - ",FHZ1
  1.  .S FHALMP=$P(FHFPS,";",2,99) I FHALMP="" W ?40,"** NONE **" Q
  1.  .S FHZ=0,N=0 F  S FHZ=FHZ+1,FHANAM=$P(FHALMP,";",FHZ) Q:FHANAM=""  D
  1.  ..W ?40,$S(FHZ>1:",",1:"") S N=N+$L(FHANAM)+1 W:N>40 !?40 S:N>40 N=0 W FHANAM I N=0 S N=N+$L(FHANAM)+1
  1.  D EXIT Q
  1. LISTAL ; List all the GMR Allergies and the Food Pref to map to
  1.  D ^FHSELA2
  1.  S FHK="" W !!,"GMR STANDARD FOOD ALLERGY MAP"
  1.  W !!,"GMR Allergy Name",?25,"Corresponding NFS Food Preference"
  1.  W !,"=======================",?25,"===================================="
  1.  F  S FHK=$O(^TMP($J,"FHALG",FHK)) Q:FHK=""  D
  1.  .S FHFPS=$P(^TMP($J,"FHALG",FHK),";",1,99),FHZ1=$P(FHFPS,";",1)
  1.  .S FHALMP=$P(FHFPS,";",2,99) I FHALMP="" Q
  1.  .S FHZ=0,N=0 F  S FHZ=FHZ+1,FHANAM=$P(FHALMP,";",FHZ) Q:FHANAM=""  D
  1.  ..S ^TMP($J,"FHAL",FHANAM)="ALLERGY - "_FHZ1
  1.  S FHANAMZ=""
  1.  F  S FHANAMZ=$O(^TMP($J,"FHAL",FHANAMZ)) Q:FHANAMZ=""  D
  1.  .W !,FHANAMZ,?25,"...maps to: ",^TMP($J,"FHAL",FHANAMZ)
  1.  D EXIT Q
  1. MISSING ; List all Food Pref's with no pointers to 120.82
  1.  D ^FHSELA2
  1.  S FHK=""
  1.  F  S FHK=$O(^TMP($J,"FHALG",FHK)) Q:FHK=""  D
  1.  .S FHFPS=$P(^TMP($J,"FHALG",FHK),";",1,99),FHZ1=$P(FHFPS,";",1)
  1.  .I $P(FHFPS,";",2)'="" Q
  1.  .W !?5,"ALLERGY - ",FHZ1," does not have corresponding 120.82 entries"
  1.  D EXIT Q
  1. CHECK ; Check for any missing Allergy-type FP's or one's not renamed in 115.2
  1.  D ^FHSELA2
  1.  S FHK="",FLG=0
  1.  W !,"The following Food Preferences titles were not found in file #115.2:"
  1.  F  S FHK=$O(^TMP($J,"FHALG",FHK)) Q:FHK=""  D
  1.  .S FHFPS=$P(^TMP($J,"FHALG",FHK),";",1,99)
  1.  .S FHZ1="ALLERGY - "_$P(FHFPS,";",1)
  1.  .I '$D(^FH(115.2,"B",FHZ1)) W !,FHZ1 S FLG=1
  1.  I FLG=0 W !,"ALL FOOD PREFERENCES HAVE BEEN RENAMED!"
  1.  D EXIT Q
  1.  ;
  1. UPDATE ;Update Food Preferences for all Patient's based on Allergies
  1.  D ^FHSELA2 S FHCOUNT=0,FHQT=0
  1.  W !!,"...Updating Patient Food Preferences based on Food-Type Allergies"
  1.  W "..." K FHMISS F FHDFN=0:0 S FHDFN=$O(^FHPT(FHDFN)) Q:FHDFN'>0  D
  1.  .S FHCOUNT=FHCOUNT+1 I FHCOUNT#100=0 W "."
  1.  .D GETZN^FHOMUTL I FILE'="P" Q
  1.  .S DFN=IEN D ALG^FHCLN I '$O(^TMP($J,"FHGMRAL","")) Q
  1.  .F FHGMRN=0:0 S FHGMRN=$O(^TMP($J,"FHGMRAL",FHGMRN)) Q:FHGMRN=""  D UPDFP1^FHWGMR
  1.  I $G(FHPST8)=1 K ^TMP($J,"FHGMRAL"),^TMP($J,"FHMISS"),FHGMRN,FHMSAL,FHMSFP,FHMSPT,FHPST8,FHCOUNT Q
  1.  D LIST
  1.  K ^TMP($J,"FHGMRAL"),^TMP($J,"FHMISS"),FHGMRN,FHMSAL,FHMSFP,FHMSPT,FHPST8,FHCOUNT,FHQT
  1.  Q
  1. LIST ;
  1.  I '$D(^TMP($J,"FHMISS")) Q
  1.  W !!,"The following entries need to be mapped in order to automatically"
  1.  W !,"update the Patient Food Preferences:",! S FHCOUNT=0,FHQT=0
  1.  S FHMSFP="" F  S FHMSFP=$O(^TMP($J,"FHMISS",FHMSFP)) Q:FHMSFP=""!(FHQT=1)  D
  1.  .W !,"'ALLERGY - ",FHMSFP,"'" S FHCOUNT=FHCOUNT+1
  1.  .S FHMSPT="" F  S FHMSPT=$O(^TMP($J,"FHMISS",FHMSFP,FHMSPT)) Q:FHMSPT=""  D
  1.  ..S FHMSAL=$P($G(^TMP($J,"FHMISS",FHMSFP,FHMSPT)),U,1)
  1.  ..W !?3,"Patient: ",$E(FHMSPT,1,30),?43,"Allergy: ",FHMSAL
  1.  ..S FHCOUNT=FHCOUNT+1
  1.  ..I FHCOUNT>14 S FHCOUNT=0 W ! K DIR S DIR(0)="E" D ^DIR W ! I X="^" S FHQT=1
  1.  Q
  1. EXIT ;
  1.  D MAP
  1.  K ^TMP($J,"FHALG"),^TMP($J,"FHAL")
  1.  K FHFPIEN,FHK,FHX,FHZ,FHFPS,FHZ1,FHVAL,N,FHANAM,FHANAMZ
  1.  K FHQUIT,NUM,FHRESP,FHAFPNM,FHSEL,PAD,FHLIST,FHALGMZ,FHALMP