Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: INHVCRL1

INHVCRL1.m

Go to the documentation of this file. 
  1. INHVCRL1 ;KAC ; 8 Jul 95 15:58; Logon Server (LoS) Background Controller (continued)
  1.  ;;3.01;BHL IHS Interfaces with GIS;;JUL 01, 2001
  1.  ;COPYRIGHT 1991-2000 SAIC
  1.  ;
  1.  Q
  1.  ;
  1. RESET(INBPN,INCHNL,INERR,INA,INIP,INUIF,INPARMS) ;
  1.  ; Logon attempt by remote system has failed.  Log the error, transmit 
  1.  ; negative acknowledgement to remote system (if requested), close LoS 
  1.  ; port.
  1.  ;
  1.  ; Input:
  1.  ;   INA      - (opt) array containing either:
  1.  ;                    1) INA = UNIVERSAL INTERFACE IEN for outbound Ack
  1.  ;                             (already processed by outbound script)
  1.  ;                    2) INA array subscripts, some or all of which have
  1.  ;                       been defined, comprising a msg ready to be 
  1.  ;                       processed by outbound script
  1.  ;                    3) INA = Ack code - AA = application accept
  1.  ;                                        AE = application error
  1.  ;                                        AR = application reject
  1.  ;                    4) If INA is passed, but does NOT meet conditions
  1.  ;                       in 1-3, default Ack code = AR
  1.  ;                    If INA is NOT passed, do NOT send Ack.
  1.  ;   INBPN    - (req) BACKGROUND PROCESS CONTROL IEN for LoS
  1.  ;   INCHNL   - (req) TCP channel assigned to this server when connection
  1.  ;                    is opened
  1.  ;   INDA     - array containing information to be sent to an outbound
  1.  ;              destination.  Not currently used.
  1.  ;                INDA = IEN in base file used by outbound script
  1.  ;                Subscripts may hold subfile IENs in the format:
  1.  ;                  INDA(subfile #,DA)=""
  1.  ;              If NOT needed, set to -1 prior to running outbound script.
  1.  ;   INERR    - (opt) array containing error msg used to log an error
  1.  ;   INIP     - (opt) array containing initialization parameters from
  1.  ;                    BACKGROUND PROCESS CONTROL file. Required to send Ack.
  1.  ;   INPARMS  - (opt) inbound msg parameter array
  1.  ;                    Format: INPARMS(INDSTP,"param")=value
  1.  ;   INUIF    - (opt) UNIVERSAL INTERFACE IEN for inbound msg
  1.  ;                    Required to "build" Ack.
  1.  ;
  1.  ; Variables:
  1.  ;   INERRACK - error information returned by function
  1.  ;   X        - scratch
  1.  ;
  1.  ; Output:
  1.  ;   None.
  1.  ;
  1.  N INERRACK,X
  1.  D:$D(INERR) LOG^INHVCRA1(.INERR,"E")
  1.  ;
  1.  ; Send Ack if requested
  1.  I $D(INA) D
  1.  . N INERR
  1.  .; Skip Ack creation if Ack was already built in UIF or in INA array
  1.  . I $S('$G(INA):1,'$D(^INTHU(INA)):1,1:0),$D(INA)<10 D
  1.  ..; Create Ack in INA array
  1.  .. S X=$G(INA) K INA
  1.  ..; Ck if user passed valid error Ack code
  1.  .. S INA("INSTAT")=$S(X="AE":X,1:"AR")
  1.  .. S INA("INACKTXT")="Invalid CHCS Logon Attempt"
  1.  .; Transmit negative Ack
  1.  . D LOG^INHVCRA1("Transmitting negative acknowledgement")
  1.  . S INERRACK=$$SNDAACK^INHVCRL2(INBPN,INCHNL,.INIP,.INA,.INDA,$G(INUIF),.INPARMS,1,.INERR)
  1.  . I INERRACK D LOG^INHVCRA1(.INERR,"E") Q  ; error sending Ack
  1.  . D LOG^INHVCRA1("Successful transmission")
  1.  ;
  1.  D LOG^INHVCRA1("Closing connection")
  1.  D CLOSE^INHVCRL(INBPN,INCHNL)
  1.  Q
  1.  ;