Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GMRCSTL7

GMRCSTL7.m

Go to the documentation of this file. 
  1. GMRCSTL7 ;SLC/JFR/WAT - DRIVER FOR CSLT PER MONITOR ;4/8/05 10:28
  1.  ;;3.0;CONSULT/REQUEST TRACKING;**41,60**;DEC 27, 1997;Build 9
  1.  ;
  1.  ;This routine invokes ICRs 
  1.  ;1519(XUTMDEVQ,10103(XLFDT),10104(XLFSTR),3744(VADPT),10089(%ZISC),10026(DIR)
  1.  Q
  1.  ;
  1. EN ; start here
  1.  K GMRCQUT
  1.  N DIROUT,DTOUT,DUOUT,DIR,Y,X,GMRCTMP,GMRCDG,GMRCSVC,GMRCSVNM,GMRCDT1
  1.  N GMRCDT2,GMRCFMT,GMRCGRP,VALMBCK,GMRCSAVE
  1.  N GMRC30ST,GMRC30SP
  1.  D CAVEATS
  1.  ;Ask for service
  1.  S DIR(0)="P^123.5:EMQ",DIR("??")="^D LISTALL^GMRCASV"
  1.  S DIR("A")="Select Service/Specialty"
  1.  D ^DIR
  1.  I $D(DTOUT)!($D(DUOUT))!($D(DIROUT))!(X="") D EXIT Q
  1.  S GMRCDG=+Y,GMRCSVNM=$P(Y,U,2)
  1.   ;Ask for current FY
  1.  N DIROUT,DTOUT,DUOUT,DIR,Y,X,GMRCFY
  1.  S DIR(0)="F^4:4^K:(X-1700)>($E(DT,1,3)+1) X"
  1.  S DIR("A")="Current Fiscal Year (i.e. 2008)"
  1.  S DIR("A",1)="Ensure you are providing fiscal year, NOT calendar year."
  1.  D ^DIR
  1.  I $D(DTOUT)!($D(DUOUT))!($D(DIROUT))!(X="") D EXIT Q
  1.  S GMRCFY=X
  1.  N DIROUT,DTOUT,DUOUT,DIR,Y,X,GMRCQTR,GMRCYR
  1.  S DIR(0)="N^1:4"
  1.  S DIR("A")="Enter a number 1 - 4"
  1.  S DIR("A",1)="For which quarter are you running the report: first, second, third or fourth?"
  1.  D ^DIR
  1.  I $D(DTOUT)!($D(DUOUT))!($D(DIROUT))!(X="") D EXIT Q
  1.  S GMRCQTR=X
  1.  ;if first quarter
  1.  I $G(GMRCQTR)=1 D
  1.  .;use FY-1 to set year part of date range to the previous calendar year
  1.  .S GMRCYR=$G(GMRCFY)-1700 S GMRCYR=$G(GMRCYR)-1,GMRCDT1=$E($G(GMRCYR),1,3)_"1001" S GMRCDT2=$G(GMRCYR)_"1231"
  1.  I $G(GMRCQTR)=2 D
  1.  .S GMRCYR=$G(GMRCFY)-1700 S GMRCDT1=$E($G(GMRCYR),1,3)_"0101" S GMRCDT2=$G(GMRCYR)_"0331"
  1.  I $G(GMRCQTR)=3 D
  1.  .S GMRCYR=$G(GMRCFY)-1700 S GMRCDT1=$E($G(GMRCYR),1,3)_"0401" S GMRCDT2=$G(GMRCYR)_"0630"
  1.  I $G(GMRCQTR)=4 D
  1.  .S GMRCYR=$G(GMRCFY)-1700 S GMRCDT1=$E($G(GMRCYR),1,3)_"0701" S GMRCDT2=$G(GMRCYR)_"0930"
  1.  S GMRC30ST=$$FMADD^XLFDT(GMRCDT1,-30),GMRC30SP=$$FMADD^XLFDT(GMRCDT2,-30)
  1.  ; what type of report
  1.  N DIROUT,DTOUT,DUOUT,DIR,Y,X
  1.  S DIR(0)="S:O^S:Summary;D:Delimited",DIR("A")="What type of report"
  1.  D ^DIR
  1.  I $D(DTOUT)!($D(DUOUT))!($D(DIROUT))!(X="") D EXIT Q
  1.  S GMRCFMT=$S(Y="S":"CP",1:"DEL")
  1.  ;
  1.  W @IOF
  1.  S GMRCSAVE("GMRCFMT")=""
  1.  S GMRCSAVE("GMRCDG")=""
  1.  S GMRCSAVE("GMRCDT1")=""
  1.  S GMRCSAVE("GMRCDT2")=""
  1.  S GMRCSAVE("GMRC30ST")=""
  1.  S GMRCSAVE("GMRC30SP")=""
  1.  S GMRCSAVE("GMRCSVNM")=""
  1.  S GMRCSAVE("GMRCFY")=""
  1.  S GMRCSAVE("GMRCQTR")=""
  1.  ;
  1.  N DIROUT,DTOUT,DUOUT,DIR,Y,X S DIR(0)="FO",DIR("A")="ENTER ""?"" FOR MORE HELP OR RETURN TO CONTINUE"
  1.  S DIR("A",1)="MARGIN WIDTH IS BEST AT 256"
  1.  S DIR("?")="^D MARGHLP^GMRCSTL7"
  1.  D:GMRCFMT="DEL" ^DIR
  1.  I $D(DTOUT)!($D(DUOUT))!($D(DIROUT)) D EXIT Q
  1.  D EN^XUTMDEVQ("PRNTQ^GMRCSTL7","CONSULT PERFORMANCE MONITOR",.GMRCSAVE)
  1.  ;
  1.  D EXIT
  1.  ;
  1.  Q
  1. MARGHLP ;help text to set margins
  1.  W !,"Specify a device with optional parameters in the format"
  1.  W !,?8,"Device Name;Right Margin;Page Length"
  1.  W !,?21,"or"
  1.  W !,?5,"Device Name;Subtype;Right Margin;Page Length"
  1.  W !!,"Or in the new format"
  1.  W !,?14,"Device Name;/settings"
  1.  W !,?21,"or"
  1.  W !,?10,"Device Name;Subtype;/settings"
  1.  W !,"For example"
  1.  W !,?17,"HOME;80;999"
  1.  W !,?21,"or"
  1.  W !,?13,"HOME;C-VT320;/M80L999"
  1.  Q
  1.  ;
  1. ENOR(RETURN,GMRCSVC,GMRC30ST,GMRC30SP,GMRCSTAT,GMRCST2,GMRCARRN) ;Entry point 
  1.  ;.RETURN:   This is the root to the returned temp array.
  1.  ;GMRCSVC:  Service for which consults are to be displayed.
  1.  ;GMRC30ST:  30 days prior to quarter start date
  1.  ;GMRC30SP:  30 days prior to quarter end date
  1.  ;GMRCSTAT: The list of status to include separated by commas
  1.  ;GMRCARRN: Format of report becomes ^TMP array element
  1.  ;          "CP": Summary Report; "DEL": Delimited Report
  1.  ;
  1.  ;This temp array is used internally by the report:
  1.  ;^TMP("GMRCSLIST",$J,n)=ien^name^parient ien^"+" if grouper^status
  1.  ;  status is "" tracking and/or grouper
  1.  ;            1  grouper only
  1.  ;            2  tracking only
  1.  ;            9  disabled
  1.  ;
  1.  N GMRCEDT1,GMRCEDT2,GMRCDG,GMRCHEAD,GMRCGRP,VALMCNT,VALMBCK
  1.  K ^TMP("GMRCR",$J,GMRCARRN)
  1.  S RETURN="^TMP(""GMRCR"",$J,GMRCARRN)"
  1.  I '($D(GMRCSVC)#2) S GMRCSVC=1
  1.  Q:'$D(^GMR(123.5,$G(GMRCSVC),0))
  1.  ;Build service array
  1.  S GMRCDG=GMRCSVC
  1.  D SERV1^GMRCASV
  1.  ;Get external form of date range
  1.  D LISTDATE^GMRCSTU1(GMRCDT1,$G(GMRCDT2),.GMRCEDT1,.GMRCEDT2)
  1.  ;
  1.  N GMRCDA,INDEX,STATUS,STATUS2,LOOP,GROUPER
  1.  N GMRCSVCG,GMRCPT,GMRCSVCP,GRP,PIECE,TYPE
  1.  ;
  1.  K ^TMP("GMRCR",$J,GMRCARRN),^TMP("GMRCRINDEX",$J),^TMP("GMRCT",$J)
  1.  ;
  1.  S GROUPER=0
  1.  S GROUPER(0)=0
  1.  I GMRCARRN="DEL" D
  1.  . N STR
  1.  . S STR="Svc;30DayRng;60DayRng;CmpIn30;Cmp31-60;B4Qtr;PndB4Qtr;%Cmp30;%Cmp60;%UnRsB4Qtr;IS30Rng;IS60Rng;ISCmp30;ISCmp31-60;ISB4Qtr;ISPndB4Qtr;%ISCmp30;%ISCmp60;%ISUnRsB4Qtr;"
  1.  . S STR=STR_"IR30Rng;IR60Rng;IRCmp30;IRCmp31-60;IRB4Qtr;IRPndB4Qtr;%IRCmp30;%IRCmp60;%IRUnRsB4Qtr"
  1.  . S ^TMP("GMRCR",$J,GMRCARRN,1,0)=STR
  1.  S INDEX=""
  1.  ;Loop on Service
  1.  F  S INDEX=$O(^TMP("GMRCSLIST",$J,INDEX)) Q:INDEX=""  D
  1.  .S GMRCSVC=$P(^TMP("GMRCSLIST",$J,INDEX),"^",1)
  1.  .S GMRCSVCP=$P(^TMP("GMRCSLIST",$J,INDEX),"^",2)
  1.  .S GMRCSVCG=$P(^TMP("GMRCSLIST",$J,INDEX),"^",3)
  1.  .N SUBIDX
  1.  .;pieces for tmp arrays, 1 to 6 are local, 7 to 12 are IFC placer, 13 to 18 are IFC filler
  1.  .;;total for 30 day start/end^total for 60 day start/end^results n 30 days^results n 60 days^total before quarter^total pending before quarter
  1.  .S ^TMP("GMRCT",$J,1,GMRCSVC,"DATA")="0^0^0^0^0^0^0^0^0^0^0^0^0^0^0^0^0^0"
  1.  .S ^TMP("GMRCT",$J,2,GMRCSVC,"DATA")="0^0^0^0^0^0^0^0^0^0^0^0^0^0^0^0^0^0"
  1.  .;Check if starting a new Grouper
  1.  .F  Q:GROUPER(GROUPER)=GMRCSVCG  D
  1.  ..;End of a group so print the group totals
  1.  ..I GROUPER(GROUPER)=GMRCSVCG D 
  1.  ... I GMRCARRN="CP" D
  1.  ....D PRTTOT^GMRCSTL8(2,GROUPER(GROUPER),GMRCARRN)
  1.  ...I GMRCARRN="DEL" D
  1.  ....D DELTOT^GMRCSTL8(2,GROUPER(GROUPER),GMRCARRN)
  1.  ..;pop grouper from stack
  1.  ..S GROUPER=GROUPER-1
  1.  .I $P(^TMP("GMRCSLIST",$J,INDEX),"^",4)="+" D
  1.  ..;push new grouper on stack
  1.  ..S GROUPER=GROUPER+1
  1.  ..S GROUPER(GROUPER)=GMRCSVC
  1.  .;Loop for one status at a time
  1.  .F LOOP=1:1:$L(GMRCSTAT,",") S STATUS=$P(GMRCSTAT,",",LOOP) D
  1.  ..D ONESTAT^GMRCSTL8(GMRCARRN,INDEX,STATUS,GMRC30ST,GMRC30SP,"30")
  1.  .F LOOP=1:1:$L(GMRCSTAT,",") S STATUS=$P(GMRCSTAT,",",LOOP) D
  1.  ..D ONESTAT^GMRCSTL8(GMRCARRN,INDEX,STATUS,$$FMADD^XLFDT(GMRC30ST,-30),$$FMADD^XLFDT(GMRC30SP,-30),"60")
  1.  .S GMRCDT1=$$FMADD^XLFDT(GMRC30ST,30) ;add 30 days back to set date back to start of FY quarter.
  1.  .F LOOP=1:1:$L(GMRCST2,",") S STATUS2=$P(GMRCST2,",",LOOP) D
  1.  ..D ONESTAT2^GMRCSTL8(GMRCARRN,INDEX,STATUS2,$$FMADD^XLFDT(GMRCDT1,-60))
  1.  .F GRP=GROUPER:-1:1 D
  1.  ..F PIECE=1:1:18 D
  1.  ...S $P(^TMP("GMRCT",$J,2,GROUPER(GRP),"DATA"),U,PIECE)=$P(^TMP("GMRCT",$J,2,GROUPER(GRP),"DATA"),U,PIECE)+$P(^TMP("GMRCT",$J,1,GMRCSVC,"DATA"),U,PIECE)
  1.  .;
  1.  .;Print the totals for this service that are >0
  1.  .I GMRCARRN="CP" D
  1.  ..D PRTTOT^GMRCSTL8(1,GMRCSVC,GMRCSVCP,GMRCARRN)
  1.  .I GMRCARRN="DEL" D
  1.  ..D DELTOT^GMRCSTL8(1,GMRCSVC,GMRCSVCP,GMRCARRN)
  1.  .Q
  1.  ;
  1.  ;Done, so now list the group totals for the top group
  1.  ;F GROUPER=GROUPER:-1:1 D  ; left for looking at all totals in future
  1.  I $G(GROUPER) S GROUPER=1 D
  1.  .I GMRCARRN="CP" D
  1.  ..D PRTTOT^GMRCSTL8(2,GROUPER(GROUPER),$P(^GMR(123.5,GROUPER(GROUPER),0),"^",1),GMRCARRN)
  1.  .I GMRCARRN="DEL" D
  1.  ..D DELTOT^GMRCSTL8(2,GROUPER(GROUPER),$P(^GMR(123.5,GROUPER(GROUPER),0),"^",1),GMRCARRN)
  1.  Q
  1. PRNTQ   ;Build report and print it
  1.  ;
  1.  N GMRCPG,GMRCTMP,IDX,GMRCQUT,TEMP
  1.  S GMRCPG=1
  1.  D SERV1^GMRCASV
  1.  D HEAD(GMRCPG) S GMRCPG=GMRCPG+1
  1.  S TEMP=$S($G(GMRCQTR)=4:"4",$G(GMRCQTR)=3:"3",$G(GMRCQTR)=2:"2",1:"1")_"Q"_"FY"_$E($G(GMRCFY),3,4)
  1.  S TEMP="Consult/Request Performance Monitor - "_TEMP
  1.  W $J("",40-($L(TEMP)/2)+.5)_TEMP
  1.  S TEMP="Fiscal Quarter Dates: "_$$FMTE^XLFDT(GMRCDT1)_" - "_$$FMTE^XLFDT(GMRCDT2)
  1.  W !,$J("",40-($L(TEMP)/2)+.5)_TEMP
  1.  S TEMP="30 Days Before Start/End: "_$$FMTE^XLFDT(GMRC30ST)_" - "_$$FMTE^XLFDT(GMRC30SP)
  1.  W !,$J("",40-($L(TEMP)/2)+.5)_TEMP
  1.  S TEMP="60 Days Before Start/End: "_$$FMTE^XLFDT($$FMADD^XLFDT(GMRC30ST,-30))_" - "_$$FMTE^XLFDT($$FMADD^XLFDT(GMRC30SP,-30))
  1.  W !,$J("",40-($L(TEMP)/2)+.5)_TEMP,!
  1.  I '$D(IO("Q")) D WAIT^DICD W !!
  1.  I '$O(^TMP("GMRCSLIST",$J,0)) D  G EXIT
  1.  .W !!,"No records to print"
  1.  D ENOR^GMRCSTL7(.GMRCTMP,GMRCDG,GMRC30ST,GMRC30SP,"2,5,6,8,9","1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,99",GMRCFMT)
  1.  I '$D(^TMP("GMRCR",$J,GMRCFMT)) D
  1.  .W !!,"No records to print",!
  1.  S IDX=""
  1.  F  S IDX=$O(^TMP("GMRCR",$J,GMRCFMT,IDX)) Q:'IDX!($G(GMRCQUT))  D
  1.  .I IOSL-$Y<3 D
  1.  ..I $E(IOST,1,2)["C-" D
  1.  ...N DIR S DIR(0)="E" D ^DIR
  1.  ...I 'Y S GMRCQUT=1
  1.  ..Q:$G(GMRCQUT)
  1.  ..D HEAD(GMRCPG) S GMRCPG=GMRCPG+1
  1.  .Q:$G(GMRCQUT)
  1.  .W ^TMP("GMRCR",$J,GMRCFMT,IDX,0),!
  1.  D:$D(^TMP("GMRCR",$J,GMRCFMT)) CAVEATS
  1.  I GMRCFMT="CP",'$G(GMRCQUT) D
  1.  .Q:$O(^TMP("GMRCT",$J,0,""))=""
  1.  .I IOSL-$Y<6 D HEAD(GMRCPG) S GMRCPG=GMRCPG+1
  1.  .W !!!,$$REPEAT^XLFSTR("-",IOM-5)
  1.  .W !,"Consult services not meeting the criteria of this report for",!,"the specified date range:",!
  1.  .S IDX=""
  1.  .F  S IDX=$O(^TMP("GMRCT",$J,0,IDX)) Q:IDX=""!($G(GMRCQUT))  D
  1.  ..I IOSL-$Y<3 D
  1.  ...I $E(IOST,1,2)["C-" D
  1.  ....N DIR S DIR(0)="E" D ^DIR
  1.  ....I 'Y S GMRCQUT=1
  1.  ...Q:$G(GMRCQUT)
  1.  ...D HEAD(GMRCPG) S GMRCPG=GMRCPG+1
  1.  ..Q:$G(GMRCQUT)
  1.  ..W ?4,IDX,!
  1.  D ^%ZISC
  1.  D EXIT
  1.  Q
  1.  ;
  1.  W @IOF
  1.  I PAGE>1 D
  1.  .S TEMP=$S($G(GMRCQTR)=4:"4",$G(GMRCQTR)=3:"3",$G(GMRCQTR)=2:"2",1:"1")_"Q"_"FY"_$E($G(GMRCFY),3,4)
  1.  .S TEMP="Consult/Request Performance Monitor - "_TEMP
  1.  .W !,$J("",40-($L(TEMP)/2)+.5)_TEMP,!
  1.  W !,$J("Run Date: "_$$HTE^XLFDT($H),0),$J("Page: "_PAGE,48)
  1.  W !,$$REPEAT^XLFSTR("-",IOM-2),!!
  1.  Q
  1.  ;
  1. CAVEATS ; brief explanatory text
  1.  W !!,"Resubmitted requests are evaluated based on the original Date of Request."
  1.  W !!,"The following are excluded from this report:"
  1.  W !," -Requests sent to test patients."
  1.  W !," -Requests not marked as Outpatient in the REQUEST/CONSULTATION file."
  1.  W !," -Services flagged as part of the interface between Consults/Request Tracking"
  1.  W !,?2,"and Prosthetics."
  1.  W !," -Administrative requests flagged via the Administrative fields in the"
  1.  W !,?2,"REQUEST SERVICES and REQUEST/CONSULTATION files. This is not retroactive"
  1.  W !,?2,"and only applies to services/requests leveraging the Administrative-flagging"
  1.  W !,?2,"capability included in GMRC*3.0*60, available on or about June 2008.",!!
  1.  Q
  1.  ;
  1. EXIT F ARR="GMRCR","GMRCS","GMRCSLIST","GMRCT" K ^TMP(ARR,$J)
  1.  K ARR
  1.  Q
  1.  ;