Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: INHRSE

INHRSE.m

Go to the documentation of this file. 
  1. INHRSE ; FRW,DP ; 16 May 96 11:15; Interface message size report
  1.  ;;3.01;BHL IHS Interfaces with GIS;;JUL 01, 2001
  1.  ;COPYRIGHT 1991-2000 SAIC
  1.  Q
  1. EN ;main entry point
  1.  N INLOAD,INDES,INBEG,INEND,FLG,INDEST,INLN,GTOT,GTOTL,L,MSG,MSGDTTM,NONE,PAG,PCOUNT,PGTOT,PERF,SIZE,SUB,TM,TOT,TT,TT1,X,X1,X2,X3,X4,%DT,ACTZE,AVGCON,AVGMSG,BEG,CNT,CON,COUNT,D,DES,DIC,LOOP,LOOP1,DTTM,ZE
  1.  W @IOF Q:'$$PARM
  1.  ; Device handling & Tasking logic
  1.  K IOP S %ZIS("A")="QUEUE ON DEVICE: ",%ZIS("B")="",%ZIS="NQ"
  1.  W ! D ^%ZIS G:POP QUIT
  1.  S:IOM<132 IOM=132 S IOP=ION_";"_IOST_";"_IOM_";"_IOSL
  1.  I IO=IO(0) S %ZIS="" D ^%ZIS I POP W *7,!,"Sorry, unable to find device..." G QUIT
  1.  I IO'=IO(0) S ZTDESC="Interface message size report",ZTIO=IOP,ZTRTN="ENQUE^INHRSE" D  G QUIT
  1.  .S ZTSAVE("INLOAD")=INLOAD D ^%ZTLOAD
  1. ENQUE ;Taskman entry point
  1.  K PERF,CREPERF S PERF="PERF",INDEST=0,FLG=0
  1.  S INBEG=$P(INLOAD,U),INEND=$P(INLOAD,U,2),INDES=$P(INLOAD,U,3)
  1.  I $L(INDES)>1 S INDEST=1 F I=1:1:$L(INDES,",")-1 S DES($P(INDES,",",I))=""
  1.  D COMP(.PERF,.CREPERF)
  1.  D SUM(.PERF)
  1.  D OUTPUT(.PERF)
  1.  ;
  1. QUIT ;Exit point
  1.  D ^%ZISC
  1.  Q
  1.  ;
  1. PARM() ;Get parameters
  1.  S DIC=4005,DIC(0)="AEMNQZ"
  1.  D DES Q:'Y  Q:POP 0
  1.  S INBEG=0,INEND=0
  1.  Q:'$$GETRNG(.INBEG,.INEND,.INABEG,.INAEND) 0
  1.  S INLOAD=INBEG_U_INEND_U_INDES_U_INABEG_U_INAEND
  1.  Q 1
  1.  ;
  1. COMP(PERF,CREPERF) ;Compile statistics
  1.  ;
  1.  ;;   PERF      - message array.
  1.  ;;   CREPERF   - control array.
  1.  ;
  1.  S BEG=INBEG-.000001
  1.  I $P(IOST,"-")["C",IO=IO(0) W !,"Compiling data "
  1.  F CNT=0:1  S BEG=$O(^INTHU("B",BEG)) Q:BEG=""!(BEG>INEND)  D
  1.  .I $P(IOST,"-")["C",IO=IO(0) W:'(CNT#1000) "."
  1.  .S LOOP="" F  S LOOP=$O(^INTHU("B",BEG,LOOP)) Q:LOOP=""  D
  1.  ..  ;Check destination
  1.  ..  S ZE=$G(^INTHU(LOOP,0))
  1.  ..  S DES=$P(ZE,U,2) S:DES="" DES="NULL"
  1.  ..  ;Determine transaction type
  1.  ..  I INDEST Q:'$D(DES(DES))
  1.  ..  S TT=$P(ZE,U,11)
  1.  ..  S TT1=$P($G(^INRHT(+TT,0)),U) S:TT1="" TT1="NULL"
  1.  ..  S:'TT TT=DES_U_"D" I 'TT S TT="NULL"
  1.  ..  I TT["D",+DES S TT1=$P($G(^INRHD(DES,0)),U)
  1.  ..  S MSGDTTM=+$E($P(ZE,U,1),1,10)
  1.  ..  S SIZE=$$SIZE(LOOP)
  1.  ..  ;check for empty messages
  1.  ..  S:'SIZE PERF(TT1,TT,2)=$G(PERF(TT1,TT,2))+1
  1.  ..  S PERF(TT1,TT)=$G(PERF(TT1,TT))+1
  1.  ..  S PERF(TT1,TT,1)=$G(PERF(TT1,TT,1))+SIZE
  1.  ..  S PERF(TT1,TT,3)=$G(PERF(TT1,TT,3))+$P(SIZE,U,2)
  1.  Q
  1.  ;
  1. SIZE(LOOP) ;Get size of message
  1.  Q:'$G(LOOP) 0 N ACT,SZ,MSGSZ,DA
  1.  S ACT="^INTHU("_LOOP_")",MSGSZ=0,SZ=0
  1.  F  S ACT=$Q(@ACT) Q:$$QS^INHUTIL(ACT,1)'=LOOP  D
  1.  .   S SUB=$$QS^INHUTIL(ACT,2),DA=$G(@ACT),ACTZE=$L(DA)
  1.  .   I SUB=3 S SZ=SZ+ACTZE Q
  1.  .   S MSGSZ=MSGSZ+ACTZE
  1.  Q SZ_U_MSGSZ
  1.  ;
  1. SUM(BREF,LEVEL) ;summarize array data
  1.  K TOT S LOOP=""
  1.  F X=0:1:3 S TOT(X)=0
  1.  F  S LOOP=$O(PERF(LOOP)) Q:LOOP=""  S LOOP1="" D
  1.  .F  S LOOP1=$O(PERF(LOOP,LOOP1)) Q:LOOP1=""  D
  1.  ..  S TOT(0)=$G(PERF(LOOP,LOOP1))+TOT(0)
  1.  ..  F I=1:1:3 S TOT(I)=$G(PERF(LOOP,LOOP1,I))+TOT(I)
  1.  Q
  1.  ;
  1. OUTPUT(BREF) ;Output data
  1.  ;INRHD - .02 - 4005 TT pointer
  1.  ;MSGSZ & CTLRSZ SHOW PERCENT OF TOTAL
  1.  S U1="%",PAG=1,TM=$$CDATASC^%ZTFDT($H,3,1) D SHDR
  1.  S DTTM="",GTOTL=(TOT(1)+TOT(3))/1000,POP=0
  1.  ; set tabs
  1.  S L(1)=49,L(2)=57,L(3)=65,L(4)=71,L(5)=81,L(6)=88,L(7)=95
  1.  F  S DTTM=$O(@BREF@(DTTM)) Q:DTTM=""!POP  S TT="" D
  1.  .  F  S TT=$O(@BREF@(DTTM,TT)) Q:TT=""!POP  D
  1.  ..  S CON=$G(@BREF@(DTTM,TT,3)),MSG=$G(@BREF@(DTTM,TT,1))
  1.  ..  S NONE=$G(@BREF@(DTTM,TT,2)),COUNT=$G(@BREF@(DTTM,TT))
  1.  ..  S:'COUNT COUNT=.000001
  1.  ..  S (AVGCON,AVGMSG)="*"
  1.  ..  I COUNT>0 S AVGCON=$J((CON+MSG)/COUNT,0,0),AVGMSG=$J(MSG/COUNT,0,0)
  1.  ..  W !!,$E(DTTM,1,40)
  1.  ..  W ?L(1)-$L(AVGCON),AVGCON,?L(2)-$L(AVGMSG),AVGMSG
  1.  ..  W ?L(3)-$L($J(CON/COUNT,0,0)),$J(CON/COUNT,0,0)
  1.  ..  W ?L(4)-$L(COUNT),COUNT
  1.  ..  S GTOT=CON+MSG,CON=$J(CON/1000,0,0),MSG=$J(MSG/1000,0,0)
  1.  ..  S GTOT=$J(GTOT/1000,0,0)
  1.  ..  ;
  1.  ..  ; calculate percentage ot total count
  1.  ..  S (PCOUNT,PGTOT)="*"
  1.  ..  I TOT(0)>0 S PCOUNT=$J(COUNT/TOT(0)*100,0,0)
  1.  ..  I GTOTL>0 S PGTOT=$J(GTOT/GTOTL*100,0,0)
  1.  ..  W ?L(5)-$L(GTOT),GTOT,?L(6)-$L(MSG),MSG,?L(7)-$L(CON),CON
  1.  ..  W !?L(4)-$L(PCOUNT),PCOUNT,U1,?L(5)-$L(PGTOT),PGTOT,U1
  1.  ..  S X="*" I GTOT>0 S X=$J(MSG/GTOT*100,0,0)
  1.  ..  W ?L(6)-$L(X),X,U1
  1.  ..  S X="*" I GTOT>0 S X=$J(CON/GTOT*100,0,0)
  1.  ..  W ?L(7)-$L(X),X,U1
  1.  ..  I $Y>(IOSL-6),$P(IOST,"-")["P" D HDR Q
  1.  ..  D:$Y>(IOSL-2) HDR
  1.  ;
  1.  ; display totals
  1.  Q:POP
  1.  N X S X="--------------------"
  1.  I TOT(0)<1 D END Q
  1.  I TOT(0)>0 D
  1.  .S X(1)=$J((TOT(1)+TOT(3))/TOT(0),0,0)
  1.  .S X(2)=$J(TOT(1)/TOT(0),0,0)
  1.  .S X(3)=$J(TOT(3)/TOT(0),0,0)
  1.  S X(4)=TOT(0)
  1.  S X(5)=$J((TOT(1)+TOT(3))/1000,0,0)
  1.  S X(6)=$J(TOT(1)/1000,0,0)
  1.  S X(7)=$J(TOT(3)/1000,0,0)
  1.  W ! F I=1:1:7 W ?L(I)-$L(X(I)),$E(X,1,$L(X(I)))
  1.  W !,"TOTAL" F I=1:1:7 W ?L(I)-$L(X(I)),X(I)
  1. P ; print text
  1.  S FLG=1 D:$Y+17>IOSL HDR Q:POP
  1.  W !!!! F I=1:1:13 S X=$P($T(TEXT+I),";;",2) D
  1.  .I $L(X)<IOM W !,X Q
  1.  .S X1=X F A=$L(X," "):-1 S X=$P(X1," ",1,A) I $L(X)<IOM S X1=$P(X1," ",A+1,99) Q
  1.  .W !,X,!?13,X1
  1. END ;I IO=$P,'POP S X=$$CR^UTSRD
  1.  I IO=IO(0),$E(IOST)'="P" S X=$$CR^UTSRD
  1.  W !! S X="*** End of Report ***" W !?IOM-$L(X)\2,X
  1.  W @IOF
  1.  Q
  1.  ;
  1. GETRNG(START,STOP,INABEG,INAEND) ;
  1.  ;get starting and ending dates
  1.  ;
  1.  N X,Y S START=1,STOP=999999999,INABEG=0
  1.  W ! Q:'$$IEN(.START,"Starting Date: ") 0
  1.  S INBEG=Y W !
  1.  S Y=$O(^INTHU("B",Y),-1) S:Y INABEG=$O(^INTHU("B",Y,""))
  1.  Q:'$$IEN(.STOP,"Ending Date: ") 0
  1.  S INEND=Y,X=$O(^INTHU("B",INEND,""))
  1.  S:INEND'["." INEND=INEND_".24"
  1.  ;calculate the approximate number of record to be proccesed
  1.  S Y=INEND+.000001
  1.  S Y=$O(^INTHU("B",Y),-1)
  1.  S INAEND=$O(^INTHU("B",Y,999999999999),-1)
  1.  W !!,"Approximately ",INAEND-INABEG," Records will be processed"
  1.  Q 1
  1.  ;
  1. IEN(IEN,ASK) ;
  1.  ;
  1.  S %DT="TAEX",%DT("A")=$G(ASK) D ^%DT Q:Y<1 0
  1.  S IEN=$Q(^INTHU("B",Y,0))
  1.  I $$QS^INHUTIL(IEN,1)'="B" S IEN="^INTHU(""B"",3000101,9999999999999)"
  1.  S IEN=$$QS^INHUTIL(IEN,2)
  1.  Q IEN
  1.  ;
  1. DES ;Get multiple destinations
  1.  N I S POP=0,INDES=""
  1.  F I=1:1 D  Q:POP  W:Y=-1&(INDES="") "ALL" Q:Y=-1
  1.  .D ^DIC S:X[U POP=1 Q:POP  Q:(+Y)<1
  1.  .S INDES=INDES_(+Y)_","
  1.  Q
  1. TEXT ;
  1.  ;;Count - Total number of Tansaction within a Tansaction type. 
  1.  ;;Average (Bytes) - All averages are calculated in Bytes (characters).
  1.  ;;   TotSize - Total message size + Total control size / count.
  1.  ;;   MsgSize - Total Bytes in a message / count
  1.  ;;   CtlSize - Total Bytes in the control / count.
  1.  ;;Totals (KBytes) - Totals are represented in KBytes (Byte/1000).
  1.  ;;   TotSize - Total number of KBytes in a transaction type.
  1.  ;;   MsgSz   - Total number of KBytes in a message section.
  1.  ;;   CtlSz   - Total number of KBytes in a control section.
  1.  ;;   %ofTot  - Percentage of the transaction type count of the total report count (Count / Total Count).
  1.  ;;   %GTot   - Percentage of total transaction type size out of total report (TotSize / Grand TotSize).
  1.  ;;   %TotM   - Percentage of the total message size out of TotSize (Totm/Gtot).
  1.  ;;   %TotC   - Percentage of total control size out of TotSize (TotC/Gtot).
  1.  Q
  1. SHDR ;set header
  1.  S X=$$CDATASC^%ZTFDT($H,1,1),INLN(0)=X_" Page "
  1.  S INLN(1)="Interface message size report"
  1.  S X="From: "_$$CDATASC^%ZTFDT($E(INBEG,1,10),3,1)
  1.  S INLN(2)=X_"      To: "_$$CDATASC^%ZTFDT($E(INEND,1,10),3,1)
  1.  ;get the site name
  1.  S INLN(6)=$S($D(^DIC(4,^DD("SITE",1),0)):^(0),1:^DD("SITE"))
  1.  S INLN(6)=$S($P(INLN(6),U,4)]"":$P(INLN(6),U,4),1:$P(INLN(6),U,1))
  1.  S INLN="",$P(INLN,"-",IOM+1)=""
  1.  ;
  1. HDR ;Print header
  1.  I $P(IOST,"-")["C",IO=IO(0) S X=$$CR^UTSRD I X S POP=1 Q
  1.  I PAG>1!($P(IOST,"-")["C") W @IOF
  1.  W !,INLN(6)
  1.  S X=INLN(0)_PAG,PAG=PAG+1
  1.  W ?IOM-$L(X)-1,X,!
  1.  F I=1,2 W !?IOM-$L(INLN(I))\2,INLN(I)
  1.  Q:FLG  W !!,"Destination: " D
  1.  .I 'INDES W "All" Q
  1.  .S D="" F  S D=$O(DES(D)) Q:D=""  W ?14,$P(^INRHD(D,0),U),!
  1.  W !,INLN,!?42,"----Average(Bytes)----",?75,"---Totals (KBytes)---"
  1.  W !,"Transaction Type"
  1.  W ?42,"TotSize MsgSize CtlSize  Count"
  1.  W ?75,"TotSize  MsgSz  CtlSz"
  1.  W !?67,"%ofTot   %GTot   %TotM  %TotC",!,INLN
  1.  Q