Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GMTSOBJ

GMTSOBJ.m

Go to the documentation of this file.
  1. GMTSOBJ ; SLC/KER - HS Object - Create/Test/Display ; 01/06/2003
  1. ;;2.7;Health Summary;**58,63**;Oct 20, 1995
  1. ;
  1. ; External References
  1. ; DBIA 2320 $$DEL^%ZISH
  1. ; DBIA 2320 $$FTG^%ZISH
  1. ; DBIA 2320 $$PWD^%ZISH
  1. ; DBIA 2320 CLOSE^%ZISH
  1. ; DBIA 2320 OPEN^%ZISH
  1. ; DBIA 10006 ^DIC (file #142.5 and #2)
  1. ; DBIA 10013 ^DIK
  1. ; DBIA 2054 $$CREF^DILF
  1. ; DBIA 2054 $$OREF^DILF
  1. ; DBIA 10026 ^DIR
  1. ; DBIA 10103 $$NOW^XLFDT
  1. ;
  1. Q
  1. MGR ; Create/Modify Health Summary Object (Manager)
  1. N GMTSMGR S GMTSMGR="" G OBJ
  1. ;
  1. DEVOBJ ; Create/Modify Health Summary Object (Developer)
  1. N GMTSDEV S GMTSDEV=5000
  1. ;
  1. OBJ ; Create/Modify Health Summary Object
  1. ; Option: GMTS OBJ ENTER/EDIT
  1. ; Create/Modify Health Summary Object
  1. N BOLD,DA,DFN,DIC,DIE,DIR,DIROUT,DLAYGO,DR,DTOUT,DUOUT,GMP,GMTS
  1. N GMTSBLK,GMTSCHD,GMTSCON,GMTSDEC,GMTSDEF,GMTSDIF,GMTSDLD,GMTSDT
  1. N GMTSHDR,GMTSI,GMTSL,GMTSLBL,GMTSLEN,GMTSLIM,GMTSNEW,GMTSO,GMTSOBJ
  1. N GMTSOBN,GMTSPER,GMTSPRO,GMTSPX1,GMTSPX2,GMTSQ,GMTSR,GMTSRDT,GMTSRHD
  1. N GMTST,GMTSTD,GMTSTIM,GMTSTYP,GMTSUNIT,GMTSUNT,GMTSV,GMTSVER,GMTSX
  1. N IOINHI,IOINORM,NORM,OBJ,D,D0,D1,DI,DILN,X,Y
  1. S DIC("S")="I +Y<50000000!(+Y>59999999)" K:+($G(GMTSDEV))=5000 DIC("S")
  1. D OBJ^GMTSOBA
  1. Q
  1. ;
  1. CRE(NAME) ; Create/Modify Health Summary Object named 'NAME'
  1. ;
  1. ; Input NAME Name of Object to Create or Edit
  1. ; Output Internal Entry Number of Object file if
  1. ; found or created
  1. ;
  1. N X,BOLD,DA,DFN,DIC,DIE,DIR,DIROUT,DLAYGO,DR,DTOUT,DUOUT,GMP,GMTS
  1. N GMTSBLK,GMTSCHD,GMTSCON,GMTSDEC,GMTSDEF,GMTSDIF,GMTSDLD,GMTSDT
  1. N GMTSHDR,GMTSI,GMTSL,GMTSLBL,GMTSLEN,GMTSLIM,GMTSNAM,GMTSNEW,GMTSO
  1. N GMTSOBJ,GMTSOBN,GMTSPER,GMTSPRO,GMTSPX1,GMTSPX2,GMTSQ,GMTSR,GMTSRDT
  1. N GMTSRHD,GMTST,GMTSTD,GMTSTIM,GMTSTYP,GMTSUNIT,GMTSUNT,GMTSV,GMTSVER
  1. N GMTSX,IOINHI,IOINORM,NORM,OBJ,D,D0,D1,DI,DILN,Y S GMTSNAM=$G(NAME)
  1. S:'$L(GMTSNAM) GMTSNAM=$$NAME^GMTSOBV("") Q:'$L(GMTSNAM) -1
  1. S DIC("S")="I +Y<50000000!(+Y>59999999)" K:+($G(GMTSDEV))=5000 DIC("S")
  1. D OBJ^GMTSOBA K DIC S DIC="^GMT(142.5,",DIC(0)="XM",X=GMTSNAM
  1. D ^DIC,CRD^GMTSOBV(+Y),^DIC S X=+Y S:X'>0 X=-1
  1. Q X
  1. ;
  1. TYPE(NAME) ; Edit Health Summary Type named NAME
  1. ;
  1. ; Input NAME Name of Health Summary Type to Edit
  1. ; Output None
  1. D ET^GMTSOBA2($G(NAME))
  1. Q
  1. ;
  1. INQ ; Inquire to Health Summary Object
  1. ; Option: GMTS OBJ INQ
  1. ; Health Summary Object Inquiry
  1. N DIC,D,D0,D1,DI,DILN,GMTSP,GMTSPL,GMTSL,GMTSEXIT
  1. S U="^",DIC="^GMT(142.5,",DIC(0)="AEMQF",GMTSP=$G(IOST),GMTSPL=0,GMTSL=0,GMTSEXIT=0
  1. S DIC("A")=" Select Health Summary Object: " D ^DIC K DIC("A")
  1. W:$L($G(IOF)) @IOF W:+($G(Y))>0 ! D:+($G(Y))>0 SO^GMTSOBS(+Y),CONT^GMTSOBS
  1. Q
  1. ;
  1. DEVDEL ; Delete Health Summary Object (Developer)
  1. N GMTSDEV S GMTSDEV=5000
  1. ;
  1. DEL ; Delete Health Summary Object
  1. ; Option: GMTS OBJ DELETE
  1. ; Delete Health Summary Object
  1. N D,D0,D1,DI,DILN,DIC,DIR,DIK,DA,X,Y,GMTSP,GMTSPL,GMTSL,GMTSEXIT S U="^",(DIK,DIC)="^GMT(142.5,",DIC(0)="AEMQF"
  1. I $$UACT^GMTSU2(+($G(DUZ)))'>0 W !!," >> You are not authorized to delete a Health Summary Object." Q
  1. S DIC("A")=" Select Health Summary Object to Delete: "
  1. S DIC("S")="I (+($P($G(^GMT(142.5,+Y,0)),""^"",17))=0!(+($P($G(^GMT(142.5,+Y,0)),""^"",17))=+($G(DUZ))))&(+($P($G(^GMT(142.5,+Y,0)),""^"",20))'>0)"
  1. S:'$D(GMTSDEV) DIC("S")="I +($$DEL^GMTSOBV(+Y))>0"
  1. K:$D(GMTSDEV) DIC("S") I +($G(Y))>50000000,+($G(Y))<59999999,'$D(GMTSDEV) W !," Can not delete a nationally exported object." Q
  1. D ^DIC I +($G(Y))>0 D
  1. . N GMTSDEL,GMTSO S GMTSDEL="" W ! D SO^GMTSOBS(+Y)
  1. . S DA=+Y,GMTSO=$P($G(^GMT(142.5,+Y,0)),"^",1)
  1. . S:$L(GMTSO) GMTSO=" """_GMTSO_""""
  1. . S DIR("B")="NO",DIR(0)="YAO",DIR("A")=" Delete Health Summary Object"_GMTSO_"? "
  1. . S (DIR("?"),DIR("??"))=" Enter either 'Y' or 'N'."
  1. . W ! D ^DIR I +Y>0 D ^DIK
  1. . I '$D(^GMT(142.5,+DA,0)) W !," <deleted>",!
  1. Q
  1. ;
  1. TEST ; Test Health Summary Object
  1. ; Option: GMTS OBJ TEST
  1. ; Test a Health Summary Object
  1. N BOLD,D,D0,D1,DI,DILN,DA,DFN,DIC,DIE,DIR,DIROUT,DLAYGO,DR,DTOUT
  1. N DUOUT,GMP,GMTS,GMTSBLK,GMTSCHD,GMTSCON,GMTSDEC,GMTSDEF,GMTSDIF
  1. N GMTSDLD,GMTSDT,GMTSHDR,GMTSI,GMTSL,GMTSLBL,GMTSLEN,GMTSLIM,GMTSNEW
  1. N GMTSO,GMTSOBJ,GMTSOBN,GMTSPER,GMTSPRO,GMTSPX1,GMTSPX2,GMTSQ,GMTSR
  1. N GMTSRDT,GMTSRHD,GMTST,GMTSTD,GMTSTIM,GMTSTYP,GMTSUNIT,GMTSUNT
  1. N GMTSV,GMTSVER,GMTSX,IOINHI,IOINORM,NORM,OBJ,X,Y
  1. D PAT^GMTSOBV I +($G(DFN))'>0 W !!," No Patient Selected" Q
  1. S GMTSL=$G(IOSL) N IOSL S IOSL=99999999
  1. S DIC="^GMT(142.5,",DIC("A")=" Select HEALTH SUMMARY OBJECT to test: ",U="^"
  1. S DIC(0)="AEMQ" K DLAYGO D ^DIC S GMTSOBJ=+($G(Y))
  1. I +GMTSOBJ'>0 W !!," No Health Summary Object Selected" Q
  1. K ^TMP("GMTSOBJ",$J,DFN) D GET(DFN,GMTSOBJ),DEV^GMTSOBS
  1. Q
  1. ;
  1. EXP ; Export a Health Summary Object
  1. D EN^GMTSOBE
  1. Q
  1. ;
  1. INS ; Install Imported Health Summary Object
  1. D EN^GMTSOBI
  1. Q
  1. ;
  1. GET(DFN,OBJ) ; Get Health Summary Object
  1. ;
  1. ; Input DFN IEN for Patient (#2)
  1. ; OBJ IEN for Health Summary Object (#142.5)
  1. ;
  1. ; Output Global array of Health Summary data
  1. ;
  1. ; ^TMP("GMTSOBJ",$J,DFN,#,0)
  1. ;
  1. K ^TMP("GMTSOBJ",$J,DFN) D ARY(DFN,OBJ,$NA(^TMP("GMTSOBJ",$J,DFN)))
  1. Q
  1. ;
  1. TIU(DFN,OBJ) ; Get Health Summary Object (TIU)
  1. ;
  1. ; Input DFN IEN for Patient (#2)
  1. ; OBJ IEN for Health Summary Object (#142.5)
  1. ;
  1. ; Output Global array of Health Summary data
  1. ;
  1. ; ^TMP("TIUHSOBJ",$J,"FGBL",0)
  1. ; ^TMP("TIUHSOBJ",$J,"FGBL",#,0)
  1. ;
  1. N ERRMSG,HSTYPE
  1. S HSTYPE=$P($G(^GMT(142.5,OBJ,0)),U,3)
  1. I $G(HSTYPE)="" Q "No Health Summary Report Found"
  1. I $D(^GMT(142,HSTYPE,1))'>0 D Q ERRMSG
  1. . S ERRMSG="There are no components in the Health Summary Type: "_$P($G(^GMT(142,HSTYPE,0)),U)
  1. K ^TMP("TIUHSOBJ",$J) D ARY(DFN,OBJ,$NA(^TMP("TIUHSOBJ",$J,"FGBL")))
  1. Q:+($G(^TMP("TIUHSOBJ",$J,"FGBL",0)))>0 "~@"_$NA(^TMP("TIUHSOBJ",$J,"FGBL"))
  1. Q "No Health Summary Report Found"
  1. ;
  1. ARY(DFN,OBJ,ROOT) ; Build Array ROOT
  1. ;
  1. ; Input DFN IEN for Patient (#2)
  1. ; OBJ IEN for Health Summary Object (#142.5)
  1. ; ROOT Closed root (global or local array)
  1. ;
  1. ; Output Array of Health Summary data in ROOT
  1. ;
  1. N GMTSBLK,GMTSFILE,GMTSHFN,GMTSNC,GMTSNCT,GMTSND,GMTSNDT,GMTSNN,GMTSIOM
  1. N GMTSPATH,GMTSPRE,GMTSRT,GMTSRTO,GMTSRTC,GMTSRNN,GMTSRNC,GMTS0,POP,X,Y
  1. Q:$G(^GMT(142.5,+($G(OBJ)),0))="" S GMTSRT=$G(ROOT)
  1. Q:'$L(GMTSRT) Q:$E(GMTSRT,1)'="^"&($E(GMTSRT,1)'?1U)
  1. S GMTSRTO=$$OREF^DILF(GMTSRT),GMTSRTC=$$CREF^DILF(GMTSRT)
  1. Q:'$L(GMTSRTO) Q:'$L(GMTSRTC) Q:'$L($TR(GMTSRTC,")",""))
  1. Q:$E(GMTSRTO,$L(GMTSRTO))'=","&($E(GMTSRTO,$L(GMTSRTO))'="(")
  1. Q:GMTSRTO'[$TR(GMTSRTC,")","") S GMTS0=GMTSRTO_"0)"
  1. S GMTSPATH=$$PWD^%ZISH,GMTSFILE=$J_$TR($$NOW^XLFDT,".","")_".DAT"
  1. D OPEN^%ZISH("WRITEFILE",GMTSPATH,GMTSFILE,"W"),DIS(+($G(DFN)),+($G(OBJ)))
  1. D CLOSE^%ZISH("WRITEFILE") K ^TMP("GMTSOBJ",$J,"OGBL")
  1. S Y=$$FTG^%ZISH(GMTSPATH,GMTSFILE,$NA(^TMP("GMTSOBJ",$J,"OGBL",1)),4)
  1. S GMTSHFN(GMTSFILE)="",Y=$$DEL^%ZISH(GMTSPATH,$NA(GMTSHFN))
  1. S (GMTSBLK,GMTSNCT,GMTSPRE)=0 S GMTSNN="^TMP(""GMTSOBJ"","_$J_",""OGBL"")"
  1. S GMTSNC="^TMP(""GMTSOBJ"","_$J_",""OGBL"","
  1. F S GMTSNN=$Q(@GMTSNN) Q:GMTSNN=""!(GMTSNN'[GMTSNC) D
  1. . S GMTSND=@GMTSNN,GMTSNDT=$$TRIM^GMTSOBV(GMTSND)
  1. . I 'GMTSBLK S:GMTSNDT="" GMTSBLK=1 Q:GMTSBLK
  1. . Q:GMTSPRE&(GMTSNDT="") S GMTSNCT=GMTSNCT+1
  1. . S @(GMTSRTO_GMTSNCT_",0)")=GMTSND
  1. . S @GMTS0=$G(@GMTS0)+1
  1. . S GMTSPRE=$S(GMTSNDT="":1,1:0)
  1. K ^TMP("GMTSOBJ",$J,"OGBL")
  1. Q
  1. ;
  1. SHOW(X) ; Show a Health Summary Object Definition
  1. ;
  1. ; Input X IEN for Health Summary Object (#142.5)
  1. ;
  1. D SO^GMTSOBS(+($G(X)))
  1. Q
  1. EXTRACT(X,ARY) ; Show a Health Summary Object Definition
  1. ;
  1. ; Input X IEN for Health Summary Object (#142.5)
  1. ; Output ARY() Array of fields and values
  1. ; (passed by reference)
  1. ;
  1. ; ARY(IEN,<field #>,"I") = Internal Value
  1. ; ARY(IEN,<field #>,"E") = External Value
  1. ; ARY(IEN,<field #>,"NAME") = Field Name
  1. ; ARY(IEN,<field #>,"PROMT") = Mixed Case of Field Name
  1. ;
  1. D GET^GMTSOBS2(+($G(X)),.ARY)
  1. Q
  1. DEF(X,ARY) ; Extract a Health Summary Object Definition
  1. ;
  1. ; Input X IEN for Health Summary Object (#142.5)
  1. ; Output ARY() Array of fields and values
  1. ; (passed by reference)
  1. ;
  1. ; ARY("D",0) = # of lines in Definition
  1. ; ARY("D",#) = Definition Text
  1. ; ARY("E",0) = # of lines in Example
  1. ; ARY("E",#) = Example Text
  1. ;
  1. D DEF^GMTSOBS(+($G(X)),.ARY)
  1. Q
  1. DIS(DFN,OBJ) ; Display Object
  1. ;
  1. ; Input DFN IEN for Patient (#2)
  1. ; OBJ IEN for Health Summary Object (#142.5)
  1. ;
  1. ; Output Display of Health Summary data
  1. ;
  1. D DIS^GMTSOBS2(+($G(DFN)),$G(OBJ))
  1. Q
  1. STMP ; Show TMP
  1. N GMTSNN,GMTSNC S GMTSNN="^TMP(""GMTSOBJ"","_$J_",""OGBL"")",GMTSNC="^TMP(""GMTSOBJ"","_$J_",""OGBL"","
  1. F S GMTSNN=$Q(@GMTSNN) Q:GMTSNN=""!(GMTSNN'[GMTSNC) W !,GMTSNN,"=",@GMTSNN
  1. Q