Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: LADOWN

LADOWN.m

Go to the documentation of this file. 
  1. LADOWN ;DALOI/RWF - TOP LEVEL OF DOWNLOAD OPTIONS ;7/20/90  08:06
  1.  ;;5.2;AUTOMATED LAB INSTRUMENTS;**17,57**;Sep 27, 1994
  1.  ;
  1. BUILD ;Build a download file for an Instrument
  1.  N DIR,LAQUIT,LAX,LRCUP1,LRCUP2,LRNEW,LRPROF,LRTRAY1,LRTYPE,TSK
  1.  ;
  1.  S LAQUIT=0
  1.  ;
  1.  D INIT
  1.  I LAQUIT D QUIT Q
  1.  ;
  1. BU2 ;
  1.  W !
  1.  S DIR(0)="YO"
  1.  S DIR("?")="If optional for this instrument, should I send the tray,cup locations."
  1.  S DIR("A")="Send TRAY/CUP locations"
  1.  S DIR("B")=$S($P(LRAUTO(9),"^",5)="N":"NO",1:"YES")
  1.  D ^DIR
  1.  I $D(DIRUT) D QUIT Q
  1.  S LRFORCE=Y
  1.  ;
  1.  K DIR("?")
  1.  S DIR("B")=$S($P(LRAUTO(9),"^",6)="N":"NO",1:"YES")
  1.  S DIR("A")="Queue work"
  1.  D ^DIR
  1.  I $D(DIRUT) D QUIT Q
  1.  ;
  1.  W !
  1.  I Y=1 D  Q
  1.  . N ZTDESC,ZTRTN,ZTIO,ZTSAVE
  1.  . S ZTRTN="DQB^LADOWN",ZTIO="",ZTSAVE("LR*")=""
  1.  . S ZTDESC="AUTO-INSTRUMENT DOWNLOAD "
  1.  . D ^%ZTLOAD
  1.  . D QUIT
  1.  ;
  1. DQB ;
  1.  S:$D(ZTQUEUED) ZTREQ="@"
  1.  ; Now ready to build file.
  1.  D BUILD^LADOWN1
  1.  ;
  1.  ; Routine from auto instrument file.
  1.  S LRTRAY=LRTRAY1 D @$P(LRAUTO(9),U,3,4)
  1.  ;
  1.  ; Go send the records
  1.  G SE2:$G(LREND)<1,LAST
  1.  ;
  1. QUIT ; Clean up
  1.  K ^TMP($J)
  1.  K LRLL,LRINST,LRAUTO,LRFILE,LRI,LRTRAY,LRCUP,LRAA,LRAD,LRAN,LRTEST,LRECORD,LRFLUID,LRFORCE,LRL,LRPNM
  1.  K F,I,J,X,X5,LRRTN
  1.  Q
  1.  ;
  1. INIT ;
  1.  N %,DIC,DIR,DIRUT,DTOUT,DUOUT,ZTSK,LREND
  1.  ;
  1.  S LAQUIT=0
  1.  ;
  1.  S DIC="^LAB(62.4,",DIC(0)="AMEQZ"
  1.  D ^DIC
  1.  I Y<1 S LAQUIT=1 Q
  1.  ;
  1.  S LRINST=+Y,LRAUTO=Y(0),LRAUTO(9)=$G(^LAB(62.4,LRINST,9))
  1.  I LRAUTO(9)="" D  Q
  1.  . S LAQUIT=1
  1.  . W !,"Sorry I don't know how to build for this Instrument"
  1.  ;
  1.  K DIC
  1.  S DIC="^LRO(68.2,",DIC(0)="AEMQZ"
  1.  S DIC("A")="Build using Load List: "
  1.  S DIC("B")=$P($G(^LRO(68.2,+$P(LRAUTO,"^",4),0)),"^",1)
  1.  D ^DIC
  1.  I Y<1 S LAQUIT=1 Q
  1.  ;
  1.  S LRLL=+Y,$P(LRAUTO,"^",4)=LRLL,LRTYPE=$P(Y(0),"^",3)
  1.  S (%,LRPROF)=0
  1.  F  S %=$O(^LRO(68.2,LRLL,10,%)) Q:'%  S LRPROF=LRPROF+1
  1.  I LRPROF>1 D  Q:LAQUIT
  1.  . N DIC,DIR
  1.  . S DIR(0)="Y",DIR("A")="All Profiles",DIR("B")="YES" D ^DIR
  1.  . I $D(DIRUT) S LAQUIT=1
  1.  . S LRPROF=Y
  1.  . I 'LRPROF D
  1.  . . S DIC="^LRO(68.2,"_LRLL_",10,",DIC(0)="AEMQ"
  1.  . . D ^DIC
  1.  . . I Y<1 S LAQUIT=1
  1.  . . E  S LRPROF=LRPROF_"^"_Y
  1.  ;
  1.  S LAX=$G(^LRO(68.2,LRLL,2))
  1.  I $P(LAX,"^",2)="" D  Q
  1.  . W !,$C(7),"Load/work list not setup"
  1.  . S LAQUIT=1
  1.  ;
  1.  W !!,"Working on the download file for instrument ",$P(LRAUTO,"^",1)
  1.  W !,"from Load list ",$P(^LRO(68.2,LRLL,0),"^",1)
  1.  I 'LRPROF W " using profile ",$P(LRPROF,"^",3)
  1.  ;
  1.  S LRTRAY1=$P(LAX,"^",2)
  1.  ;
  1.  I LRTYPE D  Q:LAQUIT
  1.  . N DIR,DIROUT,DIRUT,DTOUT,DUOUT
  1.  . W !
  1.  . S DIR(0)="NO^"_$P(LAX,"^",2)_":"_$P(LAX,"^",4)_":0"
  1.  . S DIR("A")="Starting Tray number"
  1.  . S DIR("B")=$P(LAX,"^",2)
  1.  . S DIR("?")="Enter a tray to start the build and sending at."
  1.  . D ^DIR
  1.  . I $D(DIRUT) S LAQUIT=1
  1.  . E  S LRTRAY1=Y
  1.  ;
  1.  W !
  1.  K DIR,DIROUT,DIRUT,DTOUT,DUOUT
  1.  S DIR(0)="NO^1:9999:0"
  1.  S DIR("A")="Starting "_$S(LRTYPE:"CUP",1:"SEQUENCE")_" number"
  1.  S DIR("B")=$P(LAX,"^",3)
  1.  S DIR("?")="Enter a "_$S(LRTYPE:"cup",1:"sequence")_" to start the build and sending at."
  1.  D ^DIR
  1.  I $D(DIRUT) S LAQUIT=1
  1.  E  S (LRCUP1,LRCUP2)=Y
  1.  Q
  1.  ;
  1.  ;
  1. PURGE ; Remove the download records from the Load List file, Should be removed when sent.
  1.  N C,T
  1.  D INIT
  1.  I Y'>0 D QUIT Q
  1.  S %=2 W !,"Is this OK" D YN^DICN G QUIT:%'=1
  1.  ;
  1.  S T=0
  1.  F  S T=$O(^LRO(68.2,LRLL,1,T)) Q:T'>0  D
  1.  . S C=0
  1.  . F  S C=$O(^LRO(68.2,LRLL,1,T,1,C)) Q:C'>0  K ^LRO(68.2,LRLL,1,T,1,C,2)
  1.  W !,"DONE"
  1.  D QUIT
  1.  Q
  1.  ;
  1. SEND D INIT
  1.  I Y'>0 D QUIT Q
  1. SE2 ;
  1.  K LRFILE
  1.  I '$D(ZTQUEUED) W !,"Now setting up to send."
  1.  S TSK=LRINST,LRRTN=$P(LRAUTO(9),"^",1,2),LRFILE=$P(^LRO(68.2,LRLL,0),"^",1),T=TSK
  1.  I '$P(LRAUTO,"^",8) D SETO^LAB
  1.  ;
  1.  ;Set-up call
  1.  D:$L($P(LRRTN,U,2)) @("START^"_$P(LRRTN,"^",2))
  1.  ;
  1.  S LRTRAY=LRTRAY1
  1.  F  D  Q:LRTRAY'>0 
  1.  . I $D(^LRO(68.2,LRLL,1,LRTRAY)) D TRAY
  1.  . S LRTRAY=$O(^LRO(68.2,LRLL,1,LRTRAY)) Q:LRTRAY'>0  S LRCUP2=1
  1.  ;
  1.  ;
  1. SE3 ; Clean-up call
  1.  D:$L($P(LRRTN,U,2)) @("END^"_$P(LRRTN,"^",2))
  1.  ;
  1. LAST ;
  1.  I '$D(ZTQUEUED) W !,"DONE. Data should start moving now"
  1.  D QUIT
  1.  Q
  1.  ;
  1. NEW ;Start a new file for each tray.
  1.  D:$L($P(LRRTN,U,2)) @("NEXT^"_$P(LRRTN,"^",2)) Q
  1.  ;
  1. TRAY ;
  1.  S LRNEW=1 Q:LRTRAY'>0
  1.  S LRCUP=LRCUP2-.1
  1.  F  S LRCUP=$O(^LRO(68.2,LRLL,1,LRTRAY,1,LRCUP)) Q:LRCUP'>0  D
  1.  . I LRNEW D NEW
  1.  . S LRNEW=0
  1.  . I $D(^LRO(68.2,LRLL,1,LRTRAY,1,LRCUP,2)) S X=^(2) D:$L($P(LRRTN,U,2)) @LRRTN