Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: HLOPROC

HLOPROC.m

Go to the documentation of this file. 
  1. HLOPROC ;ALB/CJM- Generic HL7 Process - 10/4/94 1pm
  1.  ;;1.6;HEALTH LEVEL SEVEN;**126**;Oct 13, 1995
  1.  ;
  1. PROCESS ;queued entry point
  1.  ;
  1.  ;insure just one process manager
  1.  I PROCNAME="PROCESS MANAGER" N RUNNING L +^HLTMP(PROCNAME):1 S RUNNING='$T D  Q:RUNNING
  1.  .I 'RUNNING D
  1.  ..D SETNM^%ZOSV($E("HLOmgr:"_$J,1,17))
  1.  .E  D
  1.  ..L +HL7("COUNTING PROCESSES"):20
  1.  ..K:$D(ZTSK) ^HLTMP("HL7 QUEUED PROCESSES",ZTSK)
  1.  ..S ^HLC("HL7 PROCESS COUNTS","RUNNING","PROCESS MANAGER")=1
  1.  ..S ^HLC("HL7 PROCESS COUNTS","QUEUED","PROCESS MANAGER")=0
  1.  ..L -HL7("COUNTING PROCESSES")
  1.  ..S ZTREQ="@"
  1.  ;
  1.  ;invoke the framework process
  1.  D HL7PROC(PROCNAME)
  1.  ;
  1.  I PROCNAME="PROCESS MANAGER" L -^HLTMP(PROCNAME)
  1.  S ZTREQ="@"
  1.  Q
  1.  ;
  1. HL7PROC(PROCNAME) ;
  1.  ;This is the generic HL7 process used by all processes started under the HL7 Process Manager
  1.  ;Input:
  1.  ;  PROCNAME - the name of a process found in the HL7 Process Registry
  1.  ;  OUTPUT - none
  1.  ;
  1.  N PROCESS,HL7STOP,WORK
  1.  ;
  1.  S ^HL7TMP("HL7 PROCESS NAME",$J)=PROCNAME
  1.  ;
  1.  L +HL7("COUNTING PROCESSES"):20
  1.  I $D(ZTQUEUED) D
  1.  .K:$D(ZTSK) ^HLTMP("HL7 QUEUED PROCESSES",ZTSK)
  1.  .I $$INC^HLOSITE($NA(^HLC("HL7 PROCESS COUNTS","QUEUED",PROCNAME)),-1)<0,$$INC^HLOSITE($NA(^HLC("HL7 PROCESS COUNTS","QUEUED",PROCNAME)))
  1.  L +^HLTMP("HL7 RUNNING PROCESSES",$J):0
  1.  I $$INC^HLOSITE($NA(^HLC("HL7 PROCESS COUNTS","RUNNING",PROCNAME)))
  1.  S ^HLTMP("HL7 RUNNING PROCESSES",$J)=$H_"^"_$G(ZTSK)_"^"_PROCNAME
  1.  L -HL7("COUNTING PROCESSES")
  1.  ;
  1.  ;
  1.  I $$GETPROC(PROCNAME,.PROCESS),'$$CHK4STOP(.PROCESS) D
  1.  .S $P(^HLD(779.3,PROCESS("IEN"),0),"^",6)=$$NOW^XLFDT
  1.  .;
  1.  .;should this task be made persistent?
  1.  .I PROCESS("PERSISTENT"),$G(ZTQUEUED),$$PSET^%ZTLOAD(ZTQUEUED)
  1.  .;
  1.  .S HL7STOP=0
  1.  .F  D  Q:HL7STOP
  1.  ..N $ETRAP,$ESTACK S $ETRAP="G ERROR^HLOPROC"
  1.  ..N HL7TRIES,GOTWORK
  1.  ..F HL7TRIES=1:1 D  Q:GOTWORK  Q:HL7STOP
  1.  ...S GOTWORK=$$GETWORK(.PROCESS,.WORK)
  1.  ...Q:GOTWORK
  1.  ...;since there is no work, don't want another process starting
  1.  ...S $P(^HLD(779.3,PROCESS("IEN"),0),"^",6)=$$NOW^XLFDT
  1.  ...H PROCESS("HANG")
  1.  ...S HL7STOP=$$CHK4STOP(.PROCESS,HL7TRIES)
  1.  ..Q:HL7STOP
  1.  ..I GOTWORK D DOWORK(.PROCESS,.WORK) S HL7TRIES=0
  1.  ..S:'$G(HL7STOP) HL7STOP=$$CHK4STOP(.PROCESS,.HL7TRIES)
  1.  ;
  1.  S $P(^HLD(779.3,PROCESS("IEN"),0),"^",6)=$$NOW^XLFDT
  1.  ;
  1. END ;
  1.  S HL7STOP=1
  1.  K ^HL7TMP("HL7 PROCESS NAME",$J)
  1.  L +HL7("COUNTING PROCESSES"):20
  1.  K ^HLTMP("HL7 RUNNING PROCESSES",$J)
  1.  I $$INC^HLOSITE($NA(^HLC("HL7 PROCESS COUNTS","RUNNING",PROCNAME)),-1)<0,$$INC^HLOSITE($NA(^HLC("HL7 PROCESS COUNTS","RUNNING",PROCNAME)),1)
  1.  L -^HLTMP("HL7 RUNNING PROCESSES",$J)
  1.  L -HL7("COUNTING PROCESSES")
  1.  K ^TMP("HL7 ERRORS",$J)
  1.  ;
  1.  Q
  1.  ;
  1. ERROR ;error trap
  1.  ;
  1.  S $ETRAP="D UNWIND^%ZTER"
  1.  ;
  1.  ;while debugging always quit on error
  1.  I $G(^HLTMP("LOG ALL ERRORS")) D  QUIT
  1.  .D ^%ZTER
  1.  .S:'$D(PROCNAME) PROCNAME=$G(^HL7TMP("HL7 PROCESS NAME",$J))
  1.  .D END
  1.  ;
  1.  ;a lot of errors of the same type may indicate an endless loop, so quit
  1.  ;to be on the safe side.  Decrement the process count.
  1.  S $ECODE=$P($ECODE,",",1,2)
  1.  S ^TMP("HL7 ERRORS",$J,$ECODE)=$G(^TMP("HL7 ERRORS",$J,$ECODE))+1
  1.  I $G(^TMP("HL7 ERRORS",$J,$ECODE))>100 D  QUIT
  1.  .D ^%ZTER
  1.  .S:'$D(PROCNAME) PROCNAME=$G(^HL7TMP("HL7 PROCESS NAME",$J))
  1.  .D END
  1.  ;
  1.  D ^%ZTER
  1.  D UNWIND^%ZTER
  1.  Q
  1.  ;
  1. GETPROC(PROCNAME,PROCESS) ;
  1.  ;using PROCNAME to find the entry in the HL7 Process Registry, returns the entry as a subscripted array in .PROCESS
  1.  ;
  1.  ;Output: Function returns 0 on failure, 1 on success
  1.  ;
  1.  N IEN,NODE
  1.  S IEN=$O(^HLD(779.3,"B",PROCNAME,0))
  1.  Q:'IEN 0
  1.  S PROCESS("NAME")=PROCNAME
  1.  S PROCESS("IEN")=IEN
  1.  S NODE=$G(^HLD(779.3,IEN,0))
  1.  S PROCESS("MINIMUM")=+$P(NODE,"^",3)
  1.  S PROCESS("MAXIMUM")=+$P(NODE,"^",4)
  1.  S PROCESS("HANG")=+$P(NODE,"^",7)
  1.  I 'PROCESS("HANG") S PROCESS("HANG")=1
  1.  S PROCESS("GET WORK")=$P(NODE,"^",8,9)
  1.  S PROCESS("DO WORK")=$P(NODE,"^",10,11)
  1.  S PROCESS("MAX TRIES")=$P(NODE,"^",12)
  1.  I 'PROCESS("MAX TRIES") S PROCESS("MAX TRIES")=999
  1.  S PROCESS("PERSISTENT")=+$P(NODE,"^",13)
  1.  S PROCESS("LINK")=$P(NODE,"^",14)
  1.  Q 1
  1.  ;
  1. GETWORK(PROCESS,WORK) ;
  1.  N RETURN,XECUTE
  1.  I PROCESS("LINK")]"" S WORK("LINK")=PROCESS("LINK")
  1.  S XECUTE="S RETURN=$$"_PROCESS("GET WORK")_"(.WORK)"
  1.  D
  1.  .N PROCESS
  1.  .X XECUTE
  1.  Q RETURN
  1.  ;
  1. DOWORK(PROCESS,WORK) ;
  1.  N XECUTE
  1.  M PARMS=WORK
  1.  S XECUTE="D "_PROCESS("DO WORK")_"(.WORK)"
  1.  D
  1.  .N PROCESS,HL7TRIES,PARMS,PROCNAME
  1.  .X XECUTE
  1.  M WORK=PARMS
  1.  Q
  1.  ;
  1. CHK4STOP(PROCESS,HL7TRIES) ;
  1.  ;Determines if the process should stop, returns 1 if yes, 0 if no
  1.  ;
  1.  Q:$$CHKSTOP 1
  1.  Q:'$P($G(^HLD(779.3,PROCESS("IEN"),0)),"^",2) 1
  1.  I $G(HL7TRIES)>(PROCESS("MAX TRIES")-1),PROCESS("MINIMUM")<$G(^HLC("HL7 PROCESS COUNTS","RUNNING",PROCESS("NAME"))) Q 1
  1.  Q:$G(^HLC("HL7 PROCESS COUNTS","RUNNING",PROCESS("NAME")))>PROCESS("MAXIMUM") 1
  1.  Q 0
  1.  ;
  1. CHKSTOP() ;has HL7 been requested to stop?
  1.  Q '$P($G(^HLD(779.1,1,0)),"^",9)