Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: INHSYS11

INHSYS11.m

Go to the documentation of this file. 
  1. INHSYS11 ;PO/SAIC; 17 Jun 99 15:45; installation utiltiy,  error summary 
  1.  ;;3.01;BHL IHS Interfaces with GIS;;JUL 01, 2001
  1.  ;COPYRIGHT 1991-2000 SAIC
  1.  ;;
  1.  ;
  1.  ;COPYRIGHT 1999 SAIC
  1.  Q
  1.  ;
  1. FLSUMERR(INFILE,INFLD,INIEN,INDAT,INROOT) ; record file/fields error summaries
  1.  ;Input:
  1.  ; INFILE  - file or sub-file number
  1.  ; INFDL   - field number
  1.  ; INIEN   - entry ien
  1.  ; INDAT   - data value of the field that calling program was trying to
  1.  ;           insert
  1.  ; INROOT  - root node of the entry
  1.  ;
  1.  Q:'$G(^UTILITY("INHSYS_FILERR",$J))   ;error summary will not be collected, if this node is not set to true
  1.  S ^UTILITY("INHSYS_FILERR",$J,+$G(INFILE),INROOT)=""
  1.  I INIEN>0 D   ; this is a failed field insert
  1.  .S ^UTILITY("INHSYS_FILERR",$J,+$G(INFILE),INROOT,"FLD",+$G(INIEN),+$G(INFLD))=INDAT
  1.  E  D          ; this is a failed DIC lookup
  1.  .S:INDAT="" INDAT="unknown .01 field"
  1.  .S ^UTILITY("INHSYS_FILERR",$J,+$G(INFILE),INROOT,"FILE",INDAT)=""
  1.  Q
  1.  ;
  1. FLRPTERR() ;report file/fields error summary
  1.  ;Input:
  1.  ;  None
  1.  ; Output
  1.  ;  returns 1 if any error was found
  1.  ;
  1.  N C,INCNT,INDAT,INERRMSG,INFILE,INFLD,INIEN,INX,INROOT,Y
  1.  Q:'$O(^UTILITY("INHSYS_FILERR",$J,0)) 0
  1.  D HEADER("FILE/FIELD RESTORE ERROR SUMMARY")
  1.  W !,"File number and name"
  1.  W !,?3,"Error Type",?23,".01 value or"
  1.  W !,?23,"Zero node --> Zero node value"
  1.  W !,?7,"Field#",?17,"Value"
  1.  D DASHLINE()
  1.  ;
  1.  S INFILE=0
  1.  F  S INFILE=$O(^UTILITY("INHSYS_FILERR",$J,INFILE)) Q:'INFILE  D
  1.  .;S INX=$P($G(^DIC(INFILE,0)),U)
  1.  .S INX=$O(^DD(+INFILE,0,"NM",""))
  1.  .W !,INFILE,"-",INX,!
  1.  .S INROOT=""
  1.  .F  S INROOT=$O(^UTILITY("INHSYS_FILERR",$J,INFILE,INROOT)) Q:INROOT=""  D
  1.  ..S INDAT=""
  1.  ..I $O(^UTILITY("INHSYS_FILERR",$J,INFILE,INROOT,"FILE",""))'="" W ?3,"Failed DIC Lookup"
  1.  ..F  S INDAT=$O(^UTILITY("INHSYS_FILERR",$J,INFILE,INROOT,"FILE",INDAT)) Q:INDAT=""  D
  1.  ...W ?23,INDAT,!
  1.  ..;
  1.  ..S INIEN=""
  1.  ..;I $O(^UTILITY("INHSYS_FILERR",$J,INFILE,INROOT,"FLD",""))'="" W ?3,"Failed Update:"
  1.  ..F  S INIEN=$O(^UTILITY("INHSYS_FILERR",$J,INFILE,INROOT,"FLD",INIEN)) Q:INIEN=""  D
  1.  ...;  get the external value of the field data
  1.  ...;  note: make sure C=$P(^DD(INFILE,.01,0),U,2) is exactly before the
  1.  ...;        call to Y^DIQ,  otherwise you get intermittent results
  1.  ...S Y=$P($G(@(INROOT_INIEN_",0)")),U),C=$P(^DD(INFILE,.01,0),U,2) D Y^DIQ
  1.  ...W ?3,"Failed Update",?23,(INROOT_INIEN_",0)"),"-->",Y,!
  1.  ...S INFLD=0
  1.  ...F  S INFLD=$O(^UTILITY("INHSYS_FILERR",$J,INFILE,INROOT,"FLD",INIEN,INFLD)) Q:INFLD=""  D
  1.  ....W ?7,INFLD,?17,^UTILITY("INHSYS_FILERR",$J,INFILE,INROOT,"FLD",INIEN,INFLD),!
  1.  W !!,"            ****  End of File/Field Restore Error Summary  ****",!
  1.  Q 1
  1.  ;
  1. SUMERR(INERRMSG) ;record the error messages for error summary
  1.  ;Input:
  1.  ;  INERRMSG  - error message text
  1.  ;
  1.  Q:'$G(^UTILITY("INHSYS_FILERR",$J))   ;error summary will not be collected, if this node is not set to true.  please notice the INHSYS_FILERR vs INSHSYS_SUMERR subscript.
  1.  N INCNT
  1.  S INCNT=$G(^UTILITY("INHSYS_SUMERR",$J))+1
  1.  S ^UTILITY("INHSYS_SUMERR",$J)=INCNT
  1.  S ^UTILITY("INHSYS_SUMERR",$J,INCNT)=INERRMSG
  1.  Q
  1.  ;
  1. RPTERR() ;report the error summary
  1.  ;Input:
  1.  ;  None
  1.  ; Output
  1.  ;  returns 1 if any error was found
  1.  N INCNT
  1.  Q:'$O(^UTILITY("INHSYS_SUMERR",$J,0)) 0
  1.  D HEADER("COMPILATION ERROR SUMMARY")
  1.  D DASHLINE()
  1.  S INCNT=0
  1.  F  S INCNT=$O(^UTILITY("INHSYS_SUMERR",$J,INCNT)) Q:'INCNT  D
  1.  .W !,^UTILITY("INHSYS_SUMERR",$J,INCNT)
  1.  W !!,"                ****  End of Compilation Error Summary  ****",!
  1.  Q 1
  1.  ;
  1.  ;Input:
  1.  ;  INTITLE - title of the header
  1.  ;
  1.  N INMTF,INTIME
  1.  S INMTF=$$GETMTF(),INTIME=$$CDATASC^%ZTFDT($H,1,1)
  1.  W !,INMTF,?(80-$L(INTIME)),INTIME
  1.  W !,$G(INTITLE)
  1.  Q
  1. DASHLINE() ; display a dashline
  1.  W !,"--------------------------------------------------------------------------------"
  1.  Q
  1.  ;
  1. SPRTCNTR() ; display a message to contact support center
  1.  W !!
  1.  W !,?9,"********************************************************"
  1.  W !,?9,"*  Errors encountered during this installation. It is  *"
  1.  W !,?9,"*  recommended that you contact the Support Center.    *"
  1.  W !,?9,"********************************************************"
  1.  W !!
  1.  Q
  1.  ;
  1. GETMTF() ;Get the name of the primary MTF (only one per CHCS system)
  1.  ;Input:
  1.  ;  none
  1.  ;Output:
  1.  ;  returns name of the primary MTF
  1.  N Y,X
  1.  S Y=$G(^DD("SITE",1)) Q:'Y ""
  1.  S X=$P($G(^DIC(4,Y,0)),U)
  1.  Q X
  1.  ;
  1. ALLSUMER(INKILL) ;report summary errors if any. kill the utility global if it is required
  1.  ;Input:
  1.  ;  INKILL  = if true kill the Utility global that contains these errors
  1.  ;
  1.  ;if error summary is requested, display it on the user's current device 
  1.  N X,Y
  1.  I $G(^UTILITY("INHSYS_FILERR",$J)) D
  1.  .S X=$$FLRPTERR^INHSYS11()
  1.  .S Y=$$RPTERR^INHSYS11()
  1.  I $G(X)!$G(Y) D SPRTCNTR()
  1.  K:$G(INKILL) ^UTILITY("INHSYS_SUMERR",$J),^UTILITY("INHSYS_FILERR",$J)
  1.  Q