Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: HLTP3

HLTP3.m

Go to the documentation of this file. 
  1. HLTP3 ;SFIRMFO/RSD - Transaction Processor for TCP ;09/13/2006
  1.  ;;1.6;HEALTH LEVEL SEVEN;**19,43,57,58,59,66,69,109,115,108,116,117,125,120,133**;Oct 13, 1995;Build 13
  1.  ;Per VHA Directive 2004-038, this routine should not be modified.
  1.  ;
  1.  Q
  1. NEW(X) ;process new msg. ien in 773^msg. ien in 772
  1.  ;HLMTIENS=ien in #773, msg header; HLMTIEN=ien in #772, msg text
  1.  ;HLHDRO=original header;  HLHDR=response header
  1.  ;set error trap
  1.  N $ETRAP,$ESTACK S $ETRAP="D ERROR^HLTP3"
  1.  N HL,HLEID,HLEIDS,HLERR,HLHDR,HLHDRO,HLMTIEN,HLMTIENS,HLJ,HLMSA,HLQUIT,HLNODE,HLNEXT,HLRESLTA,HLDONE1,HLASTRSP,HLRESLT
  1.  S HLRESLT=""
  1.  D INIT^HLTP3A
  1.  ;error with header, return commit/app reject
  1.  I $G(HLRESLT) D  Q
  1.  . ;set status & unlock record
  1.  . D STATUS^HLTF0(HLMTIENS,4,,,1),EXIT
  1.  . ;quit if no commit or app ack
  1.  . I $G(HL("ACAT"))="NE",$G(HL("APAT"))="NE" Q
  1.  . S X=$S($G(HL("ACAT"))="AL":"CR",1:"AR")
  1.  . ;HLTCP=ien of acknowledgment msg. from ACK^HLTP4
  1.  . D ACK^HLTP4(X,$P(HLRESLT,U,2)) Q:'$G(HLTCP)
  1.  . ;write ack back over connection
  1.  . S X=$$WRITE^HLCSTCP2(HLTCP)
  1.  . ;update counter to sent
  1.  . D LLCNT^HLCSTCP(HLDP,4)
  1.  . ;update status of ack to complete
  1.  . D STATUS^HLTF0(HLTCP,3,,,1)
  1.  ;
  1.  ;check for duplicate msg., use rec. app and msg. id x-ref
  1.  ; patch HL*1.6*120
  1.  ; I $L($G(HL("MID"))),$G(HL("RAP")) S X=$O(^HLMA("AH",HL("RAP"),HL("MID"),0)) D  Q:'$D(HLMTIENS)
  1.  I $G(HL("MID"))]"",$G(HL("RAP")) S X=$O(^HLMA("AH",HL("RAP"),HL("MID"),0)) D  Q:'$D(HLMTIENS)
  1.  . ;HLASTMSG=last ien received during this connection
  1.  . ;if no duplicate, save msg. ien and quit
  1.  . I X=HLMTIENS!'X S HLASTMSG=HLMTIENS Q
  1.  . N MSH,OIENS
  1.  . S (OIENS,Y)=X D  S Y=HLMTIENS D
  1.  .. ;combine MSH into single string
  1.  .. S MSH(Y)="",I=0 F  S I=$O(^HLMA(Y,"MSH",I)) Q:'I  S MSH(Y)=MSH(Y)_$G(^(I,0))
  1.  .; patch 117 & 125, check if identical
  1.  .I MSH(HLMTIENS)'=MSH(OIENS) S HLASTMSG=HLMTIENS Q
  1.  .;
  1.  . ;msg is duplicate, set status as duplicate
  1.  . D STATUS^HLTF0(HLMTIENS,4,109,"Duplicate with ien "_OIENS,1),EXIT
  1.  . ;msg was resent during this connection, ignore it.
  1.  . I HLASTMSG=HLMTIENS K HLMTIENS Q
  1.  . ;find original response and send back
  1.  . S HLASTRSP=$O(^HLMA("AF",OIENS,OIENS))
  1.  ;
  1.  ;Quit if this is acknowledgment to acknowledgement message
  1.  I $G(HL("ACK")) D  Q
  1.  . ;Update status of original acknowledgment message to successfully
  1.  . D STATUS^HLTF0(HL("MTIENS"),3,,,1),STATUS^HLTF0(HLMTIENS,3,,,1)
  1.  . ;unlock record
  1.  . D EXIT
  1.  ;
  1.  ;enhance ack., send commit, quit if not an ack, msg will be processed by filer
  1.  I $G(HL("ACAT"))="AL" D  Q:'$G(HL("MTIENS"))
  1.  . ;msg is a resend, HLASTRSP=ien of original response
  1.  .I $G(HLASTRSP) D
  1.  ..S HLTCP=HLASTRSP
  1.  ..D LLCNT^HLCSTCP(HLDP,3)
  1.  . E  D  Q:'$G(HLTCP)
  1.  ..D ACK^HLTP4("CA") ;**109** LLCNT^HLCSTCP(HLDP,3) called in ACK^HLTP4
  1.  . S X=$$WRITE^HLCSTCP2(HLTCP)
  1.  . D LLCNT^HLCSTCP(HLDP,4),STATUS^HLTF0(HLTCP,3,,,1):'$G(HLASTRSP)
  1.  . S HLTCP=""
  1.  . ;if not an ack, set status to awaiting processing **109** and put on in queue
  1.  . I '$G(HL("MTIENS")),'$G(HLASTRSP) D STATUS^HLTF0(HLMTIENS,9),EXIT,SETINQUE^HLTP31
  1.  ;
  1.  ;enhance ack., no commit & no app ack
  1.  I $G(HL("ACAT"))="NE",$G(HL("APAT"))="NE" D  Q
  1.  . ;set status to awaiting processing, **109** and put on in queue
  1.  . I '$G(HLASTRSP) D STATUS^HLTF0(HLMTIENS,9),EXIT,SETINQUE^HLTP31
  1.  ;
  1.  ; patch HL*1.6*120 start
  1.  ;resending old response, msg is a resend
  1.  ; I $G(HLASTRSP) S HLTCP=HLASTRSP G ACK
  1.  ; do not re-send duplicate message when $G(HL("ACAT"))="AL"
  1.  I $G(HLASTRSP),$G(HL("ACAT"))'="AL" S HLTCP=HLASTRSP G ACK
  1.  ; quit if duplicate
  1.  Q:$G(HLASTRSP)
  1.  ; patch HL*1.6*120 end
  1.  ;
  1. CONT ;continue processing an enhance ack msg. called from DEFACK
  1.  ;Set special HL variables for processing rtn
  1.  S HLQUIT=0,HLNODE="",HLNEXT="D HLNEXT^HLCSUTL"
  1.  ;
  1.  ; message is an acknowledgement, HLMSA=ack code^id^text
  1.  I ($G(HLMSA)]"") D  Q
  1.  . ;X=1 if ack ok, 0=reject of error
  1.  . S X=$E(HLMSA,2)="A"
  1.  . ;Update status of original subscriber message and remove it from the out-going queue
  1.  . D STATUS^HLTF0(HL("MTIENS"),$S(X:3,1:4),"",$S(X:"",1:$P(HLMSA,HL("FS"),3)),1)
  1.  . D DEQUE^HLCSREP($P($G(^HLMA(HL("MTIENS"),0)),"^",7),"O",HL("MTIENS"))
  1.  . D
  1.  .. N HLTCP ;New variable to update status in file #772.
  1.  ..;
  1.  ..;**108**
  1.  .. N TEMP
  1.  .. S TEMP=HLMTIENS
  1.  .. N HLMTIENS
  1.  .. S HLMTIENS=TEMP
  1.  ..;**END 108**
  1.  ..;
  1.  .. D PROCACK^HLTP2(HLMTIEN,HL("EID"),.HLRESLT,.HL)
  1.  . ;update status of incoming to complete & unlock
  1.  . D STATUS^HLTF0(HLMTIENS,$S($G(HLRESLT):4,1:3),$S($G(HLRESLT):+$G(HLRESLT),1:""),$S($G(HLRESLT):$P(HLRESLT,U,2),1:""),1),EXIT
  1.  ;
  1.  ;get entry action, exit action and processing routine
  1.  K HLHDR,HLLD0,HLLD1,HLMSA
  1.  I HL("EIDS")="",$G(HLEIDS)]"" S HL("EIDS")=HLEIDS ;**CIRN**
  1.  D EVENT^HLUTIL1(HL("EIDS"),"15,20,771",.HLN)
  1.  S HLENROU=$G(HLN(20)),HLEXROU=$G(HLN(15)),HLPROU=$G(HLN(771))
  1.  ;quit if no processing routine,update status and quit
  1.  I HLPROU']"" S HLRESLT="10^"_$G(^HL(771.7,10,0)) D STATUS^HLTF0(HLMTIENS,3,,,1),EXIT Q
  1.  ;HLORNOD=subscriber protocol for Fileman auditing, ien;global ref
  1.  N HLORNODD S HLORNOD=HL("EIDS")_";ORD(101,"
  1.  ;Execute entry action of client protocol
  1.  X:HLENROU]"" HLENROU K HLENROU,HLDONE1
  1.  ;
  1.  ;Execute processing routine
  1.  X HLPROU S HLRESLT=0 S:($D(HLERR)) HLRESLT="9^"_HLERR
  1.  ;update status of incoming to complete & unlock
  1.  D STATUS^HLTF0(HLMTIENS,$S(HLRESLT:4,1:3),$S(HLRESLT:+HLRESLT,1:""),$S(HLRESLT:$P(HLRESLT,U,2),1:""),1,$S($G(HLERR("SKIP_EVENT"))=1:1,1:0)),EXIT
  1.  ;HLTCPO=link open, HLTCP=ien of acknowledgment msg. from GENACK
  1. ACK I $G(HLTCPO),$G(HLTCP) D  Q
  1.  . D LLCNT^HLCSTCP(HLDP,3)
  1.  . ;write ack back over open tcp link
  1.  . S X=$$WRITE^HLCSTCP2(HLTCP)
  1.  . ;update status of ack to complete
  1.  . D:'$G(HLASTRSP) STATUS^HLTF0(HLTCP,3,,,1)
  1.  . D LLCNT^HLCSTCP(HLDP,4)
  1.  Q
  1.  ;
  1. DEFACK(HLDP,X) ;process the deferred application ack, called from HLCSIN
  1.  ;HLDP=logical link, X=ien in file 773
  1.  ;
  1.  ; patch HL*1.6*120 start
  1.  ; clean variables except Kernel related variables
  1.  D
  1.  . ; protect variables defined in STARTIN^HLCSIN
  1.  . N HLFLG,HLEXIT,HLPTRFLR
  1.  . ; protect variables defined in DEFACK^HLCSIN
  1.  . N HLXX,HLD0,HLPCT
  1.  . ; protect input parameters of this sub-routine
  1.  . N HLDP,X
  1.  . D KILL^XUSCLEAN
  1.  ; patch HL*1.6*120 end
  1.  ;
  1.  ;set error trap
  1.  N $ETRAP,$ESTACK S $ETRAP="D ERROR^HLTP3"
  1.  N HLERR     ;patch HL*1.6*109
  1.  Q:'$G(HLDP)!'$G(X)  Q:'$G(^HLMA(X,0))
  1.  ;**109 START**
  1.  Q:'$D(^HLMA("AC","I",HLDP,X))
  1.  ;**109 END**
  1.  ;
  1.  N HL,HLA,HLD0,HLEID,HLEIDS,HLHDR,HLHDRO,HLMTIEN,HLMTIENS,HLJ,HLMSA,HLN,HLQUIT,HLNODE,HLNEXT,HLRESLT,HLRESLTA,HLTCP,HLXX,Z,HLDONE1
  1.  ;setup variables
  1.  S HLMTIENS=X,X=^HLMA(HLMTIENS,0),HLMTIEN=+$P(X,U),HL("MID")=$P(X,U,2),HL("MTIENS")=$P(X,U,10),HL("LL")=$P(X,U,7),HLTCP="",HL("Q")=""""""
  1.  S HL("EIDS")=$P(X,U,8),HL("SAP")=$P(X,U,11),HL("RAP")=$P(X,U,12),HL("MTP")=$P(X,U,13),HL("ETP")=$P(X,U,14)
  1.  S:$P(X,U,15) HL("MTP_ETP")=$P(X,U,15)
  1.  S:HL("SAP") HL("SAN")=$P($G(^HL(771,HL("SAP"),0)),U) S:HL("RAP") HL("RAN")=$P($G(^HL(771,HL("RAP"),0)),U)
  1.  S:HL("MTP") HL("MTN")=$P($G(^HL(771.2,HL("MTP"),0)),U) S:HL("ETP") HL("ETN")=$P($G(^HL(779.001,HL("ETP"),0)),U)
  1.  S:$G(HL("MTP_ETP")) HL("MTN_ETN")=$P($G(^HL(779.005,HL("MTP_ETP"),0)),U)
  1.  S HL("EID")=$P($G(^HL(772,HLMTIEN,0)),U,10)
  1.  M HLHDRO=^HLMA(HLMTIENS,"MSH")
  1.  ; if no header quit
  1.  ;**109**
  1.  ;I '$O(HLHDRO(0)) L -^HLMA(HLMTIENS) Q
  1.  Q:'$O(HLHDRO(0))
  1.  ;
  1.  S HL("FS")=$E(HLHDRO(1,0),4),HL("ECH")=$$P^HLTPCK2(.HLHDRO,2),HL("SFN")=$$P^HLTPCK2(.HLHDRO,4),HL("RFN")=$$P^HLTPCK2(.HLHDRO,6),HL("DTM")=$$P^HLTPCK2(.HLHDRO,7)
  1.  ;
  1.  ; patch HL*1.6*109 start
  1.  ; quit if ien of #772 is not defined
  1.  Q:'HLMTIEN
  1.  ; quit if field separator is not defined
  1.  Q:HL("FS")=""
  1.  ; patch HL*1.6*109 end
  1.  ;
  1.  S X=$$P^HLTPCK2(.HLHDRO,1)
  1.  ;
  1.  ; patch HL*1.6*120 start
  1.  I X="MSH" D
  1.  . S HL("PID")=$$P^HLTPCK2(.HLHDRO,11),HL("VER")=$$P^HLTPCK2(.HLHDRO,12),HL("APAT")=$$P^HLTPCK2(.HLHDRO,16),HL("CC")=$$P^HLTPCK2(.HLHDRO,17)
  1.  . ;
  1.  . ; 2nd component is Processing mode
  1.  . S HL("PMOD")=$P(HL("PID"),$E(HL("ECH"),1),2)
  1.  . ; first component is Processing id
  1.  . S HL("PID")=$P(HL("PID"),$E(HL("ECH"),1))
  1.  ;
  1.  I X'="MSH" D
  1.  . S X=$$P^HLTPCK2(.HLHDRO,9),Z=$E(HL("ECH")),HL("PID")=$P(X,Z,2),HL("VER")=$P(X,Z,4)
  1.  . ;
  1.  . ; original implementation incorrectly treats repetition separator as
  1.  . ; subcomponent separator
  1.  . I $E(HL("ECH"),2)]"",X[$E(HL("ECH"),2) D
  1.  .. S HL("SUB-COMPONENT")=$E(HL("ECH"),2)
  1.  . ; if subcomponent separator is correctly applied
  1.  . I $E(HL("ECH"),4)]"",X[$E(HL("ECH"),4) D
  1.  .. S HL("SUB-COMPONENT")=$E(HL("ECH"),4)
  1.  . ;
  1.  . I $D(HL("SUB-COMPONENT")),HL("PID")[HL("SUB-COMPONENT") D
  1.  .. ; 2nd sub-component is Processing mode
  1.  .. S HL("PMOD")=$P(HL("PID"),HL("SUB-COMPONENT"),2)
  1.  .. ; first sub-component is Processing id
  1.  .. S HL("PID")=$P(HL("PID"),HL("SUB-COMPONENT"))
  1.  . ; patch HL*1.6*120 end
  1.  . ;
  1.  . Q:$$P^HLTPCK2(.HLHDRO,10)=""
  1.  . ;HLMSA=ack code^id^text
  1.  . S HLMSA=$P($$P^HLTPCK2(.HLHDRO,10),$E(HL("ECH")),1),$P(HLMSA,HL("FS"),2)=$$P^HLTPCK2(.HLHDRO,12),$P(HLMSA,HL("FS"),3)=$P($$P^HLTPCK2(.HLHDRO,10),$E(HL("ECH")),2),HL("MSAID")=$P(HLMSA,HL("FS"),2)
  1.  ;
  1.  ; HL*1.6*108
  1.  ; quit if this is a commit ack
  1.  I $P($G(^HL(772,HLMTIEN,"IN",1,0)),HL("FS"),1)="MSA",$E($P($G(^HL(772,HLMTIEN,"IN",1,0)),HL("FS"),2))="C" Q
  1.  ; ** 
  1.  ;
  1.  ;**  HL*1.6*117 **
  1.  K HLL("SET FOR APP ACK"),HLL("LINKS")
  1.  ;** END HL*1.6*117 **
  1.  ;
  1.  D CONT
  1.  Q
  1.  ;
  1. MSA(Y) ;Y=ien in 772, returns MSA segment
  1.  ;ack code^msg being ack id^text
  1.  N X
  1.  S X=$G(^HL(772,Y,"IN",1,0)),X=$S($E(X,1,3)="MSA":$E(X,5,999),1:"")
  1.  Q X
  1.  ;
  1. ERROR ;error trap
  1.  D ^%ZTER
  1.  I $G(HLMTIENS),$D(^HLMA(HLMTIENS,0)) D STATUS^HLTF0(HLMTIENS,4,,,1),EXIT
  1.  ;*109* release all locks created by inbound filer
  1.  L -^HLMA("AC","I",+$G(HLXX))
  1.  G UNWIND^%ZTER
  1.  ;
  1.  ;
  1. EXIT ;unlock
  1.  I $G(HLMTIENS) L -^HLMA(HLMTIENS)
  1.  Q
  1.  ;
  1. ONAC(IEN773) ;
  1.  ;Returns 1 if the message is on the "AC","I" xref
  1.  ;Returns 0 otherwise
  1.  ;
  1.  N LINK
  1.  S LINK=$P($G(^HLMA(IEN773,0)),"^",17)
  1.  Q:'LINK 0
  1.  Q $D(^HLMA("AC","I",LINK,IEN773))