Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GMVCAQU

GMVCAQU.m

Go to the documentation of this file. 
  1. GMVCAQU ;HOIFO/YH,FT-DISPLAY CATEGORY/QUALIFIER/SYNONYM TABLE FOR VITAL TYPE ;10/25/02  10:04
  1.  ;;5.0;GEN. MED. REC. - VITALS;;Oct 31, 2002
  1.  ;
  1.  ; This routine uses the following IAs:
  1.  ; #10103 - ^XLFDT calls           (supported)
  1.  ; #10104 - ^XLFSTR calls          (supported)
  1.  ;
  1. EN1(RESULTS,GMVDATA) ; GMV QUALIFIER TABLE [RPC entry point]
  1.  ; Display Vitals Category/Qualifier/Synonym Table
  1.  ; GMVDEV - device name (File 3.5)
  1.  ; GMVIEN - device internal entry number
  1.  ; GMVPDT - date/time to print report
  1.  ;
  1.  N GMVDEV,GMVIEN,GMVPDT
  1.  S RESULTS=$NA(^TMP($J)) K @RESULTS
  1.  S GMVDEV=$P(GMVDATA,U,5),GMVIEN=+$P(GMVDATA,U,6),GMVPDT=$P(GMVDATA,U,7)
  1.  S ZTIO=GMVDEV ;device
  1.  S ZTDTH=$S($G(GMVPDT)>0:GMVPDT,1:$$NOW^XLFDT()) ;date/time to print
  1.  S ZTDESC="Vitals Category/Qualifier/Synonym Table"
  1.  S ZTRTN="START^GMVCAQU"
  1.  D ^%ZTLOAD
  1.  I $G(ZTSK)>0 S @RESULTS@(0)="1^Report Queued. Task #:"_ZTSK
  1.  E  S @RESULTS@(0)="-1^Unable to queue report."
  1.  K ZTSK,ZTIO,ZTDTH,ZTSAVE,ZTDESC,ZTRTN
  1.  Q
  1. START ; Start the report
  1.  U IO
  1.  S:$D(ZTQUEUED) ZTREQ="@"
  1.  S (GMROUT,GMRPG)=0
  1.  S GMVNOW=$$NOW^XLFDT() ;get current date/time
  1.  S GMVNOW=$$FMTE^XLFDT(GMVNOW) ;format current date/time
  1.  D HDR
  1.  F GMRVIT(1)="BLOOD PRESSURE","PULSE","RESPIRATION","TEMPERATURE","WEIGHT","CIRCUMFERENCE/GIRTH","HEIGHT","PULSE OXIMETRY" Q:GMROUT  D
  1.  .S GMRVIT=$O(^GMRD(120.51,"B",GMRVIT(1),0)) Q:GMRVIT'>0!GMROUT  D
  1.  ..S GMRVITY=$P(^GMRD(120.51,GMRVIT,0),"^",2) Q:GMRVITY=""!GMROUT  S GLVL=8 D LISTQ^GMVQUAL Q:GMROUT  D OTHERQ D CLEAR
  1.  ..Q
  1.  .Q
  1. Q1 ; Kill variables and quit
  1.  K GMRVIT,GMRVITY,GLVL,GMROUT,GMRPG,GSYNO,I,J,POP
  1.  D CLEAR
  1.  D ^%ZISC
  1.  Q
  1. HDR ; Header
  1.  W:$Y>0 @IOF
  1.  S GMRPG=GMRPG+1
  1.  W !,"Vitals/Measurements Category/Qualifier/Synonym Table",?65,"Page ",GMRPG
  1.  W !,"Run Date: ",GMVNOW
  1.  W !,$$RJ^XLFSTR(" ",75,"-")
  1.  W:GMRPG>1 !,GLABEL,!,GLABEL(1)
  1.  Q
  1. CLEAR ; Clean up variables
  1.  K GCHART,GCHART1,GQUAL,GMRVDFLT,GORDER,GLABEL,GFLAG,GMAX,GMIN,GMRLAST,GMRINF,GCAT,GCHA,GCOL,GDA,GENTR,GTXT,GBLNK,GCOUNT,GLN,GMRENTR,GMRVODR,GSIDE,GTYPE,GDASH
  1.  Q
  1. OTHERQ ;
  1.  Q:'$D(GCHART)&('$D(GCHART1))
  1.  S GCOL=1,GFLAG=0,$P(GLABEL," ",80)="",$P(GBLNK," ",80)="",$P(GLABEL(1)," ",80)="",$P(GDASH,"-",20)=""
  1.  S (GMAX,GMAX(1))=0
  1.  F  S GMAX(1)=$O(GCOUNT(GMAX(1))) Q:GMAX(1)'>0  S GMAX(2)="" F  S GMAX(2)=$O(GCOUNT(GMAX(1),GMAX(2))) Q:GMAX(2)=""  I GCOUNT(GMAX(1),GMAX(2))>GMAX S GMAX=GCOUNT(GMAX(1),GMAX(2))
  1.  Q:+$G(GMAX)=0
  1.  F I=1:1:GMAX S $P(GTXT(I)," ",80)=""
  1.  S GMRVODR=0
  1.  F  S GMRVODR=$O(GCOUNT(GMRVODR)) Q:GMRVODR'>0  S GCAT=$O(GCOUNT(GMRVODR,"")) Q:GCAT=""  D
  1.  . S GCOL=$S(GMRVODR=1:1,GMRVODR=2:18,GMRVODR=3:39,GMRVODR=4:58,1:70)
  1.  . I GMRVODR=2,GMRVIT(1)="PULSE" S GCOL=28
  1.  . I GMRVODR=2,GMRVIT(1)="RESPIRATION" S GCOL=32
  1.  . S GLABEL=$S(GMRVODR=1:$E(GCAT_GBLNK,1,80),1:$E($E(GLABEL,1,GCOL)_GCAT_GBLNK,1,80))
  1.  . S GCAT(1)=$E(GDASH,1,$L(GCAT))
  1.  . S GLABEL(1)=$S(GMRVODR=1:$E(GCAT(1)_GBLNK,1,80),1:$E($E(GLABEL(1),1,GCOL)_GCAT(1)_GBLNK,1,80))
  1.  . S I=0,GCHA="" F  S GCHA=$O(GQUAL(GMRVODR,GCHA)) Q:GCHA=""  D
  1.  . . S GSYNO(1)=$O(^GMRD(120.52,"B",GCHA,0)) Q:GSYNO(1)'>0  S GSYNO=$P($G(^GMRD(120.52,GSYNO(1),0)),"^",2)
  1.  . . S I=I+1,GTXT(I)=$S(GMRVODR=1:$E(GCHA_": "_GSYNO_GBLNK,1,80),1:$E($E(GTXT(I),1,GCOL)_GCHA_": "_GSYNO_GBLNK,1,80))
  1.  . . Q
  1.  . Q
  1.  W !!,"Qualifiers for "_GMRVIT(1)_": ",!!,GLABEL,!,GLABEL(1)
  1.  F I=1:1:GMAX D:IOSL<($Y+6) HDR Q:GMROUT  W !,GTXT(I)
  1.  Q