Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: INHOQR1

INHOQR1.m

Go to the documentation of this file. 
  1. INHOQR1 ; FRW/JMB ; 24 Aug 95 14:18; Show GIS queue status - cont.
  1.  ;;3.01;BHL IHS Interfaces with GIS;;JUL 01, 2001
  1.  ;COPYRIGHT 1991-2000 SAIC
  1.  ;
  1. EN ;Main entry point
  1.  G EN^INHOQR
  1.  Q
  1.  ;
  1. ENZTSK ;Taskman entry point
  1.  ;New Statements
  1.  N BP,BPC,BP0,COUNT,CUR,D,DATA,DATE,DTOUT,DTSAR,DTSOP,EXIT,FMT,GL,H,HDR
  1.  N INDEST,INEXIT,INITER,INQ,INQUEUE,INRUN,INRUNASC
  1.  N IN0,INDAT,INRUNAVG,INTOTAL,LOOP,M,NAME,NODE,OC,P,PAGE,S,X
  1.  N SAR,SEC,SEOV,SESAR,SESARTOT,SESOP,SESOPTOT,SOP,STAT,T,TAB,TOT
  1.  ;
  1.  ;Initialize report variables
  1.  S INEXIT=0,INPAR("START")=$H,INITER=0 H 1
  1.  S INPAR("MSGSTART")=$P(^INTHU(0),U,3),INPAR("TSKSTART")=$P(^INLHFTSK(0),U,3)
  1.  ;Initialize TABs
  1.  S TAB(0)=34,TAB(1)=44,TAB(2)=52,TAB(3)=60,TAB(4)=68
  1.  ;Intialize data array
  1.  D INIARR^INHOQR
  1.  ;Display message
  1.  W:'INTASKED !!,"Compiling ..."
  1.  ;
  1. ENRPT ;Repeat entry point
  1.  ;
  1.  ;Init scan variables
  1.  S INTOTAL=0,INQUEUE=0,INITER=INITER+1
  1.  S (INPAR("REPSTART"),INPAR("QSTART"))=$H
  1.  ;Init queue count by priority for next scan
  1.  D IND^INHOQR2
  1.  ;Format controller
  1.  G:'$$QUEUE("^INLHFTSK(""AH"")",$P(^INTHPC(2,0),U),1) EXIT
  1.  ;Output Controller
  1.  G:'$$QUEUE("^INLHSCH",$P(^INTHPC(1,0),U),2) EXIT
  1.  ;Destination queues
  1.  S BPC=0
  1.  F  S BPC=$O(INDEST(BPC)) Q:'BPC!INEXIT  Q:'$$QUEUE(U_$P(INDEST(BPC),U,2),$P(INDEST(BPC),U),BPC)
  1.  G:INEXIT EXIT
  1.  ;
  1.  ;Provide support for totals
  1.  D ST1(400,INTOTAL,"Queue Total")
  1.  ;
  1.  ;Provide support for message creation rates
  1.  Q:'$$ENTRIES("^INTHU","Messages created per hour",700,"MSGSTART")
  1.  ;
  1.  ;Provide support for transaction identification rates
  1.  Q:'$$ENTRIES("^INLHFTSK","Transactions identified per hour",750,"TSKSTART")
  1.  ;
  1.  ;Repeat display for terminals, one time for printers
  1.  D:'INTASKED DISP^INHOQR2
  1.  ;Check for end of tasked report
  1.  I INTASKED,INITER'<INPAR("ITER") D DISP^INHOQR2 G EXIT
  1.  ;
  1.  ;hang until next recalc
  1.  G:$$QUIT EXIT
  1.  F X=1:1:INPAR("REPAINT") Q:$$QUIT!INEXIT  H 1
  1.  G:INEXIT EXIT
  1.  G ENRPT
  1.  Q
  1.  ;
  1. QUEUE(GL,Q,INQUEUE) ;Determine entries in queue
  1.  ;INPUT:
  1.  ;  GL - location (global) of queue
  1.  ;         queue in format -> @GL@( priority , time to process , ien )
  1.  ;  Q  - name of queue
  1.  ;  INQUEUE - subscript (usually ien) of queue in INDAT array
  1.  ;OUTPUT:
  1.  ;  function - complete processing ( 0 - no ; 1 - yes )
  1.  ;  updated INDAT array with latest queue size data
  1.  ;  updated INTOTAL with total number of entries in all queues
  1.  ;
  1.  ;Intialize variables
  1.  S INPAR("QSTART")=$H,OC=0,P=999,STAT=1
  1.  F  S P=$O(@GL@(P),-1) Q:+P'=P!INEXIT  S H="~" F  S H=$O(@GL@(P,H),-1) Q:'$L(H)!INEXIT  D
  1.  .  ;Check wether to report tasks in the future
  1.  .  I +H>+$H,'INPAR("FUTURE") Q
  1.  .  ;Check wether to report tasks in the future
  1.  .  I $P(H,",",2)>$P($H,",",2),+H=+$H,'INPAR("FUTURE") Q
  1.  .  S M=" " F  S M=$O(@GL@(P,H,M),-1) Q:'M  D  I '(OC#1000),$$QUIT S STAT=0
  1.  ..  S OC=OC+1
  1.  ..  Q:'INPAR("DETAIL")
  1.  ..  ;count entries by priority (P) and Time (NST=Non stat or ST=Stat)
  1.  ..  I H S INDAT(INQUEUE,P,"STN","COUNT")=$G(INDAT(INQUEUE,P,"STN","COUNT"))+1 Q
  1.  ..  S:'H INDAT(INQUEUE,P,"ST","COUNT")=$G(INDAT(INQUEUE,P,"ST","COUNT"))+1
  1.  ;Stats with priorities
  1.  D:INPAR("DETAIL") ST0(INQUEUE)
  1.  ;Stats totals
  1.  D ST1(INQUEUE,OC,Q)
  1.  ;Update total queue entries
  1.  S INTOTAL=INTOTAL+INDAT(INQUEUE,"COUNT")
  1.  Q STAT
  1.  ;
  1. ENTRIES(GL,NAME,INQ,NODE) ;Get entries created in file / hour
  1.  ;INPUT:
  1.  ;  GL - location (global) of file
  1.  ;         file in format -> @GL@( ien )
  1.  ;  NAME  - name of queue
  1.  ;  INQ - subscript of queue in INDAT array
  1.  ;  NODE - node in INPAR that contains the last entry in the file
  1.  ;         when the report was started
  1.  ;OUTPUT:
  1.  ;  function - complete processing ( 0 - no ; 1 - yes )
  1.  ;  updated INDAT array with latest queue size data
  1.  ;
  1.  S CUR=$P(@GL@(0),U,3) S:'INPAR(NODE) INPAR(NODE)=CUR
  1.  S OC=CUR-INPAR(NODE)/($$TDIF^INHUTS(INPAR("START"))+.00001)*3600\1
  1.  D ST1(INQ,OC,NAME)
  1.  Q 1
  1.  ;
  1. ST0(INQ) ;Build Stats - Priority levels
  1.  ;INPUT:
  1.  ;  INQ   = Process Id#
  1.  ;OUTPUT:
  1.  ;  updated INDAT array with latest queue size sorted by priority
  1.  ;
  1.  N P,T,COUNT
  1.  S P=""
  1.  F  S P=$O(INDAT(INQ,P)) Q:+P'=P  S T="" F  S T=$O(INDAT(INQ,P,T))  Q:'$L(T)  D
  1.  .S COUNT=INDAT(INQ,P,T,"COUNT")
  1.  .;Minimum
  1.  .S:COUNT<$G(INDAT(INQ,P,T,"MIN"))!($G(INDAT(INQ,P,T,"MIN"))="") INDAT(INQ,P,T,"MIN")=COUNT
  1.  .;Maximum
  1.  .S:COUNT>$G(INDAT(INQ,P,T,"MAX"))!($G(INDAT(INQ,P,T,"MAX"))="") INDAT(INQ,P,T,"MAX")=COUNT
  1.  .;Total entries sorted by priority-time (T is either "ST"
  1.  .; for STAT or"STN" for Non Stat entries)
  1.  .S INDAT(INQ,P,T,"TOTC")=$G(INDAT(INQ,P,T,"TOTC"))+COUNT
  1.  .;Current average number of entries  by priority-time
  1.  .S INDAT(INQ,P,T,"AVG")=INDAT(INQ,P,T,"TOTC")\INITER
  1.  Q
  1.  ;
  1. ST1(INQ,COUNT,NAME) ;Stats - Queue Totals
  1.  ;INPUT
  1.  ;  INQ
  1.  ;  COUNT
  1.  ;  NAME
  1.  ;OUTPUT
  1.  ;  INDAT array with total stats
  1.  ;
  1.  ;Negative numbers not allowed
  1.  S:+$G(COUNT)<0 COUNT=0
  1.  ;Current count
  1.  S INDAT(INQ,"COUNT")=COUNT
  1.  ;Queue name
  1.  S:$L($G(NAME)) INDAT(INQ,"NAME")=NAME
  1.  ;Minimum
  1.  S:INDAT(INQ,"MIN")="" INDAT(INQ,"MIN")=COUNT
  1.  S:COUNT<INDAT(INQ,"MIN") INDAT(INQ,"MIN")=COUNT
  1.  ;Maximum
  1.  S:INDAT(INQ,"MAX")="" INDAT(INQ,"MAX")=COUNT
  1.  S:COUNT>INDAT(INQ,"MAX") INDAT(INQ,"MAX")=COUNT
  1.  ;Total entries found in all scans
  1.  S INDAT(INQ,"TOTC")=INDAT(INQ,"TOTC")+COUNT
  1.  ;Current average number of entries of all scans
  1.  S INDAT(INQ,"AVG")=INDAT(INQ,"TOTC")\INITER
  1.  ;
  1.  ;PROVIDE Support for data array to be used in graphing
  1.  Q
  1.  ;
  1. QUIT() ;Determine if program should quit
  1.  ;INPUT:
  1.  ;  INEXIT - quit flag
  1.  ;OUTPUT:
  1.  ;  INEXIT - quit flag
  1.  ;  function -  1 - time to exit ; 0 - continue
  1.  ;
  1.  ;Quit If:
  1.  ;report time calculation takes too long
  1.  I 'INPAR("RUNTOEND"),$$TDIF^INHUTS(INPAR("REPSTART"))>INPAR("MAXREPTIME") S INEXIT=1 Q INEXIT
  1.  ;queue time calculation takes too long
  1.  I 'INPAR("RUNTOEND"),$$TDIF^INHUTS(INPAR("QSTART"))>INPAR("MAXQTIME") S INEXIT=1 Q INEXIT
  1.  ;user presses <any key>
  1.  I 'INTASKED S INEXIT=$$QUIT^INHUTS
  1.  Q INEXIT
  1.  ;
  1. EXIT ;Primary exit point
  1.  ;Close device
  1.  D ^%ZISC
  1.  Q