Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: LA7VQN5A

LA7VQN5A.m

Go to the documentation of this file. 
  1. LA7VQN5A ;VA/DALOI/JMC - Process Incoming UI Msgs, continued ; 11-Apr-2014 07:11 ; MAW
  1.  ;;5.2;AUTOMATED LAB INSTRUMENTS;**46,64,1027**;NOV 01, 1997;Build 9
  1.  ; This routine is a continuation of LA7VIN5.
  1.  ; It is performs processing of fields in OBX segments.
  1.  Q
  1.  ;
  1. XFORM ; Transform the result based on fields 12,13,14,16,17 in the Chem Test
  1.  ; multiple in the Auto Instrument file (62.4), or set on the fly
  1.  ; from PARAM 1
  1.  N LA7I
  1.  S LA7XFORM=LA76241(2)
  1.  ;
  1.  ; get PARAM 1 overides
  1.  I $D(LA7XFORM(1)),LA7XFORM(1)?1.N S $P(LA7XFORM,"^")=LA7XFORM(1)
  1.  F LA7I=2,3,5,6 I $D(LA7XFORM(LA7I)) S $P(LA7XFORM,"^",LA7I)=LA7XFORM(LA7I)
  1.  ; set up defaults if field was not answered
  1.  ; accept results,yes
  1.  I $P(LA7XFORM,"^",3)="" S $P(LA7XFORM,"^",3)=1
  1.  ; strip spaces,no
  1.  I $P(LA7XFORM,"^",6)="" S $P(LA7XFORM,"^",6)=0
  1.  ; now transform
  1.  ;
  1.  ; Don't accept results
  1.  I '$P(LA7XFORM,"^",3) S LA7VAL="" Q
  1.  ;
  1.  ; Only accept "FINAL" type results
  1.  I $P(LA7XFORM,"^",3)=2,"CFU"'[LA7ORS S LA7VAL="" Q
  1.  ;
  1.  ; Accept ordered tests only
  1.  ; If LEDI interface (10) and message indicates a reflex ("G") or add-on
  1.  ; test ("A") then process anyway in case it has not been added to
  1.  ; accession.
  1.  I $P(LA7XFORM,"^",5) D
  1.  . I LA7INTYP=10,LA7SAC?1(1"A",1"G") Q
  1.  . S LA7LIMIT=1
  1.  ;
  1.  ; Decimal places if number of places defined
  1.  I $P(LA7XFORM,"^")?1.N D JUSTDEC
  1.  ;
  1.  ; Strip spaces
  1.  I $P(LA7XFORM,"^",6) S LA7VAL=$TR(LA7VAL," ","")
  1.  ;
  1.  ; Make result a comment
  1.  ; Set value to null after making into remark, don't store twice.
  1.  I $P(LA7XFORM,"^",2) D
  1.  . N LA7Y
  1.  . ; Store comment in ^LAH global
  1.  . S LA7Y=$P(LA7RMK(0,+LA76241(0)),"^",2)
  1.  . D RMKSET^LASET(LA7LWL,LA7ISQN,LA7VAL,LA7Y)
  1.  . S LA7VAL=""
  1.  Q
  1.  ;
  1.  ;
  1. CHKDIE ; Check if value to be stored passes input transform of field in DD
  1.  N LA7ERR,LA7Y
  1.  ;
  1.  ; If result is on a LEDI interface (type=10) then don't check result
  1.  ; against FileMan input tranform.
  1.  ; VistA sends "canc" as test result when test is cancelled.
  1.  ; DoD sends "PL Canceled" --> change to "canc" for VistA storage.
  1.  I LA7INTYP=10 D  Q
  1.  . I LA7VAL="PL Cancelled" S LA7VAL="canc"
  1.  . I LA7VAL="PL Canceled" S LA7VAL="canc"
  1.  . I LA7VAL="PLCanceled" S LA7VAL="canc"
  1.  ;
  1.  ; If value fails data checker then log error and suppress result.
  1.  D CHK^DIE(LA7SUBFL,LA76304,"H",LA7VAL,.LA7Y,"LA7ERR")
  1.  I LA7Y="^" D
  1.  . N LA7X
  1.  . S LA7X=$G(LA7ERR("DIERR",1,"TEXT",1))
  1.  . D CREATE^LA7LOG(37)
  1.  . S LA7VAL=""
  1.  Q
  1.  ;
  1.  ;
  1. JUSTDEC ; Justify to number of places specified
  1.  ;
  1.  N LA7DDTYP,LA7FMT,LA7I,LA7PRFIX,LA7X
  1.  ;
  1.  ; If LEDI interface (type=10) then skip decimal adjustment
  1.  I LA7INTYP=10 Q
  1.  ;
  1.  ; Get data name field type from DD
  1.  ; Only justify if Vista field is numeric or free text.
  1.  S LA7DDTYP=$$GET1^DID(LA7SUBFL,LA76304,"","TYPE")
  1.  I "NUMERIC^FREE TEXT"'[LA7DDTYP D  Q
  1.  . N LA7FLDNM
  1.  . S LA7FLDNM=$$GET1^DID(63.04,LA76304,"","LABEL")
  1.  . D CREATE^LA7LOG(38)
  1.  ;
  1.  S LA7X=LA7VAL,(LA7FMT,LA7PRFIX)=""
  1.  ;
  1.  ; If comma formatted, strip comma and set flag to add back in.
  1.  S LA7X=$TR(LA7X,",","")
  1.  I LA7X'=LA7VAL S LA7FMT="P"
  1.  ;
  1.  ; If "<>=" formatted, strip and save to add back in.
  1.  F LA7I=1:1:$L(LA7X) Q:$E(LA7X,LA7I)'?1(1"<",1">",1"=")
  1.  I LA7I>1 D
  1.  . S LA7PRFIX=$E(LA7X,1,LA7I-1)
  1.  . S LA7X=$E(LA7X,LA7I,$L(LA7X))
  1.  ;
  1.  ; Format if starts with number or decimal point, skip other results.
  1.  I LA7X?1(1.N,.N1"."1.N) D
  1.  . S LA7X=$FN(LA7X,LA7FMT,+LA7XFORM)
  1.  . S LA7VAL=LA7PRFIX_LA7X
  1.  Q
  1.  ;
  1.  ;
  1. PRDID(LA7PRDID,LA7SFAC,LA7CS) ; Process/Store Producer's ID
  1.  ; Store where test was performed.
  1.  ; Call with LA7PRDID = Producer's ID field
  1.  ;            LA7SFAC = sending facility
  1.  ;              LA7CS = component encoding character
  1.  ;
  1.  N LA74,LA7X,LA7Y
  1.  ;
  1.  S LA7X=$P(LA7PRDID,LA7CS,2),LA74=""
  1.  ;
  1.  I $P(LA7PRDID,LA7CS,3)="99VA4" S LA74=$$FIND1^DIC(4,"","OMX",$P(LA7PRDID,LA7CS))
  1.  I 'LA74 S LA74=$$FINDSITE^LA7VHLU2($P(LA7PRDID,LA7CS),1,1)
  1.  I 'LA74 S LA74=$$FINDSITE^LA7VHLU2($P(LA7SFAC,LA7CS),1,1)
  1.  ;
  1.  ; Store producer's id in LAH global with results.
  1.  I LA74 S $P(^LAH(LA7LWL,1,LA7ISQN,LA76304),"^",9)=LA74
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. REFRNG(LA7X) ; Process/Store References Range.
  1.  ; Call with LA7X = reference range to store.
  1.  ;
  1.  N LA7Y,X,Y
  1.  ;
  1.  ; Remove leading and trailing quotes from reference range.
  1.  S LA7X=$$TRIM^XLFSTR($G(LA7X),"RL","""")
  1.  I LA7X="" Q
  1.  ;
  1.  S X=$P($G(^LAH(LA7LWL,1,LA7ISQN,LA76304)),"^",5)
  1.  ;
  1.  ; >lower limit (no upper limit e.g. >10) - store as low value
  1.  I LA7X?1">".N.1".".N S $P(X,"!",2)=$TR(LA7X,">",""),LA7X=""
  1.  ;
  1.  ; <upper limit (no lower limit e.g. <15) - store as high value
  1.  I LA7X?1"<".N.1".".N S $P(X,"!",3)=$TR(LA7X,"<",""),LA7X=""
  1.  ;
  1.  ; Alphabetic reference with hyphen
  1.  I LA7X?1.A1"-"1.A S $P(X,"!",2)=$C(34)_LA7X_$C(34),LA7X=""
  1.  ;
  1.  ; Lower limit value
  1.  S Y=$P(LA7X,"-")
  1.  I Y'="" D
  1.  . I Y?.N.1".".N S $P(X,"!",2)=Y
  1.  . E  S $P(X,"!",2)=$C(34)_$$UNESC^LA7VHLU3(Y,LA7FS_LA7ECH)_$C(34)
  1.  ;
  1.  ; Upper limit value
  1.  S Y=$P(LA7X,"-",2)
  1.  I Y'="" D
  1.  . I Y?.N.1".".N S $P(X,"!",3)=Y
  1.  . E  S $P(X,"!",3)=$C(34)_$$UNESC^LA7VHLU3(Y,LA7FS_LA7ECH)_$C(34)
  1.  ;
  1.  ; Store reference range in LAH global with results.
  1.  S $P(^LAH(LA7LWL,1,LA7ISQN,LA76304),"^",5)=X
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. ABFLAG(LA7X) ; Process/Store Abnormal Flags.
  1.  ; Call with LA7X = abnormal flags to store.
  1.  ; Converts flag to interpretation based on HL7 Table 0078.
  1.  ; If no match store code instead of interpretation
  1.  ;
  1.  N LA7I,LA7Y,X
  1.  ;
  1.  ; Store abnormal flags in LAH global with results.
  1.  ; Currently only storing high/low and critical flags
  1.  ;S LA7Y=$S(LA7X="L":"L",LA7X="H":"H",LA7X="LL":"L*",LA7X="HH":"H*",1:"")  ;cmi/maw 5/21/2010 store anything that comes in for reference lab
  1.  S LA7Y=$S(LA7X="L":"L",LA7X="H":"H",LA7X="LL":"L*",LA7X="HH":"H*",LA7X="A":"A",1:"")  ;cmi/maw 04/12/2011 store A from Reference lab
  1.  ;S LA7Y=$G(LA7X)  ;cmi/maw 5/21/2010 file as is CHANGED BACK ON 8/9/2010
  1.  S $P(^LAH(LA7LWL,1,LA7ISQN,LA76304),"^",2)=LA7Y
  1.  ;
  1.  ; Critical or designated abnormal tests generate bulletin/alert
  1.  ; on LEDI (type=10) interfaces.
  1.  I LA7INTYP=10,LA7Y'="" D
  1.  . I $E(LA7Y,2)'="*",'$P(LA76241(2),"^",11) Q
  1.  . S LA7I=$O(^TMP("LA7 ABNORMAL RESULTS",$J,""),-1),LA7I=LA7I+1
  1.  . S X=LA7LWL_"^"_LA7ISQN_"^"_LA76304_"^"_LA76248_"^"_LA76249_"^"_LA7ORS_"^"_LA7TEST_"^"_$S(LA7TEST(0)'="":LA7TEST(0),1:LA7TEST(2,0))_"^"_$$P^LA7VHLU(.LA7SEG,9,LA7FS)
  1.  . S ^TMP("LA7 ABNORMAL RESULTS",$J,LA7I)=X
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. EII ; Store equipment instance identifier in LAH global with results.
  1.  ;
  1.  N I,LA7X,X
  1.  ;
  1.  S LA7X=""
  1.  F I=1:1:4 D
  1.  . S X=$P(LA7EII,LA7CS,I)
  1.  . I X="" Q
  1.  . S $P(LA7X,"!",I)=$TR(X,"!","~")
  1.  I LA7X]"" S $P(^LAH(LA7LWL,1,LA7ISQN,LA76304),"^",11)=LA7X
  1.  Q
  1.  ;
  1.  ;
  1. ORESULTS ; Process results that accompany order (ORM) messages
  1.  ;
  1.  N I,LA764,LA7DIE,LA7ERR,LA7I,LA7WP,LA7X,LA7Y,X
  1.  S LA7WP(1,0)=" ",LA7I=2,X=""
  1.  I LA7RLNC S X="[LOINC "_$$GET1^DIQ(95.3,LA7RLNC_",",.01)_"] "_$$GET1^DIQ(95.3,LA7RLNC_",",80)
  1.  I 'LA7RLNC,LA7RNLT D
  1.  . S LA764=$$FIND1^DIC(64,"","X",LA7RNLT,"E","","LA7ERR")
  1.  . I 'LA764 S LA7RNLT="" Q
  1.  . S X="[NLT "_$$GET1^DIQ(64,LA764_",",1)_"] "_$$GET1^DIQ(64,LA764_",",.01,"I")
  1.  I 'LA7RLNC,'LA7RNLT D
  1.  . I LA7TEST(0)]""!(LA7TEST]"") S X="["_LA7TEST(0,1)_" "_LA7TEST_"] "_LA7TEST(0) Q
  1.  . S X="["_LA7TEST(2,1)_" "_LA7TEST(2)_"] "_LA7TEST(2,0)
  1.  S LA7WP(LA7I,0)="Test result: "_X
  1.  ; Date value
  1.  I LA7VTYP="DT" D
  1.  . S LA7X=$$P^LA7VHLU(.LA7SEG,6,LA7FS)
  1.  . S LA7X=$$HL7TFM^XLFDT(LA7X,"L")
  1.  . S LA7I=LA7I+1,LA7WP(LA7I,0)=" Test value: "_LA7X
  1.  ; Coded entry
  1.  I "CECM"[LA7VTYP D
  1.  . S LA7X=$P($$P^LA7VHLU(.LA7SEG,6,LA7FS),LA7CS,2)
  1.  . S LA7X=$$UNESC^LA7VHLU3(LA7X,LA7FS_LA7ECH)
  1.  . S LA7I=LA7I+1,LA7WP(LA7I,0)=" Test value: "_LA7X_$S(LA7UNITS]"":" "_LA7UNITS,1:"")
  1.  ; Numeric/ Structured Numeric value
  1.  I "NMSN"[LA7VTYP D
  1.  . S LA7X=$$P^LA7VHLU(.LA7SEG,6,LA7FS)
  1.  . S LA7X=$$UNESC^LA7VHLU3(LA7X,LA7FS_LA7ECH)
  1.  . S LA7I=LA7I+1,LA7WP(LA7I,0)=" Test value: "_LA7X_$S(LA7UNITS]"":" "_LA7UNITS,1:"")
  1.  ; String Data/ Formatted Text/ Text Data
  1.  I "FTSTX"[LA7VTYP D
  1.  . D PA^LA7VHLU(.LA7SEG,6,LA7FS,.LA7X)
  1.  . D UNESCFT^LA7VHLU3(.LA7X,LA7FS_LA7ECH,.LA7Y)
  1.  . I LA7Y=1,(($L(LA7Y(1,0))+$L(LA7UNITS))<225) S LA7I=LA7I+1,LA7WP(LA7I,0)=" Test value: "_LA7Y(1,0)_$S(LA7UNITS]"":" "_LA7UNITS,1:"") Q
  1.  . S LA7I=LA7I+1,LA7WP(LA7I,0)=" Test value:"
  1.  . F I=1:1:LA7Y S LA7I=LA7I+1,LA7WP(LA7I,0)=LA7Y(I,0)
  1.  . I LA7UNITS]"" S LA7I=LA7I+1,LA7WP(LA7I,0)=" Test units: "_LA7UNITS
  1.  ; Normals/ Reference range
  1.  S LA7X=$$P^LA7VHLU(.LA7SEG,8,LA7FS)
  1.  I LA7X]"" S LA7I=LA7I+1,LA7WP(LA7I,0)=" Test normals: "_LA7X
  1.  ; Normalcy status
  1.  S LA7X=$$P^LA7VHLU(.LA7SEG,9,LA7FS)
  1.  I LA7X]"" D
  1.  . S X=" L^ H^LL^HH^ <^ >^ N^ A^AA^ U^ D^ B^ W^ S^ R^ I^MS^VS"
  1.  . S I=$F(X,LA7X)\3,LA7X=$P($T(ABFLAGS+I^LA7VHLU1),";;",2)
  1.  . I LA7X]"" S LA7I=LA7I+1,LA7WP(LA7I,0)=" Test normalcy status: "_LA7X
  1.  I $D(LA7WP) D WP^DIE(69.6,LA7696_",",99,"A","LA7WP","LA7DIE(99)")
  1.  Q