Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: LA7VSTP

LA7VSTP.m

Go to the documentation of this file. 
  1. LA7VSTP ;VA/DALOI/JMC - HL7 environment setup routine ;JUL 06, 2010 3:14 PM
  1.  ;;5.2;AUTOMATED LAB INSTRUMENTS;**27,44,51,46,64,1027**;NOV 01, 1997
  1.  ; This routine will create LEDI and UNIVERSAL INTERFACE HL7 v1.6 file setups.
  1.  ;
  1.  ; Reference to PROTOCOL file (#101) supported by DBIA #872
  1.  ;
  1. HOST(PRIMARY,PRSITE,LRI,SITE,LA7VER) ;
  1.  ;
  1.  N LA7Y,LAREMOTE,LAHOST,LASERV,LACLNT,LRS,PROT,ORU
  1.  ;
  1.  I $G(LRI)="" D EXIT Q
  1.  ;
  1.  W !,"Setting up the following Host Labs for "_PRSITE
  1.  W !,"  Updating HL7 APPLICATION PARAMETER file (#771)."
  1.  ;
  1.  S LA7VER=$S($G(LA7VER)]"":LA7VER,1:2.3)
  1.  S LAREMOTE="LA7V REMOTE "_PRIMARY
  1.  S $P(LAREMOTE,"^",2)=$$SETAPP(LAREMOTE,PRIMARY)
  1.  ;
  1.  S LAHOST="LA7V HOST "_LRI
  1.  S $P(LAHOST,"^",2)=$$SETAPP(LAHOST,LRI)
  1.  ;
  1.  W !,"  Updating PROTOCOL file (#101)."
  1.  ;
  1.  ; Setup protocols to receive and process result (ORU) messages.
  1.  ; Create event & subscriber protocols.
  1.  K LASERV
  1.  S LASERV="LA7V Receive Results from "_LRI
  1.  S LASERV(4)="E"
  1.  S LASERV(770.1)=$P(LAHOST,"^")
  1.  S LASERV(770.3)="ORU"
  1.  S LASERV(770.4)="R01"
  1.  S LASERV(770.95)=LA7VER
  1.  D SETPRO(.LASERV)
  1.  ;
  1.  K LACLNT
  1.  S LACLNT="LA7V Process Results from "_LRI
  1.  S LACLNT(4)="S"
  1.  S LACLNT(770.2)=$P(LAREMOTE,"^")
  1.  S LACLNT(770.3)="@"
  1.  S LACLNT(770.4)="R01"
  1.  S LACLNT(770.11)="ACK"
  1.  S LACLNT(770.95)=LA7VER
  1.  S LACLNT(771)="D ORU^LA7VHL"
  1.  F I=773.1,773.2,773.4 S LACLNT(I)=1
  1.  D SETPRO(.LACLNT)
  1.  ;
  1.  ; Add subscriber to event.
  1.  D ADDSUB(LASERV,LACLNT)
  1.  ;
  1.  ; Setup protocols to build and send order (ORM) messages.
  1.  ; Create event & subscriber protocols.
  1.  K LASERV
  1.  S LASERV="LA7V Order to "_LRI
  1.  S LASERV(4)="E"
  1.  S LASERV(770.1)=$P(LAREMOTE,"^")
  1.  S LASERV(770.3)="ORM"
  1.  S LASERV(770.4)="O01"
  1.  F I=770.2,770.11 S LASERV(I)="@"
  1.  F I=770.8,770.9 S LASERV(I)="AL"
  1.  S LASERV(770.95)=LA7VER
  1.  S LASERV(772)="D ORR^LA7VHL"
  1.  D SETPRO(.LASERV)
  1.  ;
  1.  K LACLNT
  1.  S LACLNT="LA7V Send Order to "_LRI
  1.  S LACLNT(4)="S"
  1.  S LACLNT(770.2)=$P(LAHOST,"^")
  1.  S LACLNT(770.4)="O02"
  1.  S LACLNT(770.11)="ORR"
  1.  S LACLNT(770.95)=LA7VER
  1.  F I=770.1,770.3 S LACLNT(I)="@"
  1.  F I=773.1,773.2,773.4 S LACLNT(I)=1
  1.  D SETPRO(.LACLNT)
  1.  ;
  1.  ; Add subscriber to event.
  1.  D ADDSUB(LASERV,LACLNT)
  1.  ;
  1.  D HOST^LA7VSTP1
  1.  D EXIT
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. REMOTE(PRIMARY,PRSITE,LRI,SITE,LA7VER) ;
  1.  N LA7Y,LAREMOTE,LAHOST,LASERV,LACLNT,LRS,PROT,ORU
  1.  ;
  1.  I $G(LRI)="" D EXIT Q
  1.  ;
  1.  W !,"Setting up the REMOTE Lab, "_SITE_" and HOST Lab "_PRSITE
  1.  W !,"   Updating HL7 APPLICATION PARAMETER file (#771)."
  1.  ;
  1.  S LA7VER=$S($G(LA7VER)]"":LA7VER,1:2.3)
  1.  S LAHOST="LA7V HOST "_PRIMARY
  1.  S $P(LAHOST,"^",2)=$$SETAPP(LAHOST,PRIMARY)
  1.  ;
  1.  S LAREMOTE="LA7V REMOTE "_LRI
  1.  S $P(LAREMOTE,"^",2)=$$SETAPP(LAREMOTE,LRI)
  1.  ;
  1.  W !,"  Updating PROTOCOL file (#101)."
  1.  ;
  1.  ; Setup protocols to build and send results (ORU) message back.
  1.  ; Create event & subscriber protocols.
  1.  K LASERV
  1.  S LASERV="LA7V Results Reporting to "_LRI
  1.  S LASERV(4)="E"
  1.  S LASERV(770.1)=$P(LAHOST,"^")
  1.  S LASERV(770.3)="ORU"
  1.  S LASERV(770.4)="R01"
  1.  S LASERV(770.95)=LA7VER
  1.  F I=770.8,770.9 S LASERV(I)="AL"
  1.  S LASERV(772)="D ACK^LA7VHL"
  1.  D SETPRO(.LASERV)
  1.  ;
  1.  K LACLNT
  1.  S LACLNT="LA7V Send Results to "_LRI
  1.  S LACLNT(4)="S"
  1.  S LACLNT(770.2)=$P(LAREMOTE,"^")
  1.  S LACLNT(770.3)="@"
  1.  S LACLNT(770.4)="R01"
  1.  S LACLNT(770.11)="ACK"
  1.  S LACLNT(770.95)=LA7VER
  1.  F I=773.1,773.2,773.4 S LACLNT(I)=1
  1.  D SETPRO(.LACLNT)
  1.  ;
  1.  ; Add subscriber to event.
  1.  D ADDSUB(LASERV,LACLNT)
  1.  ;
  1.  ; Setup protocols to receive and process order (ORM) messages.
  1.  ; Create event & subscriber protocols.
  1.  K LASERV
  1.  S LASERV="LA7V Receive Order from "_LRI
  1.  S LASERV(4)="E"
  1.  S LASERV(770.1)=$P(LAREMOTE,"^")
  1.  S LASERV(770.3)="ORM"
  1.  S LASERV(770.4)="O01"
  1.  S LASERV(770.95)=LA7VER
  1.  F I=770.2,770.11 S LASERV(I)="@"
  1.  D SETPRO(.LASERV)
  1.  ;
  1.  K LACLNT
  1.  S LACLNT="LA7V Process Order from "_LRI
  1.  S LACLNT(4)="S"
  1.  S LACLNT(770.2)=$P(LAHOST,"^")
  1.  S LACLNT(770.4)="O02"
  1.  S LACLNT(770.11)="ORR"
  1.  F I=770.1,770.3 S LACLNT(I)="@"
  1.  F I=773.1,773.2,773.4 S LACLNT(I)=1
  1.  S LACLNT(770.95)=LA7VER
  1.  S LACLNT(771)="D IN^LA7VORM"
  1.  D SETPRO(.LACLNT)
  1.  ;
  1.  ; Add subscriber to event.
  1.  D ADDSUB(LASERV,LACLNT)
  1.  ;
  1.  D REMOTE^LA7VSTP1
  1.  D EXIT
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. EXIT ; Exit with message
  1.  W !!,"HL7 v1.6 Environment setup is complete!!"
  1.  S LASERV(770.95)=LA7VER
  1.  K DIR
  1.  S DIR(0)="E" D ^DIR
  1.  Q
  1.  ;
  1.  ;
  1. SETAPP(LA7X,LA7FAC) ;sets up the HL7 APPLICATION PARAMETER file #771
  1.  ;
  1.  ; Call with LA7X = value of .01 field to add to file #771
  1.  ;           LA7FAC = facility name
  1.  ;
  1.  N DIC,DIE,DLAYGO,DR,LA7Y
  1.  ;
  1.  S X=LA7X
  1.  S DIC="^HL(771,",DLAYGO=771,DIC(0)="L"
  1.  D ^DIC
  1.  S LA7Y=Y
  1.  W:$P(LA7Y,"^",3) !,"     Adding "_LA7X
  1.  I +LA7Y<1 Q
  1.  ;
  1.  S DA=+LA7Y,DIE="^HL(771,",DR="2////a;3////"_LA7FAC
  1.  D ^DIE
  1.  Q $P(LA7Y,"^")
  1.  ;
  1.  ;
  1. SETPRO(FIELDS) ;sets up the PROTOCOL file #101
  1.  ; Call with   LA7X = Protocol name
  1.  ;           FIELDS = FileMan fields array
  1.  ;
  1.  N DA,DIC,FDA,I,LA7DIE,LA7IENS
  1.  ;
  1.  S X=FIELDS,DIC="^ORD(101,",DIC(0)="L",DLAYGO=101
  1.  D ^DIC
  1.  I '$G(LA7QUIET) W !,FIELDS W:$P(Y,U,3) !,"     Adding "_X
  1.  S DA=+Y
  1.  I DA<0 Q
  1.  ;
  1.  S I=0,LA7IENS=DA_","
  1.  F  S I=$O(FIELDS(I)) Q:'I  S FDA(1,101,LA7IENS,I)=FIELDS(I)
  1.  S FDA(1,101,LA7IENS,770.6)="@"
  1.  D FILE^DIE("E","FDA(1)","LA7DIE(1)")
  1.  S FDA(2,101,LA7IENS,5)=DUZ
  1.  D FILE^DIE("","FDA(2)","LA7DIE(2)")
  1.  D CLEAN^DILF
  1.  Q
  1.  ;
  1.  ;
  1. ADDSUB(LA7EVNT,LA7SUB) ; Add subscriber to event protocol
  1.  ; Call with LA7EVNT = name of event protocol
  1.  ;            LA7SUB = name of subscriber protocol
  1.  ;
  1.  N DIC,DA,DR,D0,DLAYGO,LA7101E,LA7101S,X,Y
  1.  ;
  1.  I '$D(^ORD(101,"B",LA7SUB)) Q
  1.  I '$D(^ORD(101,"B",LA7EVNT)) Q
  1.  ;
  1.  ; Get ien for event and subscriber protocols
  1.  S LA7101E=$O(^ORD(101,"B",LA7EVNT,0))
  1.  S LA7101S=$O(^ORD(101,"B",LA7SUB,0))
  1.  ;
  1.  ; Already listed as a subscriber to this event
  1.  I $D(^ORD(101,LA7101E,775,"B",LA7101S)) Q
  1.  ;
  1.  S X=LA7SUB,DA(1)=LA7101E,DIC="^ORD(101,"_DA(1)_",775,"
  1.  S DLAYGO=101.01,DIC(0)="QEL",DIC("P")=$P(^DD(101,775,0),U,2)
  1.  D ^DIC
  1.  ;
  1.  Q