LRBARCFA.m

LRBARCFA ;DALOI/JMC - Lab Label Zebra Configuration Utility ;8/29/94  12:36

 ;;5.2T9;LR;**218,1018**;Nov 17, 2004

 ;

EN ;

 N DA,DIR,DIRUT,DTOUT,DUOUT,LRY,X,Y

 D ZIS

 I POP D END Q

 D USE^%ZISUTL("LRHOME")

 S DIR(0)="SO^1:Configuration Update;2:Print Configuration Label;3:Adjust Tear Off Position;4:Label Top Position;5:Set Darkness;6:Mode Protection (Stripe printers only)"

 S DIR("A")="Select Function",DIR("B")=1

 D ^DIR

 I $D(DIRUT) D END Q

 S LRY=+Y

 I LRY=1 D CU

 I LRY=2 D CFL

 I LRY=3 D TA

 I LRY=4 D LT

 I LRY=5 D SD

 I LRY=6 D MP

 D END

 Q

 ;

CU ; Zebra Configuration Update.

 N LRY,DIR,DIRUT,DTOUT,DUOUT,X,Y

 S DIR(0)="SO^F:Reload Factory Defaults;R:Recall Last Saved Values;S:Save Current Settings"

 D USE^%ZISUTL("LRHOME")

 D ^DIR Q:$D(DIRUT)

 S LRY=Y

 D USE^%ZISUTL("LRLABEL")

 W "^XA^JU"_LRY_"^XZ" ; Set configuration update.

 D CFL

 Q

 ;

CFL ; Print Zebra Configuration Label.

 D USE^%ZISUTL("LRLABEL")

 W "~WC" ; Print configuration label.

 D USE^%ZISUTL("LRHOME")

 Q

 ;

TA ; Zebra Tear Off Adjust Position.

 N LRY,DIR,DIRUT,DTOUT,DUOUT,X,Y

 S DIR(0)="NAO^-64:64:0",DIR("A")="Number of dots to adjust (Range -64 to +64): "

 F  D  Q:$D(DIRUT)

 . D USE^%ZISUTL("LRHOME")

 . D ^DIR Q:$D(DIRUT)

 . S LRY=+Y

 . I LRY<0 S LRY="-"_$$RJ^XLFSTR($P(LRY,"-",2),2,"0")

 . E  S LRY="+"_$$RJ^XLFSTR(LRY,2,"0")

 . D USE^%ZISUTL("LRLABEL")

 . W "^XA~TA"_LRY_"^XZ^XA^JUS^XZ" ; Set tear off and save configuration

 . D CFL

 Q

 ;

LT ; Zebra Label Top Position adjustment

 N LRY,DIR,DIRUT,DTOUT,DUOUT,X,Y

 S DIR(0)="NAO^-64:64:0",DIR("A")="Number of dots to adjust (Range -64 to +64): "

 F  D  Q:$D(DIRUT)

 . D USE^%ZISUTL("LRHOME")

 . D ^DIR Q:$D(DIRUT)

 . S LRY=+Y

 . I LRY<0 S LRY="-"_$$RJ^XLFSTR($P(LRY,"-",2),2,"0")

 . E  S LRY="+"_$$RJ^XLFSTR(LRY,2,"0")

 . D USE^%ZISUTL("LRLABEL")

 . W "^XA^LT"_LRY_"^XZ^XA^JUS^XZ" ; Set label top and save configuration

 . D CFL

 Q

 ;

SD ; Zebra Set Darkness adjustment

 N LRY,DIR,DIRUT,DTOUT,DUOUT,X,Y

 S DIR(0)="NAO^0:30:0",DIR("A")="Number of dots to adjust (Range 0 to 30): "

 F  D  Q:$D(DIRUT)

 . D USE^%ZISUTL("LRHOME")

 . D ^DIR Q:$D(DIRUT)

 . S LRY=+Y

 . S LRY=$$RJ^XLFSTR(LRY,2,"0")

 . D USE^%ZISUTL("LRLABEL")

 . W "^XA~SD"_LRY_"^XZ^XA^JUS^XZ" ; Set darkness and save configuration

 . D CFL

 Q

 ;

MP ; Zebra Mode Protection (only applies to Stripe printers).

 N LRY,DIR,DIRUT,DTOUT,DUOUT,X,Y

 S DIR(0)="SO^E:Enable All Modes;D:Disable Darkness;P:Disable Position;C:Disable Calibration;S:Disable Save Permanent;W:Disable Pause Key;F:Disable Feed Key;X:Disable Cancel Key;M:Disable Menu Changes"

 S DIR("A")="Select Mode to Change"

 D USE^%ZISUTL("LRHOME")

 D ^DIR Q:$D(DIRUT)

 S LRY=Y

 D USE^%ZISUTL("LRLABEL")

 W "^XA^MP"_LRY_"^XZ" ; Set mode protection.

 D CFL

 Q

 ;

ZIS ; Device selection

 D OPEN^%ZISUTL("LRHOME","HOME") ; Setup handle for user's "HOME" device.

 S %ZIS="0",%ZIS("A")="Select ZEBRA Printer: ",%ZIS("B")=""

 S %ZIS("S")="N LRY S LRY=$O(^LAB(69.9,1,3.6,""B"",Y,0)) I LRY,$P($G(^LAB(69.9,1,3.6,LRY,0)),U,2)=2"

 D OPEN^%ZISUTL("LRLABEL",,.%ZIS) ; Setup handle for user's LABEL device.

 Q

 ;

END ; Clean up.

 I $D(ZTQUEUED) S ZTREQ="@"

 E  D

 . D CLOSE^%ZISUTL("LRLABEL")

 . D CLOSE^%ZISUTL("LRHOME")

 Q

LRBARCFA  ;DALOI/JMC - Lab Label Zebra Configuration Utility ;8/29/94  12:36

 +1       ;;5.2T9;LR;**218,1018**;Nov 17, 2004

 +2       ;

EN        ;

 +1        NEW DA,DIR,DIRUT,DTOUT,DUOUT,LRY,X,Y

 +2        DO ZIS

 +3        IF POP

               DO END

               QUIT 

 +4        DO USE^%ZISUTL("LRHOME")

 +5        SET DIR(0)="SO^1:Configuration Update;2:Print Configuration Label;3:Adjust Tear Off Position;4:Label Top Position;5:Set Darkness;6:Mode Protection (Stripe printers only)"

 +6        SET DIR("A")="Select Function"

           SET DIR("B")=1

 +7        DO ^DIR

 +8        IF $DATA(DIRUT)

               DO END

               QUIT 

 +9        SET LRY=+Y

 +10       IF LRY=1

               DO CU

 +11       IF LRY=2

               DO CFL

 +12       IF LRY=3

               DO TA

 +13       IF LRY=4

               DO LT

 +14       IF LRY=5

               DO SD

 +15       IF LRY=6

               DO MP

 +16       DO END

 +17       QUIT 

 +18      ;

CU        ; Zebra Configuration Update.

 +1        NEW LRY,DIR,DIRUT,DTOUT,DUOUT,X,Y

 +2        SET DIR(0)="SO^F:Reload Factory Defaults;R:Recall Last Saved Values;S:Save Current Settings"

 +3        DO USE^%ZISUTL("LRHOME")

 +4        DO ^DIR

           IF $DATA(DIRUT)

               QUIT 

 +5        SET LRY=Y

 +6        DO USE^%ZISUTL("LRLABEL")

 +7       ; Set configuration update.

           WRITE "^XA^JU"_LRY_"^XZ"

 +8        DO CFL

 +9        QUIT 

 +10      ;

CFL       ; Print Zebra Configuration Label.

 +1        DO USE^%ZISUTL("LRLABEL")

 +2       ; Print configuration label.

           WRITE "~WC"

 +3        DO USE^%ZISUTL("LRHOME")

 +4        QUIT 

 +5       ;

TA        ; Zebra Tear Off Adjust Position.

 +1        NEW LRY,DIR,DIRUT,DTOUT,DUOUT,X,Y

 +2        SET DIR(0)="NAO^-64:64:0"

           SET DIR("A")="Number of dots to adjust (Range -64 to +64): "

 +3        FOR 

               Begin DoDot:1

 +4                DO USE^%ZISUTL("LRHOME")

 +5                DO ^DIR

                   IF $DATA(DIRUT)

                       QUIT 

 +6                SET LRY=+Y

 +7                IF LRY<0

                       SET LRY="-"_$$RJ^XLFSTR($PIECE(LRY,"-",2),2,"0")

 +8               IF '$TEST

                       SET LRY="+"_$$RJ^XLFSTR(LRY,2,"0")

 +9                DO USE^%ZISUTL("LRLABEL")

 +10      ; Set tear off and save configuration

                   WRITE "^XA~TA"_LRY_"^XZ^XA^JUS^XZ"

 +11               DO CFL

               End DoDot:1

               IF $DATA(DIRUT)

                   QUIT 

 +12       QUIT 

 +13      ;

LT        ; Zebra Label Top Position adjustment

 +1        NEW LRY,DIR,DIRUT,DTOUT,DUOUT,X,Y

 +2        SET DIR(0)="NAO^-64:64:0"

           SET DIR("A")="Number of dots to adjust (Range -64 to +64): "

 +3        FOR 

               Begin DoDot:1

 +4                DO USE^%ZISUTL("LRHOME")

 +5                DO ^DIR

                   IF $DATA(DIRUT)

                       QUIT 

 +6                SET LRY=+Y

 +7                IF LRY<0

                       SET LRY="-"_$$RJ^XLFSTR($PIECE(LRY,"-",2),2,"0")

 +8               IF '$TEST

                       SET LRY="+"_$$RJ^XLFSTR(LRY,2,"0")

 +9                DO USE^%ZISUTL("LRLABEL")

 +10      ; Set label top and save configuration

                   WRITE "^XA^LT"_LRY_"^XZ^XA^JUS^XZ"

 +11               DO CFL

               End DoDot:1

               IF $DATA(DIRUT)

                   QUIT 

 +12       QUIT 

 +13      ;

SD        ; Zebra Set Darkness adjustment

 +1        NEW LRY,DIR,DIRUT,DTOUT,DUOUT,X,Y

 +2        SET DIR(0)="NAO^0:30:0"

           SET DIR("A")="Number of dots to adjust (Range 0 to 30): "

 +3        FOR 

               Begin DoDot:1

 +4                DO USE^%ZISUTL("LRHOME")

 +5                DO ^DIR

                   IF $DATA(DIRUT)

                       QUIT 

 +6                SET LRY=+Y

 +7                SET LRY=$$RJ^XLFSTR(LRY,2,"0")

 +8                DO USE^%ZISUTL("LRLABEL")

 +9       ; Set darkness and save configuration

                   WRITE "^XA~SD"_LRY_"^XZ^XA^JUS^XZ"

 +10               DO CFL

               End DoDot:1

               IF $DATA(DIRUT)

                   QUIT 

 +11       QUIT 

 +12      ;

MP        ; Zebra Mode Protection (only applies to Stripe printers).

 +1        NEW LRY,DIR,DIRUT,DTOUT,DUOUT,X,Y

 +2        SET DIR(0)="SO^E:Enable All Modes;D:Disable Darkness;P:Disable Position;C:Disable Calibration;S:Disable Save Permanent;W:Disable Pause Key;F:Disable Feed Key;X:Disable Cancel Key;M:Disable Menu Changes"

 +3        SET DIR("A")="Select Mode to Change"

 +4        DO USE^%ZISUTL("LRHOME")

 +5        DO ^DIR

           IF $DATA(DIRUT)

               QUIT 

 +6        SET LRY=Y

 +7        DO USE^%ZISUTL("LRLABEL")

 +8       ; Set mode protection.

           WRITE "^XA^MP"_LRY_"^XZ"

 +9        DO CFL

 +10       QUIT 

 +11      ;

ZIS       ; Device selection

 +1       ; Setup handle for user's "HOME" device.

           DO OPEN^%ZISUTL("LRHOME","HOME")

 +2        SET %ZIS="0"

           SET %ZIS("A")="Select ZEBRA Printer: "

           SET %ZIS("B")=""

 +3        SET %ZIS("S")="N LRY S LRY=$O(^LAB(69.9,1,3.6,""B"",Y,0)) I LRY,$P($G(^LAB(69.9,1,3.6,LRY,0)),U,2)=2"

 +4       ; Setup handle for user's LABEL device.

           DO OPEN^%ZISUTL("LRLABEL",,.%ZIS)

 +5        QUIT 

 +6       ;

END       ; Clean up.

 +1        IF $DATA(ZTQUEUED)

               SET ZTREQ="@"

 +2       IF '$TEST

               Begin DoDot:1

 +3                DO CLOSE^%ZISUTL("LRLABEL")

 +4                DO CLOSE^%ZISUTL("LRHOME")

               End DoDot:1

 +5        QUIT