Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: HDISVF04

HDISVF04.m

Go to the documentation of this file. 
  1. HDISVF04 ;ALB/RMO - 7118.11 File Utilities/API Cont.; 1/10/05@11:37:00
  1.  ;;1.0;HEALTH DATA & INFORMATICS;;Feb 22, 2005
  1.  ;
  1.  ;---- Begin HDIS Term/Concept VUID Association file (#7118.11) API(s) ----
  1.  ;
  1. GETTERM(HDISTERM,HDISFARY,HDISTIEN) ;Get a Term/Concept Entry by Term/Concept and File/Field
  1.  ; Input  -- HDISTERM Term/Concept Text
  1.  ;           HDISFARY File/Field Array - Pass by HDISFARY(HDIS File/Field file #7115.6 IEN)=""
  1.  ; Output -- 1=Successful and 0=Failure
  1.  ;           If Successful:
  1.  ;           HDISTIEN HDIS Term/Concept VUID Association file IEN
  1.  N HDISFIEN,HDISI
  1.  ;Initialize output
  1.  S HDISTIEN=""
  1.  ;Check for missing variables, exit if not defined
  1.  I '$D(HDISTERM)!('$D(HDISFARY)) G GETTERMQ
  1.  ;Check for existing Term/Concept and File/Field
  1.  S HDISFIEN=0
  1.  F  S HDISFIEN=$O(HDISFARY(HDISFIEN)) Q:'HDISFIEN  D
  1.  . I $D(^HDISV(7118.11,"AC",HDISFIEN)) D
  1.  . S HDISI=0
  1.  . F  S HDISI=$O(^HDISV(7118.11,"AC",HDISFIEN,HDISI)) Q:'HDISI!($G(HDISTIEN))  D
  1.  . . I $D(^HDISV(7118.11,HDISI,0)),$P(^(0),"^",1)=HDISTERM D
  1.  . . . S HDISTIEN=HDISI
  1. GETTERMQ Q +$S($G(HDISTIEN)>0:1,1:0)
  1.  ;
  1. ADDTERM(HDISTERM,HDISVUID,HDISFARY,HDISNTLF,HDISCKTF,HDISEDTM,HDISSTAT,HDISTIEN,HDISERRM) ;Add a New Term/Concept Entry
  1.  ; Input  -- HDISTERM Term/Concept Text
  1.  ;           HDISVUID VUID
  1.  ;           HDISFARY File/Field Array - Pass by HDISFARY(HDIS File/Field file #7115.6 IEN)=""
  1.  ;           HDISNTLF National Standard Flag  (Optional- Default 0)
  1.  ;                    1=Yes and 0=No
  1.  ;           HDISCKTF Check for Existing Term/Concept Flag  (Optional- Default 1)
  1.  ;                    1=Yes and 0=No
  1.  ;           HDISEDTM Effective Date/Time  (Optional- Default NOW)
  1.  ;           HDISSTAT Status  (Optional- Default 0)
  1.  ;                    1=Active and 0=Inactive
  1.  ; Output -- 1=Successful and 0=Failure
  1.  ;           If Successful:
  1.  ;           HDISTIEN HDIS Term/Concept VUID Association file IEN
  1.  ;           If Failure:
  1.  ;           HDISERRM Error Message  (Optional)
  1.  N HDISCNT,HDISERRF,HDISFDA,HDISFFNM,HDISFIEN,HDISI,HDISIEN,HDISIENS,HDISMSG,HDISNDTF,HDISOKF
  1.  ;Initialize output
  1.  S (HDISTIEN,HDISERRM)=""
  1.  ;Check for missing variables, exit if not defined
  1.  I '$D(HDISTERM)!($G(HDISVUID)'>0)!('$D(HDISFARY)) D  G ADDTERMQ
  1.  . S HDISERRM="Required Variable Missing."
  1.  ;Set National Standard Flag to default of 0, if needed
  1.  S HDISNTLF=$S('$D(HDISNTLF):0,1:HDISNTLF)
  1.  ;Set No Effective Date/Time Flag to 1 if there is no Effective Date/Time and no Status
  1.  I '$G(HDISEDTM),'$G(HDISSTAT) D
  1.  . S HDISNDTF=1
  1.  ;If No Effective Date/Time Flag is set to 1, Effective Date/Time Multiple should not be created
  1.  I '$G(HDISNDTF) D
  1.  . ;Set Effective Date/Time to default of NOW, if needed
  1.  . S HDISEDTM=$S('$D(HDISEDTM):$$NOW^XLFDT,1:HDISEDTM)
  1.  . ;Set Status to default of 0, if needed
  1.  . S HDISSTAT=$S('$D(HDISSTAT):0,1:HDISSTAT)
  1.  ;Set Check for Existing Term/Concept Flag to default of 1, if needed
  1.  S HDISCKTF=$S('$D(HDISCKTF):1,1:HDISCKTF)
  1.  ;Check for existing Term/Concept and File/Field, return error and exit if it exists
  1.  I $G(HDISCKTF),$$GETTERM(HDISTERM,.HDISFARY) D  G ADDTERMQ
  1.  . S HDISERRM="Term/Concept and File/Field already exists."
  1.  ;Check for existing Term/Concept and VUID, return error and exit if it exists
  1.  I $$GETIENS(HDISVUID,.HDISIENS) D  G ADDTERMQ:$G(HDISERRF)
  1.  . S HDISI=0
  1.  . F  S HDISI=$O(HDISIENS(HDISI)) Q:'HDISI!($G(HDISERRF))  I $G(HDISIENS(HDISI))=HDISTERM D
  1.  . . S HDISERRF=1
  1.  . . S HDISERRM="Term/Concept and VUID already exists."
  1.  ;Set array for Term/Concept and VUID
  1.  S HDISFDA(7118.11,"+1,",.01)=$G(HDISTERM)
  1.  S HDISFDA(7118.11,"+1,",99.99)=$G(HDISVUID)
  1.  ;Set array for National Standard Flag to Yes
  1.  I $G(HDISNTLF) D
  1.  . S HDISFDA(7118.11,"+1,",1.02)=1
  1.  ELSE  D
  1.  . ;Set array for Date/Time Created and National Standard Flag to No
  1.  . S HDISFDA(7118.11,"+1,",1.01)=$$NOW^XLFDT
  1.  . S HDISFDA(7118.11,"+1,",1.02)=0
  1.  ;If No Effective Date/Time Flag is set to 1, Effective Date/Time Multiple should not be created
  1.  I '$G(HDISNDTF) D
  1.  . ;Set array for Effective Date/Time and Status
  1.  . S HDISFDA(7118.12,"+2,+1,",.01)=$G(HDISEDTM)
  1.  . S HDISFDA(7118.12,"+2,+1,",.02)=$G(HDISSTAT)
  1.  ;Set array for File/Field
  1.  S HDISFIEN=0
  1.  S HDISCNT=2
  1.  F  S HDISFIEN=$O(HDISFARY(HDISFIEN)) Q:'HDISFIEN  I $D(^HDIS(7115.6,HDISFIEN,0)) S HDISFFNM=$P(^(0),"^",1) D
  1.  . S HDISCNT=HDISCNT+1
  1.  . S HDISFDA(7118.13,"+"_HDISCNT_",+1,",.01)=HDISFFNM
  1.  D UPDATE^DIE("E","HDISFDA","HDISIEN","HDISMSG")
  1.  ;Check for error
  1.  I $D(HDISMSG("DIERR")) D
  1.  . S HDISERRM=$G(HDISMSG("DIERR",1,"TEXT",1))
  1.  ELSE  D
  1.  . S HDISTIEN=+$G(HDISIEN(1))
  1.  . S HDISOKF=1
  1.  D CLEAN^DILF
  1. ADDTERMQ Q +$G(HDISOKF)
  1.  ;
  1. GETIENS(HDISVUID,HDISIENS) ;Get IENS for a Term/Concept by VUID
  1.  ; Input  -- HDISVUID VUID
  1.  ; Output -- 1=Successful and 0=Failure
  1.  ;           If Successful:
  1.  ;           HDISIENS Array where HDISIENS(IEN)=Term/Concept field (#.01)
  1.  N HDISI
  1.  ;Initialize output
  1.  K HDISIENS
  1.  ;Check for missing variable, exit if not defined
  1.  I $G(HDISVUID)'>0 G GETIENSQ
  1.  ;Check for entries by VUID
  1.  S HDISI=0
  1.  F  S HDISI=$O(^HDISV(7118.11,"AVUID",HDISVUID,HDISI)) Q:'HDISI  D
  1.  . I $D(^HDISV(7118.11,HDISI,0)) S HDISIENS(HDISI)=$P($G(^(0)),"^",1)
  1. GETIENSQ Q +$S($D(HDISIENS):1,1:0)
  1.  ;
  1. GETVUID(HDISTIEN,HDISVUID) ;Get VUID for a Term/Concept by IEN
  1.  ; Input  -- HDISTIEN HDIS Term/Concept VUID Association file IEN
  1.  ; Output -- 1=Successful and 0=Failure
  1.  ;           If Successful:
  1.  ;           HDISVUID VUID
  1.  ;Initialize output
  1.  S HDISVUID=""
  1.  ;Check for missing variable, exit if not defined
  1.  I $G(HDISTIEN)'>0 G GETVUIDQ
  1.  ;Check for VUID by IEN
  1.  I $D(^HDISV(7118.11,HDISTIEN,"VUID")) S HDISVUID=$P($G(^("VUID")),"^",1)
  1. GETVUIDQ Q +$S($G(HDISVUID)>0:1,1:0)
  1.  ;
  1. GETNTLF(HDISTIEN,HDISNTLF) ;Get National Standard Flag for a Term/Concept by IEN
  1.  ; Input  -- HDISTIEN HDIS Term/Concept VUID Association file IEN
  1.  ; Output -- 1=Successful and 0=Failure
  1.  ;           If Successful:
  1.  ;           HDISNTLF National Standard Flag
  1.  ;Initialize output
  1.  S HDISNTLF=""
  1.  ;Check for missing variable, exit if not defined
  1.  I $G(HDISTIEN)'>0 G GETNTLFQ
  1.  ;Check for National Standard Flag by IEN
  1.  I $D(^HDISV(7118.11,HDISTIEN,1)) S HDISNTLF=$P($G(^(1)),"^",2)
  1. GETNTLFQ Q +$S($G(HDISNTLF)]"":1,1:0)
  1.  ;
  1. GETSTAT(HDISTIEN,HDISDTM,HDISEDTM,HDISSTAT) ;Get Effective Date and Status for a Term/Concept by IEN and Date/Time
  1.  ; Input  -- HDISTIEN HDIS Term/Concept VUID Association file IEN
  1.  ;           HDISDTM  Date/Time  (Optional- Default NOW for Current)
  1.  ; Output -- 1=Successful and 0=Failure
  1.  ;           If Successful:
  1.  ;           HDISEDTM Effective Date/Time
  1.  ;           HDISSTAT Status
  1.  N HDIS0,HDISII
  1.  ;Initialize output
  1.  S (HDISEDTM,HDISSTAT)=""
  1.  ;Check for missing variable, exit if not defined
  1.  I $G(HDISTIEN)'>0 G GETSTATQ
  1.  ;Set Date/Time to default of NOW for Current, if needed
  1.  S HDISDTM=$S('$D(HDISDTM):$$NOW^XLFDT,1:HDISDTM)
  1.  S:'$P(HDISDTM,".",2) HDISDTM=HDISDTM_.235959
  1.  ;Get Effective Date/Time Multiple IEN by IEN and Date/Time
  1.  S HDISII=+$O(^(+$O(^HDISV(7118.11,HDISTIEN,"TERMSTATUS","B",HDISDTM),-1),0))
  1.  ;Check for Effective Date/Time and Status
  1.  I $D(^HDISV(7118.11,HDISTIEN,"TERMSTATUS",HDISII,0)) S HDIS0=$G(^(0)) D
  1.  . S HDISEDTM=$P(HDIS0,"^",1)
  1.  . S HDISSTAT=$P(HDIS0,"^",2)
  1. GETSTATQ Q +$S($G(HDISEDTM)'=""&($G(HDISSTAT)'=""):1,1:0)
  1.  ;          
  1.  ;---- End HDIS Term/Concept VUID Association file (#7118.11) API(s) ----