Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GMTSPXU2

GMTSPXU2.m

Go to the documentation of this file. 
  1. GMTSPXU2 ;SLC/KKA,SBW - PCE Drivers for visits ; 08/27/2002
  1.  ;;2.7;Health Summary;**2,56**;Oct 20, 1995
  1.  ;
  1.  ; External References
  1.  ;   DBIA 10141  $$VERSION^XPDUTL
  1.  ;   DBIA 10026  ^DIR
  1.  ;   DBIA    17  ^DGPM("ATID1")
  1.  ;   DBIA    17  ^DGPM(  file #405
  1.  ;   DBIA 10103  $$FMTE^XLFDT
  1.  ;   DBIA  1273  VISIT^PXRHS14
  1.  ;                      
  1.  ;                      
  1.  ;   Allows user to choose Outpatient Visits based
  1.  ;   on V files or Inpatient visits based on patient
  1.  ;   movement file.
  1.  N DIR,SEL,DTOUT,DIRUT
  1.  S (GMTSPX2,GMTSPX1)=""
  1.  ;                      
  1.  ;   If PCE not installed just allow for inpatient
  1.  ;   range selection
  1.  I $$VERSION^XPDUTL("PX")'>0 D INPAT^GMTSPXU2(DFN,.GMTSPX2,.GMTSPX1) Q
  1.  S DIR(0)="SO^1:Outpatient Visit Date;2:Admission Date"
  1.  S DIR("?")="Select 1 or 2 or ^ to exit"
  1.  D ^DIR
  1.  Q:$D(DIRUT)!(+$G(Y)'>0)
  1.  S SEL=+Y
  1.  D:SEL=1 OUTPAT^GMTSPXU2(DFN,.GMTSPX2,.GMTSPX1)
  1.  D:SEL=2 INPAT^GMTSPXU2(DFN,.GMTSPX2,.GMTSPX1)
  1.  Q
  1.  ;                      
  1. OUTPAT(DFN,DATEFROM,DATETO) ; Select by Outpatient Visit Date
  1.  N INPDATE,DIRUT,DTOUT
  1.  D OUTLOOK(DFN,.INPDATE)
  1.  Q:INPDATE']""
  1.  I INPDATE]"" S (DATEFROM,DATETO)=$P(INPDATE,".")
  1.  Q
  1. INPAT(DFN,DATEFROM,DATETO) ; Select by Inpatient Visit Date
  1.  N DIRUT,DTOUT
  1.  D INLOOK(DFN,.DATEFROM,.DATETO)
  1.  I DATEFROM']""!(DATETO']"") S (DATEFROM,DATETO)=""
  1.  Q
  1. INLOOK(DFN,GMTSADM,GMTSDC) ; Displays Patient's Admission Dates
  1.  N DIR,Y,X,ADT,RECNR,CTR,HIT,DCDT,ADMDT,SELNR
  1.  S (GMTSADM,GMTSDC)=""
  1.  I '$D(^DGPM("ATID1",DFN)) W !!,"No admissions on file for this patient" Q
  1.  K ^TMP("GMTSPX",$J)
  1.  S (CTR,HIT,ADT,SELNR)=0
  1.  F  S ADT=$O(^DGPM("ATID1",DFN,ADT)) Q:+ADT'>0  D  Q:$D(DIRUT)!+$G(Y)
  1.  . S RECNR=0
  1.  . F  S RECNR=$O(^DGPM("ATID1",DFN,ADT,RECNR)) Q:RECNR'>0  D  Q:$D(DIRUT)!+$G(Y)
  1.  . . S ADMDT=$P(^DGPM(RECNR,0),U)
  1.  . . S DCDT=$P($G(^DGPM(+$P(^DGPM(RECNR,0),U,17),0)),U)
  1.  . . D:'HIT INHDR S HIT=1,SELNR=SELNR+1,CTR=CTR+1
  1.  . . W !,?7,SELNR,?15,$$FMTE^XLFDT(ADMDT,"2P")
  1.  . . W:DCDT]"" ?45,$$FMTE^XLFDT(DCDT,"2P")
  1.  . . S ^TMP("GMTSPX",$J,SELNR)=ADMDT_U_DCDT
  1.  . . I CTR>9 D  Q:$D(DTOUT)!$D(DUOUT)!(+$G(Y)>0)
  1.  . . . S DIR("A")="Enter a number between 1 and "_SELNR_", press return to continue or '^' to exit: "
  1.  . . . S DIR(0)="NOA^1:"_SELNR D ^DIR S CTR=0 W !
  1.  Q:$D(DUOUT)!$D(DTOUT)!$D(DIROUT)
  1.  I SELNR>0,(CTR>0),(CTR'>9)&(+$G(Y)'>0) D
  1.  . S DIR("A")="Enter a number between 1 and "_SELNR_": "
  1.  . S DIR(0)="NOA^1:"_SELNR D ^DIR W !
  1.  Q:$D(DUOUT)!$D(DTOUT)!$D(DIROUT)!(+$G(Y)'>0)
  1.  S GMTSADM=$P($P($G(^TMP("GMTSPX",$J,+Y)),U),".")
  1.  S GMTSDC=$P($P($G(^TMP("GMTSPX",$J,+Y)),U,2),".")
  1.  I GMTSADM]"",GMTSDC="" S GMTSDC=DT
  1.  K ^TMP("GMTSPX",$J)
  1.  Q
  1.  ;                      
  1. INHDR ; Based on the VISIT File
  1.  W !!,?15,"ADMISSION DATE/TIME",?45,"DISCHARGE DATE/TIME",!
  1.  Q
  1.  ;                      
  1. OUTLOOK(DFN,OUT) ; Display Outpatient Visits
  1.  ;                      
  1.  ;   This option displays outpatient visits from the
  1.  ;   Visit (#9000010) file to the screen. Outpatient 
  1.  ;   visits = visits with a service category of:
  1.  ;                      
  1.  ;      Ambulatory
  1.  ;      Observation
  1.  ;      Day Surgery
  1.  ;      Nursing Home
  1.  ;                      
  1.  ;   A number, the visit date, and the hospital location
  1.  ;   or credit stop will be display on the screen. The 
  1.  ;   order of the display will be from most recent visits
  1.  ;   to oldest visits. The user can pick the visit they 
  1.  ;   want and the visit date is passed back to the calling
  1.  ;   routine by parameter passing by reference.  
  1.  ;                        
  1.  N DIR,Y,X,VISITDT,CTR,SELNR,RECNR,CLINIC,HIT,VISIT,HLOC
  1.  S OUT=""
  1.  K ^TMP("HS",$J),^TMP("PXV",$J)
  1.  S (CTR,HIT,SELNR,VISITDT,RECNR)=0
  1.  S VISITDT="",RECNR=""
  1.  F  D VISIT^PXRHS14(DFN,.VISITDT,.RECNR,1,"ASOR") Q:VISITDT'>0  D  Q:$D(DUOUT)!$D(DTOUT)!(+$G(Y)>0)
  1.  . S NODE=$G(^TMP("PXV",$J,VISITDT,RECNR))
  1.  . K ^TMP("PXV",$J)
  1.  . Q:NODE']""
  1.  . S VISIT=$P(NODE,U)
  1.  . S CLINIC=$P(NODE,U,4)
  1.  . S HLOC=$P(NODE,U,6)
  1.  . D:'HIT OUTHDR S HIT=1 S SELNR=SELNR+1,CTR=CTR+1
  1.  . W !,?7,SELNR,?15,$$FMTE^XLFDT(VISIT,"2P"),?45,$S(HLOC]"":HLOC,1:CLINIC)
  1.  . S ^TMP("HS",$J,SELNR)=RECNR_U_VISIT_U_CLINIC_U_HLOC
  1.  . I CTR>9 D  Q:$D(DTOUT)!$D(DUOUT)!(+$G(Y)>0)
  1.  . . S DIR("A")="Enter a number between 1 and "_SELNR_", press return to continue or '^' to exit: "
  1.  . . S DIR(0)="NOA^1:"_SELNR D ^DIR S CTR=0 W !
  1.  I SELNR>0&(CTR>0)&(CTR'>9) D
  1.  . S DIR("A")="Enter a number between 1 and "_SELNR_": "
  1.  . S DIR(0)="NOA^1:"_SELNR D ^DIR W !
  1.  I SELNR'>0 W !!,"No Outpatient visits for this patient" Q
  1.  S OUT=$P($G(^TMP("HS",$J,+$G(Y))),U,2)
  1.  K ^TMP("HS",$J),^TMP("PXV",$J)
  1.  Q
  1. OUTHDR ; Header for screen Display
  1.  W !!,?15,"VISIT DATE/TIME",?45,"HOSPITAL LOCATION/CLINIC",!
  1.  Q