Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GMTSADOR

GMTSADOR.m

Go to the documentation of this file.
  1. GMTSADOR ;SLC/KER - Ad Hoc Summary Driver ; 09/21/2001
  1. ;;2.7;Health Summary;**30,35,47**;Oct 20, 1995
  1. ;
  1. ; External References
  1. ; DBIA 10026 ^DIR
  1. ; DBIA 10140 EN^XQORM
  1. ; DBIA 10102 DISP^XQORM1
  1. ;
  1. MAIN ; External call to allow user to define components and
  1. ; defaults through the AD Hoc menu interface and print
  1. ; health summaries for a programmer-specified patient
  1. ; and device. Called with:
  1. ;
  1. ; DFN = Patient internal file record number (optional)
  1. ; For OE/RR interface sets DFN to Patient DFN in
  1. ; the ORVP variable. If not defined a patient
  1. ; will be prompted for.
  1. ;
  1. N C,GMTSEG,GMTSEGI,GMTSEGC,GMTSQIT,GMTSTYP,GMTSTITL,GMW,X,Y,DIC,DIPGM,I,POP,%,GMTSMULT,DIROUT,DUOUT,DTOUT,ZTRTN
  1. S DIC=142,DIC(0)="MZF",X="GMTS HS ADHOC OPTION" S Y=$$TYPE^GMTSULT K DIC Q:+Y'>0 S GMTSTYP=+Y,GMTSTITL="AD HOC"
  1. I $G(DFN)'>0 S DFN=$S($D(ORVP):$P(ORVP,";"),1:"") D:+DFN'>0 SELPT^GMTS
  1. Q:+($G(DFN))'>0 F K GMTSEG,GMTSEGI,GMTSEGC D BUILD Q:$D(GMTSQIT)!($D(DIROUT)) D HSOUT^GMTS,END^GMTS S:$D(DTOUT) GMTSQIT="" Q:$D(GMTSQIT)!($D(DIROUT))
  1. D END
  1. Q
  1. BUILD ; Conducts Dialogue to build Ad Hoc Summary
  1. N GMI,GMJ,GMW,X,XQORM,Y Q:$D(GMTSQIT)!($D(DIROUT)) W @IOF
  1. S XQORM("S")="I $D(^GMT(142,DA(1),1,DA,0)),($P(^GMT(142.1,$P(^GMT(142,DA(1),1,DA,0),U,2),0),U,6)'=""Y"")"
  1. S XQORM=GMTSTYP_";GMT(142,",XQORM(0)="DA",XQORM("A")="Select COMPONENT(S): ",XQORM("??")="D HELP^GMTSADH" D EN^XQORM I Y'>0 S GMTSQIT="" Q
  1. G:+Y&(X?1"^^".E) BUILD S GMTSEGC=Y,(X,GMI,GMJ)=0 F S GMI=$O(Y(GMI)) Q:'GMI D LOAD
  1. D GETLIM^GMTSADH1
  1. Q
  1. LOAD ; Load enabled components
  1. N SREC,STRN S STRN=+Y(GMI),SREC=^GMT(142,GMTSTYP,1,STRN,0)
  1. LOAD1 ; Load array GMTSEG
  1. S GMJ=GMJ+1,GMTSEG(GMJ)=SREC,GMTSEGI($P(SREC,U,2))=GMJ D LOADSEL
  1. Q
  1. LOADSEL ; Loads GMTSEG(J,FN,IFN) (Selection Items)
  1. N S2,SEL,SR,SF S S2=0 F S S2=$O(^GMT(142,GMTSTYP,1,STRN,1,S2)) Q:'S2 D
  1. . S SEL=^(S2,0),SR=U_$P(SEL,";",2) Q:SR="^"
  1. . S SF=+$P(@(SR_"0)"),U,2) Q:+SF=0
  1. . S GMTSEG(GMJ,SF,S2)=$P(SEL,";"),GMTSEG(GMJ,SF,0)=SR
  1. Q
  1. END ; Cleans up any residual locals
  1. K GMTSQIT,FROM,GMI,I1,ISVALID,LRDFN,PTR,SEX,TO,VAOA,VASD,VASV,X Q
  1. HELP ; Display Help Text
  1. N GMJ,GMTSTXT,HLP S HLP=$S(X="??":"HTX2",X="?":"HTX1",1:"") I $L(HLP) W ! F GMJ=1:1 S GMTSTXT=$T(@HLP+GMJ) Q:GMTSTXT["ZZZZ" W !,$P(GMTSTXT,";",3,99)
  1. I X="???" W !! D HELP2^GMTSUP1
  1. D REDISP
  1. Q
  1. REDISP ; Ask Whether or not to redisplay menu
  1. N I,DIR,X,Y S DIR(0)="Y",DIR("A")="Redisplay items",DIR("B")="YES" D ^DIR Q:'Y W @IOF
  1. D DISP^XQORM1 W !
  1. Q
  1. HTX1 ; Help Text for "?"
  1. ;; Select ONE or MORE items from the menu, separated by commas.
  1. ;;
  1. ;; Enter: ?? to see HELP for MULTIPLE SELECTION
  1. ;; ??? to see HELP for "^^"-jump
  1. ;;
  1. ;;ZZZZ
  1. HTX2 ; Help Text for ??
  1. ;;
  1. ;; The Health Summary components you select at this prompt create
  1. ;; an ADHOC Health Summary.
  1. ;;
  1. ;; Select ONE or MORE items from the menu, separated by commas.
  1. ;;
  1. ;; ALL items may be selected by typing "ALL".
  1. ;;
  1. ;; EXCEPTIONS may be entered by preceding them with a minus.
  1. ;; For example, "ALL,-THIS,-THAT" selects all but "THIS" and "THAT".
  1. ;;
  1. ;;ZZZZ