Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: INHOA

INHOA.m

Go to the documentation of this file. 
  1. INHOA ;JMB; 15 Sep 95 08:27; Background Process Monitor
  1.  ;;3.01;BHL IHS Interfaces with GIS;;JUL 01, 2001
  1.  ;COPYRIGHT 1991-2000 SAIC
  1.  ;
  1.  Q
  1. EN ;Called from INHOP
  1.  ;NEW statements
  1.  N BP0,BPC,INDAT,INQUEUE,INTOTAL,INDV,INDQ,X,OC
  1.  N DA,INDEST,DTOUT,GL,H,M,S,TAB,CUR
  1.  N INEXIT,IN0,INH,INI,INL,INRUN,INITER,INK,INQ,INWARN,INSIG,INT
  1.  N INRUNASC,INRUNAVG,P,SEL,T,TOP,STAT
  1.  ;
  1.  ;Initialize report variables
  1.  S INITER=0,INEXIT=0,INPAR("START")=$H
  1.  S BPC=$P(INPAR("PROCESS"),U)
  1.  ;Initialize TABs 
  1.  S TAB(1)=5,TAB(2)=37,TAB(3)=49,TAB(4)=58,TAB(5)=66,TAB(6)=74
  1.  ;
  1.  ;Queue size parameter
  1.  S INPAR("MSGSTART")=$P(^INTHU(0),U,3),INPAR("TSKSTART")=$P(^INLHFTSK(0),U,3)
  1.  ;Init INDAT array, save INDAT
  1.  D INIARR(BPC),SQ
  1.  ;
  1. ENRPT ;Repeat entry point
  1.  ;
  1.  ;Init scan variables
  1.  S INITER=INITER+1,(INPAR("QSTART"),INPAR("REPSTART"))=$H
  1.  S (INWARN,INSIG,INTOTAL,INQUEUE)=0
  1.  D P1(BPC) G:INEXIT EXIT ;Verify status
  1.  D P3(BPC) G:INEXIT EXIT ;Top entries
  1.  D P2(BPC) G:INEXIT EXIT ;Queue size
  1.  ;
  1.  G:$$QUIT^INHUTS EXIT ;handles INPAR("REPAINT")=0
  1.  ;hang until next recalculation
  1.  F X=1:1:INPAR("REPAINT") S:'INTASKED INEXIT=$$QUIT^INHUTS Q:INEXIT  H 1
  1.  G:INEXIT EXIT
  1.  G ENRPT
  1.  ;
  1. EXIT ;End of program
  1.  ;Close device
  1.  D ^%ZISC
  1.  Q
  1.  ;
  1. P1(BPC) ;Part 1: Verify status of background process
  1.  ;
  1.  ;Restore INDAT stats
  1.  D RV
  1.  ;Set warning flag INWARN to 1 if another user is running this report.
  1.  L +^INTHPC("AVERIFY"):1 E  S INWARN=1
  1.  D VERIFY^INHOV1(BPC)
  1.  L:'INWARN -^INTHPC("AVERIFY")
  1.  ;
  1.  Q:INEXIT
  1.  ;Repeat display for terminals 1 time for printers
  1.  I 'INTASKED D DISV^INHOA1
  1.  ;Check for end of tasked report
  1.  I INTASKED,INITER'<INPAR("ITER") D DISV^INHOA1 D SV Q
  1.  ;
  1.  ;Save INDAT stats
  1.  D SV
  1.  Q
  1.  ;
  1. P2(BPC) ;Part 2: Queue size sorted by priority
  1.  ;  Notice that: INDAT(1) - Format Controller  (BPC=2)
  1.  ;               INDAT(2) - Output Controller  (BPC=1)
  1.  ;
  1.  ;Restore INDAT
  1.  D RQ
  1.  ;init INDAT by priority for next scan
  1.  D IND^INHOQR2
  1.  ;Format controller, Notice that when $$QUEUE=1 => INEXIT=1
  1.  I BPC=2 Q:'$$QUEUE^INHOQR1("^INLHFTSK(""AH"")",$P(^INTHPC(2,0),U),1)
  1.  ;Output Controller
  1.  I BPC=1 Q:'$$QUEUE^INHOQR1("^INLHSCH",$P(^INTHPC(1,0),U),2)
  1.  ;Destination queue
  1.  I ";1;2;"'[BPC Q:'$$QUEUE^INHOQR1(U_$P(INDEST(BPC),U,2),$P(INDEST(BPC),U),BPC)
  1.  ;
  1.  ;Provide support for message creation rates
  1.  Q:'$$ENTRIES^INHOQR1("^INTHU","Messages created per hour",700,"MSGSTART")
  1.  ;
  1.  ;Provide support for transaction identification rates
  1.  Q:'$$ENTRIES^INHOQR1("^INLHFTSK","Transactions identified per hour",750,"TSKSTART")
  1.  ;
  1.  ;Repeat display for terminals, one time for printers
  1.  I 'INTASKED D DISQ^INHOA1
  1.  ;Check for end of tasked report
  1.  ; NOTICE: INEXIT=1 to exit (completed last part of report)
  1.  I INTASKED,INITER'<INPAR("ITER") D DISQ^INHOA1 S INEXIT=1 Q
  1.  ;
  1.  ;save INDAT
  1.  D SQ
  1.  Q
  1.  ;
  1. P3(BPC) ;Part 3: Show top entries in queue
  1.  ;
  1.  ;Init INDAT
  1.  K INDAT
  1.  ;Format controller
  1.  I BPC=2 I '$$QUEUE^INHOQT1("^INLHFTSK(""AH"")",2) S INEXIT=1 Q
  1.  ;Output Controller
  1.  I BPC=1 I '$$QUEUE^INHOQT1("^INLHSCH",1) S INEXIT=1 Q
  1.  ;Destination queues
  1.  I ";1;2;"'[BPC I '$$QUEUE^INHOQT1(U_$P(INDEST(BPC),U,2),BPC) S INEXIT=1 Q
  1.  ;
  1.  Q:INEXIT
  1.  ;display report
  1.  D:'INTASKED DIST^INHOA1
  1.  ;Check for end of tasked report
  1.  I INTASKED,INITER'<INPAR("ITER") D DIST^INHOA1 K INDAT Q
  1.  ;
  1.  ;Delete INDAT 
  1.  K INDAT
  1.  ;
  1.  Q
  1.  ;
  1. INIARR(BP) ;Init INDAT,INDEST for Queue size report
  1.  ;OUTPUT:
  1.  ;  INDAT - array of data for each queue
  1.  ;
  1.  ;Determine destination to check
  1.  D INITQ(BP)
  1.  ; 
  1.  ;Intialize data arrays
  1.  S BP=$S(BP=1:2,BP=2:1,1:BP)
  1.  D DATINIT(BP)
  1.  ;
  1.  F BP=700,750 D DATINIT(BP)
  1.  Q
  1.  ;
  1. DATINIT(INQ) ;Initialize data array
  1.  ;INPUT:
  1.  ;  INQ - queue entry (usually ien in Back Proc Control file)
  1.  ;OUTPUT:
  1.  ;  INDAT - array of initialized data for a queue
  1.  ;
  1.  F X="COUNT","MIN","MAX","AVG","NAME","ITER","TOTC" S INDAT(INQ,X)=""
  1.  Q
  1.  ;
  1. INITQ(BPC) ;Init
  1.  N BP0,D
  1.  S BP0=$G(^INTHPC(BPC,0))
  1.  S D=$P(BP0,U,7) Q:'D
  1.  ;Check if process is NOT active and no messages in queue
  1.  Q:'$P(BP0,U,2)&'$D(^INLHDEST(D))
  1.  S INDEST(BP)=$P(BP0,U)_U_"INLHDEST("_D_")"
  1.  Q
  1.  ;
  1. RV M INDAT=INDV K INDV Q
  1. SV M INDV=INDAT K INDAT Q
  1. RQ M INDAT=INDQ K INDQ Q
  1. SQ M INDQ=INDAT K INDAT Q