Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: HLCSHDR1

HLCSHDR1.m

Go to the documentation of this file. 
  1. HLCSHDR1 ;SFIRMFO/RSD - Make HL7 header for TCP ;09/13/2006
  1.  ;;1.6;HEALTH LEVEL SEVEN;**19,57,59,72,80,93,120,133**;Oct 13, 1995;Build 13
  1.  ;Per VHA Directive 2004-038, this routine should not be modified.
  1.  ;
  1.  ;Input  : IEN - Pointer to entry in Message Administration file (#773)
  1.  ;               that HL7 MSH segment is being built for
  1.  ;         CLIENT - IEN of the receiving application
  1.  ;         HLERROR - Variable to return possible error text in
  1.  ;                   (pass by reference - only used when needed)
  1.  ;
  1.  ;Output : HLHDR(1) - HL7 MSH segment
  1.  ;         HLHDR(2) - Continuation of HL7 MSH segment (if needed)
  1.  ;         HLHDR(3) - Continuation of HL7 MSH segment (if needed)
  1.  ;
  1.  ;Notes  : HLERROR will only be defined [on output] if an error occurs
  1.  ;       : HLHDR() will not be defined [on output] if an error occurs
  1.  ;       : HLHDR(2) & HLHDR(3) are continuation [or roll-over] nodes
  1.  ;         and will only be used/defined when needed
  1.  ;
  1.  N ACKTO,ACCACK,APPACK,CHILD,CLNTAPP,CLNTFAC,CNTRY,EC,EVNTYPE,FS,HLDATE,HLHDRI,HLHDRL,HLID,HLPID,MSGTYPE,PROT,PROTS,SECURITY,SEND,SERAPP,SERFAC,TXTP,TXTP0,X,MSGEVN
  1.  N COMFLAG ; patch HL*1.6*120
  1.  S HLERROR=""
  1.  S HLPARAM=$$PARAM^HLCS2
  1.  D VAR Q:$G(HLERROR)]""
  1.  ; The following line commented by HL*1.6*72
  1.  ;I $D(^HLMA(IEN)) S $P(^HLMA(IEN,0),U,13)=MSGTYPE,$P(^HLMA(IEN,0),U,14)=$G(EVNTYPE)
  1.  ;Append event type
  1.  I $G(EVNTYPE)]"" S MSGTYPE=MSGTYPE_$E(EC,1)_EVNTYPE
  1.  ;Append message structure component
  1.  I $G(EVNTYPE)]"",$G(MSGEVN)]"" S MSGTYPE=MSGTYPE_$E(EC,1)_MSGEVN
  1.  ;Build MSH array
  1.  D RESET^HLCSHDR3 ;HL*1.6*93
  1.  ;
  1.  ; patch HL*1.6*120 start
  1.  ; escape delimiters for SERAPP and CLNTAPP
  1.  ; escape component separator if the field is not consisted
  1.  ; of 3 components
  1.  S EC(1)=$E(EC,1)
  1.  S EC(2)=$E(EC,2)
  1.  S EC(3)=$E(EC,3)
  1.  S EC(4)=$E(EC,4)
  1.  S COMFLAG=1
  1.  I $L(SERAPP,$E(EC,1))=3 S COMFLAG=0
  1.  I (SERAPP[FS)!(SERAPP[EC(1))!(SERAPP[EC(2))!(SERAPP[EC(3))!(SERAPP[EC(4)) D
  1.  . S SERAPP=$$ESCAPE(SERAPP,COMFLAG)
  1.  S COMFLAG=1
  1.  I $L(CLNTAPP,$E(EC,1))=3 S COMFLAG=0
  1.  I (CLNTAPP[FS)!(CLNTAPP[EC(1))!(CLNTAPP[EC(2))!(CLNTAPP[EC(3))!(CLNTAPP[EC(4)) D
  1.  . S CLNTAPP=$$ESCAPE(CLNTAPP,COMFLAG)
  1.  ; patch HL*1.6*120 end
  1.  ;
  1.  S HLHDRI=1,HLHDR(1)="MSH"_FS_EC_FS_SERAPP,HLHDRL=$L(HLHDR(1))
  1.  F X=SERFAC,CLNTAPP,CLNTFAC,HLDATE,SECURITY,MSGTYPE,HLID,HLPID,$P(PROT,U,9),"",$G(^HL(772,TXTP,1)),ACCACK,APPACK,CNTRY D MSH(X)
  1.  ;in preceeding line, "" is for sequence number - not supported
  1.  Q
  1.  ;
  1. MSH(X) ;add X to HLHDR
  1.  S:HLHDRL+$L(X)>245 HLHDRI=HLHDRI+1,HLHDR(HLHDRI)=""
  1.  S HLHDR(HLHDRI)=HLHDR(HLHDRI)_FS_X,HLHDRL=$L(HLHDR(HLHDRI))
  1.  Q
  1. BHSHDR(IEN,CLIENT,HLERROR) ; Create Batch Header Segment
  1.  ; The BHS has 12 segments, of which 4 are blank.
  1.  ; INPUT: IEN - IEN of entry in file #772
  1.  ; OUTPUT: HLHDR(1) and HLHDR(2) - the two lines with the 12 segs.
  1.  ;   ready for adding to a message directly.
  1.  N ACKTO,ACCACK,ACKMID,APPACK,BNAME,BSTATUS,BTACK,CHILD,CLNTAPP ;HL*1.6*80
  1.  N CLNTFAC,CNTRY,EC,EVNTYPE,FS,HLDATE,HLHDRI,HLHDRL,HLID,HLPID ;HL*1.6*80 - added HLPID
  1.  N PROT,PROTS,SECURITY,SEND,SERAPP,SERFAC,TXTP,TXTP0,X ;HL*1.6*80
  1.  N COMFLAG ; patch HL*1.6*120
  1.  S HLERROR=""
  1.  ;
  1.  S HLPARAM=$$PARAM^HLCS2
  1.  D VAR Q:$G(HLERROR)]""
  1.  ; The following line commented by HL*1.6*72
  1.  ;I $D(^HLMA(IEN)) S $P(^HLMA(IEN,0),U,13)=MSGTYPE,$P(^HLMA(IEN,0),U,14)=$G(EVNTYPE)
  1.  ;
  1.  ;Append event type
  1.  I $G(EVNTYPE)]"" S MSGTYPE=MSGTYPE_$E(EC,2)_EVNTYPE,(ACKMID,BTACK)=""
  1.  ;batch/name/id/type(#9)=null~process ID~msg type|evnt type~version~CA~AA
  1.  S BNAME=$E(EC,1)_HLPID_$E(EC,1)_MSGTYPE_$E(EC,1)_$P(PROT,U,9)_$E(EC,1)_ACCACK_$E(EC,1)_APPACK ;HL*1.6*80
  1.  ;for batch ACK
  1.  I ACKTO D  S BTACK=X_$E(EC,1)_$P(BSTATUS,U,3)
  1.  . ;get msg id and status of message that is being ACKed
  1.  . S ACKMID=$P($G(^HLMA(ACKTO,0)),U,2),BSTATUS=$G(^HLMA(ACKTO,"P")) ;HL*1.6*80
  1.  . ;set type of ACK based on status
  1.  . S X=$S(ACKMID="":"AR",(BSTATUS>3)&(BSTATUS<8):"AE",1:"AA")
  1.  ;
  1.  D RESET^HLCSHDR3 ;HL*1.6*93
  1.  ;
  1.  ; patch HL*1.6*120 start
  1.  ; escape delimiters for SERAPP and CLNTAPP
  1.  ; escape component separator if the field is not consisted
  1.  ; of 3 components
  1.  S EC(1)=$E(EC,1)
  1.  S EC(2)=$E(EC,2)
  1.  S EC(3)=$E(EC,3)
  1.  S EC(4)=$E(EC,4)
  1.  S COMFLAG=1
  1.  I $L(SERAPP,$E(EC,1))=3 S COMFLAG=0
  1.  I (SERAPP[FS)!(SERAPP[EC(1))!(SERAPP[EC(2))!(SERAPP[EC(3))!(SERAPP[EC(4)) D
  1.  . S SERAPP=$$ESCAPE(SERAPP,COMFLAG)
  1.  S COMFLAG=1
  1.  I $L(CLNTAPP,$E(EC,1))=3 S COMFLAG=0
  1.  I (CLNTAPP[FS)!(CLNTAPP[EC(1))!(CLNTAPP[EC(2))!(CLNTAPP[EC(3))!(CLNTAPP[EC(4)) D
  1.  . S CLNTAPP=$$ESCAPE(CLNTAPP,COMFLAG)
  1.  ; patch HL*1.6*120 end
  1.  ;
  1.  S HLHDRI=1,HLHDR(1)="BHS"_FS_EC_FS_SERAPP,HLHDRL=$L(HLHDR(1))
  1.  F X=SERFAC,CLNTAPP,CLNTFAC,HLDATE,SECURITY,BNAME,BTACK,HLID,ACKMID D MSH(X)
  1.  Q
  1. VAR ;Check input
  1.  N APPPRM,HLPROTS,HLPROT
  1.  S IEN=+$G(IEN)
  1.  I '$G(^HLMA(IEN,0)) S HLERROR="Valid pointer to Message Administration file (#772) not passed" Q
  1.  I '$G(CLIENT) S HLERROR="Could not determine receiving application" Q
  1.  ;Get child, text pointer,text entry, and sending app.
  1.  S CHILD=$G(^HLMA(IEN,0)),SEND=+$P($G(^(0)),U,11),TXTP=+CHILD,TXTP0=$G(^HL(772,TXTP,0))
  1.  I ('SEND) S HLERROR="Could not determine sending application" Q
  1.  ;Get info for sending & receiving applications
  1.  D APPPRM^HLUTIL2(CLIENT),APPPRM^HLUTIL2(SEND)
  1.  ;Get name of sending application, facility, and country
  1.  S SERAPP=$P(APPPRM(SEND,0),U),SERFAC=$P(APPPRM(SEND,0),U,2),CNTRY=$P(APPPRM(SEND,0),U,3)
  1.  ;Get name of receiving application and facility
  1.  S CLNTAPP=$P(APPPRM(CLIENT,0),U),CLNTFAC=$P(APPPRM(CLIENT,0),U,2)
  1.  ;
  1.  ; patch HL*1.6*120
  1.  ; for dynamic addressing, overide the receiving facility from the
  1.  ; 3rd component of HLL("LINKS") array
  1.  I $G(HLP("REC-FACILITY"))]"" S CLNTFAC=HLP("REC-FACILITY")
  1.  ;
  1.  ;Get field separator & encoding characters
  1.  S FS=APPPRM(SEND,"FS"),EC=APPPRM(SEND,"EC")
  1.  S:(EC="") EC="~|\&" S:(FS="") FS="^"
  1.  ;Determine if it's a response/ACK to another message
  1.  S ACKTO=+$P(CHILD,U,10)
  1.  ;subscriber protocol is from child (file 773)
  1.  ;If response, get MType from subscriber
  1.  S HLPROTS=+$P(CHILD,U,8)
  1.  S PROTS=$$TYPE^HLUTIL2(HLPROTS)
  1.  I ACKTO S MSGTYPE=$P(PROTS,U,10),EVNTYPE=$P(PROTS,U,3),MSGEVN=$P(PROTS,U,4)
  1.  ;Get accept ack & application ack type (based on server protocol) it
  1.  ; is always in file 772, TXPT0
  1.  ;If original message, get MT from Event Driver Protocol
  1.  S HLPROT=+$P(TXTP0,U,10)
  1.  S PROT=$$TYPE^HLUTIL2(HLPROT)
  1.  S:'ACKTO MSGTYPE=$P(PROT,U,2),EVNTYPE=$P(PROT,U,3),MSGEVN=$P(PROT,U,4)
  1.  S ACCACK=$P(PROT,U,7),APPACK=$P(PROT,U,8)
  1. PID ;Processing ID
  1.  ;I PID not 'debug' get from site params
  1.  ;If event driver set to 'debug' get from protocol
  1.  ;'production' or 'training' comes from site params
  1.  S HLPID=$P(PROT,U,5)
  1.  I $G(HLPID)'="D" S HLPID=$P(HLPARAM,U,3)
  1.  ;
  1.  ; patch HL*1.6*120: to include processing mode
  1.  I $G(HLP("PMOD"))]"",($G(HLTYPE)="M") D
  1.  . S HLPID=HLPID_$E($G(EC),1)_HLP("PMOD")
  1.  ;
  1.  I $G(HLPID)="" S HLERROR="Missing processing ID Site parameter."
  1.  ;acknowledgements have no application ack, link open no commit ack
  1.  I ACKTO S:APPACK]"" APPACK="NE" S:ACCACK]""&$G(HLTCPO) ACCACK="NE"
  1.  ;Get date/time, Message ID, and security
  1.  S HLDATE=+TXTP0,HLDATE=$$FMTHL7^XLFDT(HLDATE),HLID=$P(CHILD,U,2),SECURITY=$P(CHILD,U,9)
  1. HDR23 ;generate extended facility field info based on 'facility required'
  1.  ;default format is INSTITUTION_HLCS_DOMAIN_HLCS_'DNS'
  1.  ;application parameter entry overrides default
  1.  N HLEP773,HLS773
  1.  S SERFAC=$G(SERFAC),CLNTFAC=$G(CLNTFAC)
  1.  S HLEP773=+$G(^ORD(101,HLPROTS,773))
  1.  S HLS773=+$P($G(^ORD(101,HLPROTS,773)),U,2)
  1.  Q:'HLEP773&('HLS773)
  1.  D GEN^HLCSHDR2
  1.  I ACKTO D  Q
  1.  .;Find original message
  1.  .S X=$G(^HLMA(ACKTO,"MSH",1,0)) ;Find header in TCP nodes
  1.  .I X["MSH" D
  1.  ..;
  1.  ..; patch HL*1.6*120 start
  1.  .. N HLEC
  1.  ..S HLFS=$E(X,4),HLEC=$E(X,5)
  1.  ..S SENDFAC=$P(X,HLFS,4),RECFAC=$P(X,HLFS,6) ;from original msg
  1.  ..S CLNTFAC=SENDFAC,SERFAC=RECFAC ;reverse facility info
  1.  ..S EC("COMPONENT")=$E($G(EC),1)
  1.  ..I $L(EC("COMPONENT"))=1,$L(HLEC)=1,EC("COMPONENT")'=HLEC D
  1.  ... ; change the the component separator in the sending and
  1.  ... ; receiving facilities for the outgoing message
  1.  ... S CLNTFAC=$TR(CLNTFAC,HLEC,EC("COMPONENT"))
  1.  ... S SERFAC=$TR(SERFAC,HLEC,EC("COMPONENT"))
  1.  ; patch HL*1.6*120 end
  1.  ;
  1.  I HLEP773,SERFAC="" D EP^HLCSHDR2
  1.  I HLS773,CLNTFAC="" D S^HLCSHDR2
  1.  Q
  1.  ;
  1. ESCAPE(INPUT,COMPONET) ;
  1.  ; patch HL*1.6*120 - escape delimiters:
  1.  ; - field separator
  1.  ; - component separator
  1.  ; - repetition separator
  1.  ; - escape character
  1.  ; - subcomponent separator
  1.  ;
  1.  ; input: 
  1.  ;     INPUT - string data to be escaped
  1.  ;  COMPONET - if 1, escape component separator
  1.  ;             if 0, do not escape component separator
  1.  ;        FS - field separator character
  1.  ;        EC - encoding characters 
  1.  ; result: return the escaped string
  1.  ;
  1.  N HLDATA,HLESCAPE,HLI,HLCHAR,HLEN,HLOUT,COMFLAG
  1.  S HLDATA=$G(INPUT)
  1.  S COMFLAG=$G(COMPONET)
  1.  Q:$L($G(FS))'=1 HLDATA
  1.  ;
  1.  ; patch HL*1.6*133
  1.  ; Q:$L($G(EC))'=4 HLDATA
  1.  Q:($L($G(EC))<3) HLDATA
  1.  Q:HLDATA']"" HLDATA
  1.  ;
  1.  S HLESCAPE=FS_EC
  1.  S HLESCAPE("F")=FS
  1.  S HLESCAPE("S")=$E(EC,1)
  1.  S HLESCAPE("R")=$E(EC,2)
  1.  S HLESCAPE("E")=$E(EC,3)
  1.  S HLESCAPE("T")=$E(EC,4)
  1.  S HLEN=$L(HLDATA)
  1.  S HLOUT=""
  1.  F HLI=1:1:HLEN D
  1.  . S HLCHAR=$E(HLDATA,HLI)
  1.  . I HLESCAPE[HLCHAR D  Q
  1.  .. I HLCHAR=HLESCAPE("F") S HLOUT=HLOUT_HLESCAPE("E")_"F"_HLESCAPE("E") Q
  1.  .. I HLCHAR=HLESCAPE("S") D  Q
  1.  ... I COMFLAG=1 S HLOUT=HLOUT_HLESCAPE("E")_"S"_HLESCAPE("E") Q
  1.  ... S HLOUT=HLOUT_HLCHAR
  1.  .. I HLCHAR=HLESCAPE("R") S HLOUT=HLOUT_HLESCAPE("E")_"R"_HLESCAPE("E") Q
  1.  .. I HLCHAR=HLESCAPE("E") S HLOUT=HLOUT_HLESCAPE("E")_"E"_HLESCAPE("E") Q
  1.  .. I HLCHAR=HLESCAPE("T") S HLOUT=HLOUT_HLESCAPE("E")_"T"_HLESCAPE("E") Q
  1.  . ;
  1.  . S HLOUT=HLOUT_HLCHAR
  1.  Q HLOUT