Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: LA7VIN5

LA7VIN5.m

Go to the documentation of this file. 
  1. LA7VIN5 ;VA/DALOI/JMC - Process Incoming UI Msgs, continued ; 13-Aug-2013 09:09 ; MKK
  1.  ;;5.2;AUTOMATED LAB INSTRUMENTS;**46,1018,64,1027,68,1033**;NOV 1, 1997
  1.  ;
  1.  ; This routine is a continuation of LA7VIN1 and is only called from there.
  1.  ; It is called to process OBX segments for "CH" subscript tests.
  1.  Q
  1.  ;
  1. OBX ;
  1.  ;
  1.  N LA76241,LA76304,LA7EII,LA7I,LA7LIMIT,LA7OBM,LA7SUBFL,LA7TEST,LA7TREEN,LA7UNITS,LA7VAL,LA7VTYP,LA7X,LA7XFORM,LA7Y
  1.  ;
  1.  K LA7RMK,^TMP("LA7TREE",$J)
  1.  ;
  1.  S LA7SUBFL=63.04
  1.  ;
  1.  ; OBX Set ID
  1.  S LA7SOBX=$$P^LA7VHLU(.LA7SEG,2,LA7FS)
  1.  ;
  1.  ; Value type - type of data from Table 0125
  1.  S LA7VTYP=$P($$P^LA7VHLU(.LA7SEG,3,LA7FS),LA7CS)
  1.  ;
  1.  ; Determine test result codes - check for primary and alternate codes
  1.  ; For DoD/CHCS interface - do NOT process test codes using 99LRT as coding system per DoD/July 2002.
  1.  S LA7X=$$P^LA7VHLU(.LA7SEG,4,LA7FS),(LA7RNLT,LA7RLNC)=""
  1.  S LA7TEST=$P(LA7X,LA7CS)
  1.  S LA7TEST(0)=$$UNESC^LA7VHLU3($P(LA7X,LA7CS,2),LA7FS_LA7ECH)
  1.  I LA7TEST(0)["^" S LA7TEST(0)=$TR(LA7TEST(0),"^","~")
  1.  S LA7TEST(0,1)=$P(LA7X,LA7CS,3)
  1.  S LA7TEST(2)=$P(LA7X,LA7CS,4)
  1.  S LA7TEST(2,0)=$$UNESC^LA7VHLU3($P(LA7X,LA7CS,5),LA7FS_LA7ECH)
  1.  I LA7TEST(2,0)["^" S LA7TEST(2,0)=$TR(LA7TEST(2,0),"^","~")
  1.  S LA7TEST(2,1)=$P(LA7X,LA7CS,6)
  1.  F I=3,6 D
  1.  . S LA7Y=$P(LA7X,LA7CS,I-2)
  1.  . I $P(LA7X,LA7CS,I)="LN" D  Q
  1.  . . I $$GET1^DIQ(95.3,+LA7Y_",",.01)=LA7Y S LA7RLNC=+LA7Y
  1.  . I $P(LA7X,LA7CS,I)="99VA64" D  Q
  1.  . . I $$FIND1^DIC(64,"","OMX",LA7Y) S LA7RNLT=LA7Y
  1.  . I $P(LA7X,LA7CS,I)="99LRT" D  Q
  1.  . . I LA7TEST(0)="",LA7TEST(2,0)'="" S LA7TEST(0)=LA7TEST(2,0)
  1.  . . I LA7TEST(2,0)="",LA7TEST(0)'="" S LA7TEST(2,0)=LA7TEST(0)
  1.  . . I I=3 S (LA7TEST,LA7TEST(0),LA7TEST(0,1))="" Q
  1.  . . I I=6 S (LA7TEST(2),LA7TEST(2,0),LA7TEST(2,1))="" Q
  1.  I LA7TEST="",LA7TEST(2)'="" D
  1.  . S LA7TEST=LA7TEST(2),LA7TEST(0)=LA7TEST(2,0),LA7TEST(0,1)=LA7TEST(2,1)
  1.  . S (LA7TEST(2),LA7TEST(2,0),LA7TEST(2,1))=""
  1.  ;
  1.  ; No test code in message
  1.  I LA7TEST="",LA7TEST(2)="" D  Q
  1.  . N LA7OBX
  1.  . S LA7OBX=LA7SEG(0)
  1.  . D CREATE^LA7LOG(15)
  1.  ;
  1.  ; Test code not found in auto inst file, also check alternate codes,
  1.  ; and log error if none found.
  1.  I LA7MTYP="ORU" D  Q:LA7TEST=""
  1.  . I LA7TEST'="",$D(^LAB(62.4,LA7624,3,"AC",LA7TEST)) Q
  1.  . I LA7TEST(2)'="",$D(^LAB(62.4,LA7624,3,"AC",LA7TEST(2))) D  Q
  1.  . . S LA7TEST=LA7TEST(2),LA7TEST(0)=LA7TEST(2,0),LA7TEST(0,1)=LA7TEST(2,1)
  1.  . D CREATE^LA7LOG(16) S LA7TEST=""
  1.  ;
  1.  ; Units - trim leading/trailing spaces
  1.  S LA7X=$$P^LA7VHLU(.LA7SEG,7,LA7FS),LA7UNITS=""
  1.  I LA7X'="" D
  1.  . F I=1:1:6 S LA7UNITS(I)=$P(LA7X,LA7CS,I)
  1.  . S LA7UNITS=$$TRIM^XLFSTR(LA7UNITS(1),"LR"," ")
  1.  . I LA7UNITS["^" D
  1.  . . N LA7STR S LA7STR("^")="~U~"
  1.  . . S LA7UNITS=$$REPLACE^XLFSTR(LA7UNITS,.LA7STR)
  1.  ;
  1.  ; Observation result status - Table 0085
  1.  S LA7ORS=$$P^LA7VHLU(.LA7SEG,12,LA7FS)
  1.  ;
  1.  ; Responsible observer
  1.  S LA7RO=$$XCNTFM^LA7VHLU4($$P^LA7VHLU(.LA7SEG,17,LA7FS),LA7ECH)
  1.  ;
  1.  ; Observation method
  1.  S LA7X=$$P^LA7VHLU(.LA7SEG,18,LA7FS),LA7OBM=""
  1.  I $P(LA7X,LA7CS,3)="99VA64_2" S LA7OBM=$P($P(LA7X,LA7CS,1),".",2)
  1.  ;
  1.  ; Equipment instance identifier
  1.  S LA7EII=$$P^LA7VHLU(.LA7SEG,19,LA7FS)
  1.  I LA7EII'="" D
  1.  . S LA7EII=$$UNESC^LA7VHLU3(LA7EII,LA7FS_LA7ECH)
  1.  . S LA7EII=$TR(LA7EII,"^",";")
  1.  ;
  1.  ; Process ORU message results for all tests which use this test code.
  1.  I LA7MTYP="ORU" D  Q
  1.  . S LA76241=0
  1.  . F  S LA76241=$O(^LAB(62.4,LA7624,3,"AC",LA7TEST,LA76241)) Q:'LA76241  D PROCESS
  1.  ;
  1.  I LA7MTYP="ORM",$G(LA7696)>0 D ORESULTS^LA7VIN5A
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. PROCESS ; Process results for a given test code
  1.  S LA7VAL=$$P^LA7VHLU(.LA7SEG,6,LA7FS)
  1.  I LA7VTYP="CE",$P(LA7VAL,LA7CS,2)'="" S LA7VAL=$P(LA7VAL,LA7CS,2)
  1.  E  S LA7VAL=$P(LA7VAL,LA7CS)
  1.  ;
  1.  F LA7I=0,1,2 S LA76241(LA7I)=$G(^LAB(62.4,LA7624,3,LA76241,LA7I))
  1.  ;
  1.  ; Chem test fields incorrect
  1.  I (LA76241(0)="")!(LA76241(1)="") D  Q
  1.  . D CREATE^LA7LOG(18)
  1.  ;
  1.  ; Setup LA7RMK(0) variable in case comments (NTE) sent with test results.
  1.  S LA7RMK(0,+LA76241(0))=+$P(LA76241(2),"^",7)_"^"_$P(LA76241(2),"^",8)
  1.  ;
  1.  S LA76304=+$P(LA76241(1),"(",2) ;lab data field
  1.  ; No dataname for this result
  1.  I LA76304'>1 D  Q
  1.  . D CREATE^LA7LOG(18)
  1.  ;
  1.  ; Set flag for new results alert
  1.  I LA7ORS'="","CDW"'[LA7ORS S ^TMP("LA7-ORU",$J,LA76248,LA76249)=""
  1.  ;
  1.  ; Set flag to send amended results bulletin
  1.  I LA7INTYP=10,LA7ORS'="","CDW"[LA7ORS D
  1.  . S LA7I=$O(^TMP("LA7 AMENDED RESULTS",$J,""),-1),LA7I=LA7I+1
  1.  . S X=LA7LWL_"^"_LA7ISQN_"^"_LA76304_"^"_LA76248_"^"_LA76249_"^"_LA7ORS_"^"_LA7TEST_"^"_$S(LA7TEST(0)'="":LA7TEST(0),1:LA7TEST(2,0))_"^"_$$P^LA7VHLU(.LA7SEG,9,LA7FS)
  1.  . S ^TMP("LA7 AMENDED RESULTS",$J,LA7I)=X
  1.  . I LA7UID'="" S ^LAH("LA7 AMENDED RESULTS",LA7UID,LA76304,LA7LWL,LA7ISQN)=X
  1.  ;
  1.  ; NOTE - this array can be set from inside PARAM 1
  1.  K LA7XFORM
  1.  ; execute PARAM 1 if not a LEDI interface
  1.  I LA7INTYP'=10 X $P(LA76241(0),"^",2)
  1.  I $P(LA76241(2),"^",3)=0 Q
  1.  I $P(LA76241(2),"^",3)=2,"CFUX"'[LA7ORS Q
  1.  I LA7ORS="X",LA7VAL="" Q
  1.  ;
  1.  ; No value found
  1.  I LA7VAL="" D  Q
  1.  . D CREATE^LA7LOG(17)
  1.  ;
  1.  ; Transform result based on fields in file 62.4
  1.  D XFORM^LA7VIN5A
  1.  Q:LA7VAL=""
  1.  ;
  1.  ; Check if result passes input transform on data name
  1.  D CHKDIE^LA7VIN5A
  1.  Q:LA7VAL=""
  1.  ;
  1.  ; Set flag to not store comments if it wasn't explicitly ordered.
  1.  I $G(LA7LIMIT)=1 D
  1.  . N LA76804
  1.  . K LA7LIMIT,LA7TREEN,^TMP("LA7TREE",$J)
  1.  . ; Store all tests accessioned in ^TMP
  1.  . S LA76804=0
  1.  . F  S LA76804=$O(^LRO(68,LA7AA,1,LA7AD,1,LA7AN,4,LA76804)) Q:'LA76804  D UNWIND^LA7UTIL(LA76804)
  1.  . I '$D(^TMP("LA7TREE",$J,+LA76241(0))) S LA7LIMIT=1 ;wasn't ordered
  1.  I $G(LA7LIMIT) D  Q
  1.  . S $P(LA7RMK(0,+LA76241(0)),"^",1)=0
  1.  . K LA7LIMIT,^TMP("LA7TREE",$J)
  1.  K ^TMP("LA7TREE",$J)
  1.  ;
  1.  ; Check point of care interface for matching specimen type  for this test in #62.4
  1.  I LA7INTYP>19,LA7INTYP<30 D  Q:'LA761
  1.  . N LA70070
  1.  . S LA761="",LA7X=$P(LA76241(2),"^",13) Q:'LA7X
  1.  . S LA70070=$$GET1^DIQ(61,LA7X_",","LEDI HL7:HL7 ABBR")
  1.  . I LA70070=LA7SPEC S LA761=LA7X
  1.  ;
  1.  ; Set data node=test value
  1.  S $P(^LAH(LA7LWL,1,LA7ISQN,LA76304),"^")=LA7VAL
  1.  ;
  1.  ; Store reference ranges except for UI (LA7INTYP=1) interfaces
  1.  I LA7INTYP'=1 D REFRNG^LA7VIN5A($$P^LA7VHLU(.LA7SEG,8,LA7FS))
  1.  ;
  1.  ; Store order/result codes/observation method except for UI (LA7INTYP=1) interfaces
  1.  S LA7X=$P(^LAH(LA7LWL,1,LA7ISQN,LA76304),"^",3)
  1.  I LA7ONLT S $P(LA7X,"!",1)=LA7ONLT
  1.  I LA7RNLT S $P(LA7X,"!",2)=LA7RNLT
  1.  I LA7RLNC S $P(LA7X,"!",3)=LA7RLNC
  1.  I LA7OBM S $P(LA7X,"!",4)=LA7OBM
  1.  I LA7INTYP'=1 S $P(^LAH(LA7LWL,1,LA7ISQN,LA76304),"^",3)=LA7X
  1.  ; 
  1.  ; Store abnormal flags except for UI (LA7INTYP=1) interfaces.
  1.  I LA7INTYP'=1 D ABFLAG^LA7VIN5A($$P^LA7VHLU(.LA7SEG,9,LA7FS))
  1.  ;
  1.  ; Store units except for UI (LA7INTYP=1) interfaces which pull values from file #60.
  1.  I LA7INTYP'=1,LA7UNITS'="" D
  1.  . S LA7X=$P($G(^LAH(LA7LWL,1,LA7ISQN,LA76304)),"^",5)
  1.  . S $P(LA7X,"!",7)=LA7UNITS
  1.  . S $P(^LAH(LA7LWL,1,LA7ISQN,LA76304),"^",5)=LA7X
  1.  ;
  1.  ; Store responsible observer on POC interfaces
  1.  I LA7RO'="",LA7INTYP>19,LA7INTYP<30 D
  1.  . I $P(LA7RO,"^",2) S $P(^LAH(LA7LWL,1,LA7ISQN,LA76304),"^",4)=$P(LA7RO,"^",2)
  1.  ;
  1.  ; Store specimen type except for UI (LA7INTYP=1) interfaces which pull values from the accession.
  1.  I LA7INTYP'=1,$G(LA761) D
  1.  . S X=$P(^LAH(LA7LWL,1,LA7ISQN,LA76304),"^",5)
  1.  . S $P(X,"!")=LA761
  1.  . S $P(^LAH(LA7LWL,1,LA7ISQN,LA76304),"^",5)=X
  1.  ;
  1.  ; Store where test was performed except for UI (LA7INTYP=1) interfaces.
  1.  I LA7INTYP'=1 D
  1.  . N LA74,LA7I,LA7X
  1.  . S LA7X=$$P^LA7VHLU(.LA7SEG,24,LA7FS),LA74=""
  1.  . I $P(LA7X,LA7CS,6)="CLIA" S LA74=$$IDX^XUAF4("CLIA",$P(LA7X,LA7CS,10))
  1.  . I LA74 S $P(^LAH(LA7LWL,1,LA7ISQN,LA76304),"^",9)=LA74 Q
  1.  . S LA7X=$$P^LA7VHLU(.LA7SEG,16,LA7FS)
  1.  . F LA7I=1,4 I $P(LA7X,LA7CS,LA7I+2)?1(1"L-CL",1"CLIA",1"99VACLIA") S LA74=$$IDX^XUAF4("CLIA",$P(LA7X,LA7CS,LA7I))
  1.  . I LA74 S $P(^LAH(LA7LWL,1,LA7ISQN,LA76304),"^",9)=LA74 Q
  1.  . D PRDID^LA7VIN5A($$P^LA7VHLU(.LA7SEG,16,LA7FS),LA7SFAC,LA7CS)
  1.  ;
  1.  ; Store equipment instance identifier
  1.  I LA7EII'="" D EII^LA7VIN5A
  1.  ;
  1.  ; If results for LEDI interface (LA7INTYP=10) and site keeps file #60
  1.  ; in sync with reference lab then compare message's units and normals
  1.  ; with site's to detect changes(LA7FLAG=1) and notify site.
  1.  I LA7INTYP=10,$G(LA761),$G(^LAB(60,+$P(LA76241(0),"^"),1,LA761,.1)) D
  1.  . N LA760,LA7FLAG,LA7I,LA7Y,LA7X
  1.  . S LA760=+$P(LA76241(0),"^"),LA7Y=^LAB(60,LA760,1,LA761,0),LA7FLAG=0
  1.  . S LA7X=$P(^LAH(LA7LWL,1,LA7ISQN,LA76304),"^",5)
  1.  . I $P(LA7Y,"^",7)'=$P(LA7X,"!",7) S LA7FLAG=1
  1.  . I 'LA7FLAG,$P(LA7Y,"^",2)=$P(LA7X,"!",2),$P(LA7Y,"^",3)=$P(LA7X,"!",3) Q
  1.  . I 'LA7FLAG D
  1.  . . N AGE,DOB,PNM,SEX
  1.  . . N LRDPF,LRNG,LRNGS,LRNG2,LRNG3,LRNG4,LRNG5,LRTREA,LRWRD,LRX,LRY
  1.  . . I $G(LRDFN) D DEM^LRX,KVAR^VADPT
  1.  . . S LRNG=LA7Y D NORM^LRVER5
  1.  . . S LA7Y=$TR(LRNG,$C(34),""),LA7X=$TR(LA7X,$C(34),"")
  1.  . . I $P(LA7Y,"^",2)=$P(LA7X,"!",2),$P(LA7Y,"^",3)=$P(LA7X,"!",3) Q
  1.  . . S LA7FLAG=1
  1.  . I 'LA7FLAG Q
  1.  . S LA7I=$O(^TMP("LA7 UNITS/NORMALS CHANGED",$J,""),-1),LA7I=LA7I+1
  1.  . S X=LA7LWL_"^"_LA7ISQN_"^"_LA76304_"^"_LA76248_"^"_LA76249_"^"_LA7ORS_"^"_LA7TEST_"^"_$S(LA7TEST(0)'="":LA7TEST(0),1:LA7TEST(2,0))_"^"_$$P^LA7VHLU(.LA7SEG,9,LA7FS)_"^"_LA760
  1.  . S ^TMP("LA7 UNITS/NORMALS CHANGED",$J,LA7I)=X
  1.  ;
  1.  ; If LEDI interface and order status change store which results
  1.  ; associated with ordered test. Used to determine if order status
  1.  ; changed bulletin needs to be generated.
  1.  I LA7INTYP=10,LA7SAC?1(1"A",1"G") D
  1.  . S LA7I=$G(LA7SAC(0)) Q:'LA7I
  1.  . S ^TMP("LA7 ORDER STATUS",$J,LA7I,+LA76241(0))=""
  1.  Q