Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GMVDCCHK

GMVDCCHK.m

Go to the documentation of this file. 
  1. GMVDCCHK ;HOIFO/DAD,FT-VITALS COMPONENT: CHECK DATA VALUE ;9/29/00  09:15
  1.  ;;5.0;GEN. MED. REC. - VITALS;;Oct 31, 2002
  1.  ;
  1.  ; This routine uses the following IAs:
  1.  ; #10104 - ^XLFSTR calls            (supported)
  1.  ;
  1. VALID(GMVALUE,GMVMSYS,GMVTYPE) ;
  1.  ; *** Validate a vital measurement ***
  1.  ; Input:
  1.  ;  GMVALUE = The vital measurement to be validated
  1.  ;  GMVMSYS = The measurement system the measurement is expressed in
  1.  ;            (C - US Customary, M - Metric)
  1.  ;  GMVTYPE = A vital type abbreviation
  1.  ; Output:
  1.  ;  0 - Invalid, 1 - Valid
  1.  S GMVTYPE=$$UP^XLFSTR(GMVTYPE)
  1.  I $T(@GMVTYPE)]"" D
  1.  . N GMVCODE,GMVOK
  1.  . S GMVCODE="S GMVOK=$$"_GMVTYPE_"(GMVALUE)"
  1.  . X GMVCODE I 'GMVOK K GMVALUE
  1.  . Q
  1.  E  D
  1.  . K GMVALUE
  1.  . Q
  1.  Q ''$D(GMVALUE)
  1.  ;
  1. AG(X) ; ABDOMINAL GIRTH
  1.  S X=$$CNV^GMVDCCNV(X,GMVMSYS,"S",GMVTYPE)
  1.  K:X'=+X!(X>150)!(X<0)!(X?.E1".".N) X
  1.  Q ''$D(X)
  1.  ;
  1. AUD(X) ; AUDIOMETRY
  1.  N I,Y
  1.  K:X'?.N1"/".N1"/".N1"/".N1"/".N1"/".N1"/".N1"/".N1"/".N1"/".N1"/".N1"/".N1"/".N1"/".N1"/".N1"/".N1"/" X
  1.  I $D(X) F I=1:1:16 S Y=$P(Y,"/",I) I Y]"" I Y'=+Y!(Y>110)!(Y<0) K X Q
  1.  Q ''$D(X)
  1.  ;
  1. BP(X) ; BLOOD PRESSURE
  1.  N I,Y
  1.  K:(X'?1.3N1"/"1.3N1"/"1.3N)&(X'?1.3N1"/"1.3N)&(X'?1.3N) X
  1.  I $D(X) F I=1:1:$L(X,"/") S Y=$P(X,"/",I) I Y]"" I Y<0!(Y>300) K X Q
  1.  I $D(X),(X'?1.3N),$P(X,"/")'>$P(X,"/",$L(X,"/")) K X
  1.  Q ''$D(X)
  1.  ;
  1. CG(X) ; CIRCUMFERENCE/GIRTH
  1.  S X=$$CNV^GMVDCCNV(X,GMVMSYS,"S",GMVTYPE)
  1.  K:X'=+X!(X>200)!(X<0)!(X?.E1"."3.N) X
  1.  Q ''$D(X)
  1.  ;
  1. CVP(X) ; CENTRAL VENOUS PRESSURE
  1.  S X=$$CNV^GMVDCCNV(X,GMVMSYS,"S",GMVTYPE)
  1.  K:X<-13.6!(X>136)!(X?.E1"."2.N) X
  1.  Q ''$D(X)
  1.  ;
  1. FH(X) ; FUNDAL HEIGHT
  1.  S X=$$CNV^GMVDCCNV(X,GMVMSYS,"S",GMVTYPE)
  1.  K:X'=+X!(X>50)!(X<10)!(X?.E1".".N) X
  1.  Q ''$D(X)
  1.  ;
  1. FT(X) ; FETAL HEART TONES
  1.  K:X'=+X!(X>250)!(X<50)!(X?.E1".".N) X
  1.  Q ''$D(X)
  1.  ;
  1. HC(X) ; HEAD CIRCUMFERENCE
  1.  I GMVMSYS="M" D
  1.  . K:+X>76!(+X<26)!(X?.E1"."3.N) X
  1.  . Q
  1.  I GMVMSYS="C" D
  1.  . K:+X>30!(+X<10)!(X?.E1"."4.N) X
  1.  . I $D(X),X#1>0 K:"^.125^.25^.375^.5^.625^.75^.875^"'[(U_(X#1)_U) X
  1.  . Q
  1.  Q ''$D(X)
  1.  ;
  1. HE(X) ; HEARING
  1.  K:"^A^N^"'[(U_X_U) X
  1.  Q ''$D(X)
  1.  ;
  1. HT(X) ; HEIGHT
  1.  S X=$$CNV^GMVDCCNV(X,GMVMSYS,"S",GMVTYPE)
  1.  K:X'=+X!(X>100)!(X<1)!(X?.E1"."3.N) X
  1.  Q ''$D(X)
  1.  ;
  1. P(X) ; PULSE
  1.  K:+X'=X!(X>300)!(X<0)!(X?.E1".".N) X
  1.  Q ''$D(X)
  1.  ;
  1. PN(X) ; PAIN
  1.  K:"^0^1^2^3^4^5^6^7^8^9^10^99^"'[(U_X_U) X
  1.  Q ''$D(X)
  1.  ;
  1. PO2(X) ; PULSE OXIMETRY
  1.  K:X<0!(X>100)!(X?.E1".".N) X
  1.  Q ''$D(X)
  1.  ;
  1. R(X) ; RESPIRATION
  1.  K:X'=+X!(X>100)!(X<0)!(X?.E1".".N) X
  1.  Q ''$D(X)
  1.  ;
  1. T(X) ; TEMPERATURE
  1.  S X=$$CNV^GMVDCCNV(X,GMVMSYS,"S",GMVTYPE)
  1.  K:X'=+X!(X>120)!(X<45)!(X?.E1"."3.N) X
  1.  Q ''$D(X)
  1.  ;
  1. TON(X) ; TONOMETRY
  1.  N I,Y
  1.  K:(X'?1.2N1"/"1.2N)&(X'?1.2N1"/")&(X'?1"/"1.2N) X
  1.  I $D(X) F I=1,2 S Y=$P(X,"/",I) I Y]"" I Y'=+Y!(Y>80)!(Y<0) K X Q
  1.  Q ''$D(X)
  1.  ;
  1. VC(X) ; VISION CORRECTED
  1.  N I,Y
  1.  K:(X'?1.3N1"/"1.3N)&(X'?1.3N1"/")&(X'?1"/"1.3N) X
  1.  I $D(X) F I=1,2 S Y=$P(X,"/",I) I Y]"" I Y'=+Y!(Y>999)!(Y<10) K X Q
  1.  Q ''$D(X)
  1.  ;
  1. VU(X) ; VISION UNCORRECTED
  1.  Q $$VC(X)
  1.  ;
  1. WT(X) ; WEIGHT
  1.  S X=$$CNV^GMVDCCNV(X,GMVMSYS,"S",GMVTYPE)
  1.  K:X'=+X!(X>1500)!(X'>0)!(X?.E1"."3.N) X
  1.  Q ''$D(X)