MCPRE05.m

MCPRE05 ;HIRMFO/DAD-CLEAN UP DATA IN INDICATION FILE (#694.1) ;4/26/96  14:49

 ;;2.3;Medicine;;09/13/1996

 ;

 N MCDATA,MCORSPEL,MCLOOP,MCTXT,MCD0,DIE,DA,DR

 S MCDATA(1)=""

 S MCDATA(2)="Correcting misspellings in the Indication file (#694.1)."

 D MES^XPDUTL(.MCDATA)

 ;

 S MCORSPEL=$P($T(CORRECT+1),";",3)

 F MCLOOP=1:1 S MCTXT=$P($T(MISP+MCLOOP),";",3)  Q:MCTXT=""  D

 . S MCD0=0

 . F  S MCD0=$O(^MCAR(694.1,"B",MCTXT,MCD0)) Q:MCD0'>0  D

 .. I $P($G(^MCAR(694.1,MCD0,0)),U)'=MCTXT Q

 .. S DIE="^MCAR(694.1,",DA=MCD0,DR=".01///"_MCORSPEL

 .. D ^DIE

 .. Q

 . Q

 Q

CORRECT ;Correct spelling

 ;;ASSESS PROGRESSION OR STATUS OF KNOWN HEMATOLOGIC DISEASE OR DISORDER

MISP ;Known misspelling

 ;;ASSES PROGRESSION OF STATUS OF KNOW HEMATOLOGIC DISEASE OR

 ;;ASSES PROGRESSION OF STATUS OF KNOW HEMATOLOGIC DISEASE OR DISORDER

 ;;ASSES PROGRESSION OR STATUS OF KNOW HEMATOLOGIC DISEASE OR DISORDER

 ;;ASSESS PROGRESSION OR STATUS OF KNOW HEMATOLOGIC DISEASE OR DISORDER

 ;;ASSESS PROGRESSION OR STATUS OF HEMATOLOGIC DISEASE OR DISORDER

MCPRE05   ;HIRMFO/DAD-CLEAN UP DATA IN INDICATION FILE (#694.1) ;4/26/96  14:49

 +1       ;;2.3;Medicine;;09/13/1996

 +2       ;

 +3        NEW MCDATA,MCORSPEL,MCLOOP,MCTXT,MCD0,DIE,DA,DR

 +4        SET MCDATA(1)=""

 +5        SET MCDATA(2)="Correcting misspellings in the Indication file (#694.1)."

 +6        DO MES^XPDUTL(.MCDATA)

 +7       ;

 +8        SET MCORSPEL=$PIECE($TEXT(CORRECT+1),";",3)

 +9        FOR MCLOOP=1:1

               SET MCTXT=$PIECE($TEXT(MISP+MCLOOP),";",3)

               IF MCTXT=""

                   QUIT 

               Begin DoDot:1

 +10               SET MCD0=0

 +11               FOR 

                       SET MCD0=$ORDER(^MCAR(694.1,"B",MCTXT,MCD0))

                       IF MCD0'>0

                           QUIT 

                       Begin DoDot:2

 +12                       IF $PIECE($GET(^MCAR(694.1,MCD0,0)),U)'=MCTXT

                               QUIT 

 +13                       SET DIE="^MCAR(694.1,"

                           SET DA=MCD0

                           SET DR=".01///"_MCORSPEL

 +14                       DO ^DIE

 +15                       QUIT 

                       End DoDot:2

 +16               QUIT 

               End DoDot:1

 +17       QUIT 

CORRECT   ;Correct spelling

 +1       ;;ASSESS PROGRESSION OR STATUS OF KNOWN HEMATOLOGIC DISEASE OR DISORDER

MISP      ;Known misspelling

 +1       ;;ASSES PROGRESSION OF STATUS OF KNOW HEMATOLOGIC DISEASE OR

 +2       ;;ASSES PROGRESSION OF STATUS OF KNOW HEMATOLOGIC DISEASE OR DISORDER

 +3       ;;ASSES PROGRESSION OR STATUS OF KNOW HEMATOLOGIC DISEASE OR DISORDER

 +4       ;;ASSESS PROGRESSION OR STATUS OF KNOW HEMATOLOGIC DISEASE OR DISORDER

 +5       ;;ASSESS PROGRESSION OR STATUS OF HEMATOLOGIC DISEASE OR DISORDER