Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: INHMS4

INHMS4.m

Go to the documentation of this file. 
  1. INHMS4 ;JSH,DJL; 24 Jan 95 14:03;Interface - Message Search
  1.  ;;3.01;BHL IHS Interfaces with GIS;;JUL 01, 2001
  1.  ;COPYRIGHT 1991-2000 SAIC
  1.  ;
  1. GATHER(INSRCH,INDA,IND,INRVSRCH) ; Collect search criteria data
  1.  ; MODULE NAME: GATHER ( Search Criteria Gathering Routine )
  1.  ; DESCRIPTION: Gather the list of user selected search criteria and
  1.  ;              manipulate IND search starting variable depending on
  1.  ;              the INVRSRCH flag setting. Notify the user if the
  1.  ;              search may span a large numbe of messages and give
  1.  ;              the option of discontinuing the search
  1.  ; RETURN = none
  1.  ; PARAMETERS:
  1.  ;    INSRCH = Array for holding search criteria information
  1.  ;    INDA = Unique IEN into ^INTHU(4001.1) where ^DWC puts the
  1.  ;           user entered search criteria information
  1.  ;    IND = The starting time/date of the search set from information
  1.  ;          in INSRCH and determined by INRVSRCH flag
  1.  ;    INRVSRCH = Flag set user indicating direction of the search
  1.  ;          -1 = (default)a reverse listing order. Newest to Oldest
  1.  ;           1 = a forward search listing order. Oldest to Newest
  1.  ; CODE BEGINS
  1.  N X,INSRCHST,INSRCHEN,INNODE,INTEMP
  1.  S INNODE=1
  1.  F X="INSTART","INDEST","INSTAT","INID","INSOURCE","INDIR","INORIG","INPAT","INTEMP","INTYPE","INORDER","INEXPAND" S INSRCH(X)=$G(^DIZ(4001.1,INDA,INNODE)),INNODE=INNODE+1
  1.  S INSRCH("INEND")=$G(^DIZ(4001.1,INDA,1.1))
  1.  I $D(^DIZ(4001.1,INDA,9,0)) S INNODE=0 F  S INNODE=$O(^DIZ(4001.1,INDA,9,INNODE)) Q:'INNODE  S INSRCH("INTEXT")=INNODE,INSRCH("INTEXT",INNODE)=^DIZ(4001.1,INDA,9,INNODE,0)
  1.  S:'INSRCH("INEND")!(INSRCH("INEND")=DT) (INSRCH("INEND"),^DIZ(4001.1,INDA,1.1))=DT_".24"
  1.  I (INSRCH("INEND")-INSRCH("INSTART"))<0 D
  1.  .  ; a RECENT to PAST search criteria
  1.  .  S:(INSRCH("INEND")\1=INSRCH("INEND")) INSRCH("INEND")=INSRCH("INEND")-.0000001
  1.  .  S INTEMP=INSRCH("INSTART"),INSRCH("INSTART")=INSRCH("INEND")
  1.  .  I (INTEMP\1)=INTEMP S INSRCH("INEND")=INTEMP+.999999
  1.  .  I (INTEMP\1)'=INTEMP S INSRCH("INEND")=INTEMP
  1.  E  D
  1.  .  ; a PAST to RECENT search criteria
  1.  .  I (INSRCH("INEND")\1=INSRCH("INEND")) S INSRCH("INEND")=INSRCH("INEND")+.999999
  1.  .  E  S INSRCH("INEND")=INSRCH("INEND")+.000099 ; Because second resolution can not be entered
  1.  .  S INSRCH("INSTART")=INSRCH("INSTART")-.0000001
  1.  ; set the search string match type (AND/OR)
  1.  S:($D(INSRCH("INTEXT"))>9)&('INSRCH("INTYPE")) (INSRCH("INTYPE"),^DIZ(4001.1,INDA,10))=0
  1.  ; set the search starting point, (listing direction dependent)
  1.  S:'$G(INSRCH("INORDER")) (INSRCH("INORDER"),^DIZ(4001.1,INDA,11))=0
  1.  S IND=$S('INSRCH("INORDER"):INSRCH("INEND"),1:INSRCH("INSTART"))
  1.  S INRVSRCH=$S('INSRCH("INORDER"):-1,1:1)
  1.  Q
  1.  ;
  1. SRCHSIZE(INSRCH) ; Determine the expected search size
  1.  ; MODULE NAME: SRCHSIZE ( Determine the expected Search Size )
  1.  ; DESCRIPTION: Determine the expected number of message that will
  1.  ;              be searched. Warn of very large searches and provide
  1.  ;              a mechanism to abort the search.
  1.  ;              Uses the Start-Date and End-Date of span to search to
  1.  ;              determine the size(approximate).
  1.  ; RETURNS: -1 = The user aborted the search
  1.  ;          Number of messages in the search
  1.  ; PARAMETERS:
  1.  ;    INSRCH = Array for holding search criteria information
  1.  ; CODE BEGINS
  1.  N INSRCHEN,INSRCHST,INTEMP,INMSGCT,INSIZE,INWRNSZ
  1.  ; INWRNSZ= the water-mark on when to notify the user of the search size
  1.  S INWRNSZ=5000,INSIZE=0,INTEMP=$O(^INTHU("B",INSRCH("INSTART")))
  1.  I INTEMP,(INTEMP<INSRCH("INEND")) S INSRCHST=$O(^INTHU("B",INTEMP,"")),INTEMP=$O(^INTHU("B",INSRCH("INEND")),-1),INSRCHEN=$O(^INTHU("B",INTEMP,""),-1),(INMSGCT,INSIZE)=(INSRCHEN-INSRCHST)+1
  1.  I INTEMP,(INTEMP<INSRCH("INEND")),(INMSGCT>INWRNSZ) D
  1.  .  W !! D ERR^INHMS2("WARNING: Approximate search size="_INMSGCT_" messages. This may take awhile.")
  1.  .  I '$$YN^UTSRD("Do you want to continue with THIS search? ") S INSIZE=-1
  1.  Q INSIZE
  1.  ;