Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: LA7VPID

LA7VPID.m

Go to the documentation of this file. 
  1. LA7VPID ;VA/DALOI/JMC - HL7 PID/PV1 segment builder utility ;JUL 06, 2010 3:14 PM
  1.  ;;5.2;AUTOMATED LAB INSTRUMENTS;**46,64,1027**;NOV 01, 1997;Build 9
  1.  ;
  1.  ; Reference to routine $$EN^VAFHLPID supported by DBIA# 263
  1.  ;
  1. PID(LRDFN,LA7EXTID,LA7ARRAY,LA7PIDSN,HL,LA7ALTID) ; Build PID segment
  1.  ; Call with     LRDFN = Lab DFN, passed by value
  1.  ;            LA7EXTID = to return as external patient id, id used by non-VA systems (optional)
  1.  ;            LA7ARRAY = array to return PID array, pass by reference
  1.  ;            LA7PIDSN = PID id counter, passsed by value
  1.  ;                  HL = HL7 variable array, pass by reference
  1.  ;            LA7ALTID = return alternate patient id, id used by non-va systems (optional)
  1.  ;
  1.  ; Returns LA7ARRAY
  1.  ;
  1.  N DFN,HLQ,LA763,LA7Y,LRDPF,VAFPID
  1.  ;
  1.  ; Change HLQ - VAFHLPID puts delete indicator when Vista has no value for field - not according to standard.
  1.  S HLQ=""
  1.  ;
  1.  I $G(LRDFN)=""!($G(HL("FS"))="") Q
  1.  I '$D(^LR(LRDFN,0)) Q
  1.  ;
  1.  S LA7EXTID=$G(LA7EXTID),LA7ALTID=$G(LA7ALTID),LA7PIDSN=$G(LA7PIDSN)+1
  1.  S LA763(0)=$G(^LR(LRDFN,0))
  1.  S LRDPF=$P(LA763(0),"^",2),DFN=$P(LA763(0),"^",3)
  1.  ;
  1.  ; REFERRAL file (#67) with PATIENT file (#2) link, use info from PATIENT file.
  1.  I LRDPF=67,$P($G(^LRT(67,DFN,"DPT")),"^") D
  1.   .S LRDPF=2
  1.  . S DFN=$P($G(^LRT(67,DFN,"DPT")),"^")
  1.  ;
  1.  ; Patient file - use VAF call
  1.  I LRDPF=2 D F2PID
  1.  ;
  1.  ; Non-patient file 
  1.  I LRDPF'=2 D NF2PID
  1.  K AGE,PNM,SEX,DOB,SSN,VA200,LRWRD,LRRB,LRTREA,VA
  1.  Q
  1.  ;
  1.  ;
  1. PV1(LRDFN,LA7ARRAY,LA7FS,LA7ECH) ; Build PV1 segment
  1.  ; Call with    LRDFN = ien of entry in File #63
  1.  ;           LA7ARRAY = array to return PV1 array, pass by reference
  1.  ;              LA7FS = HL field separator
  1.  ;             LA7ECH = HL encoding characters
  1.  ;
  1.  ;
  1.  N DFN,LA763,LA7LOC,LRDPF,LA7Y
  1.  S LA763(0)=$G(^LR(LRDFN,0))
  1.  S LRDPF=$P(LA763(0),"^",2),DFN=$P(LA763(0),"^",3),LA7LOC=""
  1.  ;
  1.  S LA7Y(0)="PV1"
  1.  S LA7Y(1)=1
  1.  ;
  1.  ; Referral file with Patient file link.
  1.  I LRDPF=67,$P($G(^LRT(67,DFN,"DPT")),"^") D
  1.  . S LRDPF=2
  1.  . S DFN=$P($G(^LRT(67,DFN,"DPT")),"^")
  1.  ;
  1.  ; Determine patient class
  1.  ; Current inpatient location
  1.  I LRDPF=2 S LA7LOC=$G(^DPT(DFN,.1))
  1.  I $L(LA7LOC) S LA7Y(2)="I" ; Inpatient
  1.  ;
  1.  ; Otherwise from lab files
  1.  I $G(LA7LOC)="" D
  1.  . S LA7LOC=$G(^LR(LRDFN,.1))
  1.  . S LA7Y(2)="O" ; Default to outpatient
  1.  ;
  1.  ; Patient location
  1.  S LA7LOC=$$CHKDATA^LA7VHLU3(LA7LOC,LA7FS_LA7ECH)
  1.  S LA7Y(3)=LA7LOC
  1.  ;
  1.  D BUILDSEG^LA7VHLU(.LA7Y,.LA7ARRAY,LA7FS)
  1.  Q
  1.  ;
  1.  ;
  1. F2PID ; Build patient identifier field on file #2 patient
  1.  ;
  1.  ;
  1.  N I,ICN,LA7X,X
  1.  S LA7ARRAY(0)=$$EN^VAFHLPID(DFN,"1,5,6,7,8,10NTB,11,13,16,19",LA7PIDSN)  ;ihs/cmi/maw 11/19/2010 added field 11 and 13
  1.  ;
  1.  ; Return external identifer in PID-2 sequence, backward compatibility to V2.2
  1.  I $L(LA7EXTID) D
  1.  . I '(LA7EXTID?1N.N) S $P(LA7ARRAY(0),HL("FS"),3)=LA7EXTID
  1.  . E  S $P(LA7ARRAY(0),HLFS,3)=$$M11^HLFNC(LA7EXTID,HL("ECH"))
  1.  ;
  1.  ; Send SSN as patient identifier
  1.  S X=$$M11^HLFNC($P(LA7ARRAY(0),HLFS,20),HL("ECH"))
  1.  S $P(X,$E(HL("ECH")),5)="SS"
  1.  S $P(LA7ARRAY(0),HLFS,4)=X
  1.  ;
  1.  ; Send DFN as patient identifier
  1.  S X=$$M11^HLFNC(DFN,HL("ECH"))
  1.  S $P(X,$E(HL("ECH")),5)="PI"
  1.  S $P(X,$E(HL("ECH")),6)=$$GET1^DIQ(4,+$P($G(^XMB(1,1,"XUS")),"^",17),99)_$E(HL("ECH"),4)_$G(^XMB("NETNAME"))_$E(HL("ECH"),4)_"DNS"
  1.  S $P(LA7ARRAY(0),HLFS,4)=$P(LA7ARRAY(0),HL("FS"),4)_$E(HL("ECH"),2)_X
  1.  ;
  1.  ; Send ICN from MPI as patient identifier
  1.  S ICN=$$ICN(DFN,HL("ECH"))
  1.  I ICN>0 S $P(LA7ARRAY(0),HLFS,4)=$P(LA7ARRAY(0),HL("FS"),4)_$E(HL("ECH"),2)_ICN
  1.  ;
  1.  ; Send alternate patient id if passed
  1.  I LA7ALTID'="" S $P(LA7ARRAY(0),HL("FS"),5)=LA7ALTID
  1.  I $P(LA7ARRAY(0),HLFS,5)?1N.N S $P(LA7ARRAY(0),HL("FS"),5)=$$M11^HLFNC($P(LA7ARRAY(0),HL("FS"),5),HL("ECH"))
  1.  ;
  1.  ;cmi/maw 3/9/2010 pass HRN only across the interface
  1.  S $P(LA7ARRAY(0),HLFS,3)=$$HRN^AUPNPAT(DFN,DUZ(2))
  1.  S $P(LA7ARRAY(0),HLFS,4)=$$HRN^AUPNPAT(DFN,DUZ(2))
  1.  S $P(LA7ARRAY(0),HLFS,11)=""
  1.  S $P(LA7ARRAY(0),HLFS,13)=""
  1.  ;cmi/maw 3/9/2010 end of mods
  1.  ;cmi/maw 4/14/2010 mods for client number
  1.  S $P(LA7ARRAY(0),HLFS,19)=$$ACCT^LA7VQINS(LA7ORD)  ;setup this function call
  1.  ;cmi/maw 4/14/2010 end of mods for client number
  1.  ;
  1.  ; Check for overflow (>245)
  1.  I $O(VAFPID(0)) D
  1.  . S I=0
  1.  . F  S I=$O(VAFPID(I)) Q:'I  S LA7ARRAY(I)=VAFPID(I)
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. NF2PID ; Build patient identifier field on non-file #2 patient
  1.  ;
  1.  D PT^LRX
  1.  S LA7Y(0)="PID"
  1.  S LA7Y(1)=LA7PIDSN
  1.  ;
  1.  ; Return external identifer in PID-2 sequence, backward compatibility to V2.2
  1.  I LA7EXTID'="" D
  1.  . I '(LA7EXTID?1N.N) S LA7Y(2)=LA7EXTID
  1.  . E  S LA7Y(2)=$$M11^HLFNC(LA7EXTID,HL("ECH"))
  1.  S LA7Y(3)=$$M11^HLFNC(SSN(2),HL("ECH"))
  1.  I LRDPF=67.1 S $P(LA7Y(3),$E(HL("ECH"),1),5)="L2"
  1.  ;
  1.  ; Send LRDFN as alternate patient ID, unless alternate id passed
  1.  I LA7ALTID'="" S LA7Y(4)=LA7ALTID
  1.  E  S LA7Y(4)=LRDFN
  1.  I LA7Y(4)?1N.N S LA7Y(4)=$$M11^HLFNC(LA7Y(4),HL("ECH"))
  1.  ;
  1.  S LA7Y(5)=$$HLNAME^HLFNC($G(PNM),HL("ECH"))
  1.  ;
  1.  I $G(DOB)'="" D
  1.  . S DOB=$$CHKDT^LA7VHLU1(DOB)
  1.  . S LA7Y(7)=$$FMTHL7^XLFDT(DOB)
  1.  ;
  1.  S LA7Y(8)=$S($G(SEX)'="":SEX,1:"U")
  1.  ;
  1.  ; Race - if from REFERRAL PATIENT file (#67) then check RACE field.
  1.  S LA7Y(10)=""
  1.  I LRDPF=67 D
  1.  . S LA7X=$$GET1^DIQ(67,DFN_",",.06,"I")
  1.  . I LA7X<1 Q
  1.  . S LA7Y(10)=$$PTR2CODE^DGUTL4(LA7X,1,2)
  1.  . S $P(LA7Y(10),$E(HL("ECH"),1),2)=$$PTR2TEXT^DGUTL4(LA7X,1)
  1.  . S $P(LA7Y(10),$E(HL("ECH"),1),3)="HL70005"
  1.  ;
  1.  ; SSN from referral file if 9N - DoD uses PID-19 to validate
  1.  S LA7Y(19)=""
  1.  I LRDPF=67 D
  1.  . S LA7X=$$GET1^DIQ(67,DFN_",",.09,"I")
  1.  . I LA7X?9N S LA7Y(19)=LA7X
  1.  ;
  1.  D BUILDSEG^LA7VHLU(.LA7Y,.LA7ARRAY,HL("FS"))
  1.  Q
  1.  ;
  1.  ;
  1. ICN(DFN,LA7ECH) ; Send ICN from MPI
  1.  ; Call with DFN = internal entry number of patient in PATIENT #2 file.
  1.  ;        LA7ECH = HL7 encoding characters.
  1.  ;
  1.  N ICN,LA7ICN
  1.  ;
  1.  S ICN=""
  1.  ;
  1.  S X="MPIF001" X ^%ZOSF("TEST")
  1.  I $T D
  1.  . S LA7ICN=$$GETICN^MPIF001(DFN)
  1.  . I LA7ICN<1 Q
  1.  . S ICN=LA7ICN
  1.  . S $P(ICN,$E(LA7ECH,1),4)="USVHA"_$E(LA7ECH,4)_$E(LA7ECH,4)_"HL70363"
  1.  . S $P(ICN,$E(LA7ECH,1),5)="NI"
  1.  . S $P(ICN,$E(LA7ECH,1),6)="VA FACILITY ID"_$E(LA7ECH,4)_$P($$SITE^VASITE,"^",3)_$E(LA7ECH,4)_"L"
  1.  ;
  1.  Q ICN