Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: LEXDM

LEXDM.m

Go to the documentation of this file. 
  1. LEXDM ;ISL/KER - Default Misc - Mod/Del Sel/Create ;04/21/2014
  1.  ;;2.0;LEXICON UTILITY;**81,80**;Sep 23, 1996;Build 10
  1.  ;               
  1.  ; Global Variables
  1.  ;    None
  1.  ;               
  1.  ; External References
  1.  ;    ^DIR                ICR  10026
  1.  ;               
  1.  ; Entry:  S X=$$MOD^LEXDM(X)
  1.  ; Input   X  1=Filter, 2=Display, 3=Vocabulary or 4=Context
  1.  ; Returns  "^^" Double up-arrow, 0 no action taken, 1 Modify
  1.  ;          default entry or "@" delete default entry
  1.  ;
  1. MOD(LEXX) ; Modify or Delete
  1.  ;
  1.  S LEXX=+($G(LEXX)) Q:LEXX<0 0 S LEXX=LEXX\1  Q:LEXX>4 0
  1.  N DIR,X,Y,DIRUT,DTOUT,DUOUT,DIROUT
  1.  S:LEXX=1 DIR("A",1)="search filter" S:LEXX=2 DIR("A",1)="display format"
  1.  S:LEXX=3 DIR("A",1)="vocabulary" S:LEXX=4 DIR("A",1)="shortcut context"
  1.  S:$L($G(DIR("A",1))) DIR("A",1)="User default "_DIR("A",1)
  1.  S DIR("A",3)="  1  Modify",DIR("A",4)="  2  Delete"
  1.  S (DIR("A",2),DIR("A",5))="  "
  1.  S:LEXX=1 DIR(0)="SAO^1:Modify Default Filter;2:Delete Default Filter"
  1.  S:LEXX=2 DIR(0)="SAO^1:Modify Default Display;2:Delete Default Display"
  1.  S:LEXX=3 DIR(0)="SAO^1:Modify Default Vocabulary;2:Delete Default Vocabulary"
  1.  S:LEXX=4 DIR(0)="SAO^1:Modify Default Shortcut Context;2:Delete Default Shortcut Context"
  1.  S DIR("A")="Select:  ",DIR("B")="1"
  1.  D ^DIR S LEXX=$S(X=1:1,X=2:"@",X="@":"@",1:0) S:Y="^^" LEXX=Y Q LEXX
  1.  ;
  1.  ;-----------------------------------------------------------------
  1.  ; Entry:  S X=$$MTH^LEXDM(X)
  1.  ; Input   X  1=Filter, 2=Display
  1.  ; Returns "^^" Timeout or Double-uparrow, "^" Method not
  1.  ;         selected, 1 Select default from a predefined list
  1.  ;         or 2 Create a user defined default
  1.  ;
  1.  ; LEXM   Method of building string
  1.  ; LEXF   Flag, indicates the default type
  1.  ;
  1. MTH(LEXX) ; Method - Select a predefined or Create new
  1.  Q:'$L($G(LEXX)) "" Q:+LEXX'>0 "" Q:+LEXX'<3 ""
  1.  N LEXF,LEXM S LEXF=+LEXX,LEXM=$$METH W:+LEXM=1!(+LEXM=2) !!
  1.  S LEXX=LEXM S:"12"[LEXM LEXX=LEXM
  1.  S:'$L($G(LEXM))!(LEXM="^") LEXX="^" S:LEXM="^^" LEXX="^^"
  1.  Q LEXX
  1. METH(LEXX) ; Select method
  1.  N DIR,X,Y,DIRUT,DTOUT,DUOUT,DIROUT
  1.  I +LEXF=1 D
  1.  . S DIR("A",1)="Search filters (screens) to limit the response"
  1.  . S DIR("A",3)="  1  Select from predefined filters"
  1.  . S DIR("A",4)="  2  Create your own filter"
  1.  . S DIR("??")="^D HF^LEXDM"
  1.  I +LEXF=2 D
  1.  . S DIR("A",1)="Display format to be used during look-up"
  1.  . S DIR("A",3)="  1  Select from predefined display formats"
  1.  . S DIR("A",4)="  2  Create your own display format"
  1.  . S DIR("??")="^D HD^LEXDM"
  1.  S (DIR("A",2),DIR("A",5))="  "
  1.  S DIR(0)="SAO^1:Predefined Set;2:Create your own set"
  1.  S DIR("A")="Select:  ",DIR("B")="1"
  1.  D ^DIR S LEXX=$S(+Y>0:+Y,1:Y) S:$D(DTOUT) LEXX="^^" Q LEXX
  1. HF ; Help for filters - DIC("S")
  1.  W !!,"When conducting searches in the Lexicon, you may find that many of the"
  1.  W !,"expressions found are not reasonable in the context of intended use."
  1.  W !,"Many of these ""unreasonable"" expressions can be filtered out during the"
  1.  W !,"search, providing a much smaller and more meaningful list of expressions"
  1.  W !,"to select from.  Several of these filters have been predefined and made "
  1.  W !,"available.  You may select from this list of predefined filters or create"
  1.  W !,"your own." Q
  1. HD ; Help for display - LEXSHOW
  1.  W !!,"When conducting searches in the Lexicon, you may alter the display format"
  1.  W !,"of the selection list.  There are several commonly used displays which"
  1.  W !,"have been predefined and made available.  You may select from this list or"
  1.  W !,"create your own." Q