Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: OCXDEBUG

OCXDEBUG.m

Go to the documentation of this file. 
  1. OCXDEBUG ;SLC/RJS,CLA - ORDER CHECK COMPILED CODE DEBUGGER (SINGLE/MULTI);10/29/98  12:37
  1.  ;;3.0;ORDER ENTRY/RESULTS REPORTING;**32**;Dec 17,1997
  1.  ;;  ;;ORDER CHECK EXPERT version 1.01 released OCT 29,1998
  1.  ;
  1. SINGLE ;
  1.  ;
  1.  N OCXOLOG,IOP
  1.  ;
  1.  I '$O(^OCXD(861,1)) W !!,"No entries in the raw data log..." Q
  1.  ;
  1.  K ^TMP("OCXDEBUG",$J)
  1.  S ^TMP("OCXDEBUG",$J)=($P($H,",",2)+($H*86400)+(4*60*60))_" <- ^TMP ENTRY EXPIRATION DATE FOR ^OCXOPURG"
  1.  S IOP=0 D ^%ZIS K IOP S X=132 U IO X ^%ZOSF("RM")
  1.  ;
  1.  F  W !! S OCXOLOG=+$$LOOKUP("Select Log entry number: ") Q:'OCXOLOG  D RUN(OCXOLOG,$$ASKFLAG,$$ASKPURG),REPORT
  1.  Q
  1.  ;
  1. ASKFLAG() Q ('$$READ("Y","Do you want to send any alerts generated ","NO")*10)+1
  1.  ;
  1. ASKPURG() Q $$READ("Y","Do you want purge rule events ","NO")
  1.  ;
  1. SMOKE(OCXTRACE) ;
  1.  N OCXOLOG,OCXP,OCX1,OCX2,OCX3
  1.  ;
  1.  I '$O(^OCXD(861,1)) W !!,"No entries in the raw data log..." Q
  1.  S:'$L($G(OCXTRACE)) OCXTRACE=11
  1.  ;
  1.  W !
  1.  W !,"First Entry: ",+$O(^OCXD(861,1))
  1.  W !,"Last Entry: ",+$O(^OCXD(861," "),-1)
  1.  K ^TMP("OCXDEBUG",$J)
  1.  S ^TMP("OCXDEBUG",$J)=($P($H,",",2)+($H*86400)+(4*60*60))_" <- ^TMP ENTRY EXPIRATION DATE FOR ^OCXOPURG"
  1.  S IOP=0 D ^%ZIS K IOP S X=132 U IO X ^%ZOSF("RM")
  1.  ;
  1.  S OCXP=$$ASKPURG
  1.  S OCX1=$$LOOKUP("Start at Log Number: ")
  1.  S OCX2=$$LOOKUP(" Stop at Log Number: ")
  1.  S:(OCX1>OCX2) OCX3=OCX2,OCX2=OCX1,OCX1=OCX3
  1.  S OCXOLOG=OCX1 D  F  S OCXOLOG=$O(^OCXD(861,OCXOLOG)) Q:'OCXOLOG  Q:(OCXOLOG>OCX2)  D
  1.  .W @IOF D RUN(OCXOLOG,OCXTRACE,OCXP)
  1.  D ^%ZIS
  1.  U IO D REPORT D ^%ZISC
  1.  Q
  1.  ;
  1. REPORT ;
  1.  N OCXD0,OCXD1
  1.  I '$O(^TMP("OCXDEBUG",$J,0)) W !!,"No rules triggered.",!! Q
  1.  W !!,"************* Rules triggered ****************",!
  1.  S OCXD0=0 F  S OCXD0=$O(^TMP("OCXDEBUG",$J,OCXD0)) Q:'OCXD0  D
  1.  .S OCXD1=0 F  S OCXD1=$O(^TMP("OCXDEBUG",$J,OCXD0,OCXD1)) Q:'OCXD1  D
  1.  ..W !,"Rule: (",(+OCXD0),")  ",$P($G(^OCXS(860.2,+OCXD0,0)),U,1)
  1.  ..W !,"Relation: (",(+OCXD1),")  ",$G(^OCXS(860.2,+OCXD0,"R",+OCXD1,"E"))
  1.  ..W !,"       Number triggered: ",+$G(^TMP("OCXDEBUG",$J,OCXD0,OCXD1))
  1.  ..W !
  1.  Q
  1.  ;
  1. RUN(OCXDEBUG,OCXTRACE,OCXPURGE) ;
  1.  ;
  1.  Q:'$D(^OCXD(861,OCXDEBUG))  Q:'$D(^OCXD(861,OCXDEBUG,"SOURCE"))
  1.  ;
  1.  N OCXA,OCXAR,OCXD0
  1.  ;
  1.  M OCXA=^OCXD(861,OCXDEBUG)
  1.  ;
  1.  W !,"RUN: ",OCXDEBUG,"   ",OCXA("SOURCE")
  1.  ;
  1.  I OCXPURGE D
  1.  .N DFN S DFN=+$P($G(OCXA("PATIENT")),"[",2) Q:'DFN
  1.  .K ^OCXD(860.7,DFN,1)
  1.  .K ^OCXD(860.7,"AT",+$H,DFN)
  1.  ;
  1.  I (OCXA("SOURCE")="HL7") D  Q
  1.  .S OCXAR=OCXA("ARRAY")
  1.  .I '(OCXAR[U) N @OCXAR
  1.  .N OCXDBMSG
  1.  .S OCXD0=0 F  S OCXD0=$O(OCXA("DATA",OCXD0)) Q:'OCXD0  D
  1.  ..N LAST,TEXT
  1.  ..S LAST=$O(@OCXAR@(" "),-1)
  1.  ..S TEXT=OCXA("DATA",OCXD0,0)
  1.  ..I LAST,($E(TEXT,1,3)=">>>") S TEXT=$E(TEXT,4,$L(TEXT))
  1.  ..E  S LAST=LAST+1
  1.  ..S @OCXAR@(LAST)=$G(@OCXAR@(LAST))_TEXT
  1.  .S OCXDBMSG=""
  1.  .W !!
  1.  .I '(OCXAR[U) X "D SILENT^OCXOHL7(."_OCXAR_",.OCXDBMSG)" I 1
  1.  .E  D SILENT^OCXOHL7(.OCXAR,.OCXDBMSG)
  1.  .I ($D(OCXDBMSG)>1) D ZW("OCXDBMSG")
  1.  .I (OCXAR[U) K @OCXAR
  1.  ;
  1.  I (OCXA("SOURCE")="DGPM") D  Q
  1.  .N DGPM0,DGPMA,DGPMDA,DFN,OCXDBMSG
  1.  .S OCXD0=0 F  S OCXD0=$O(OCXA("DATA",OCXD0)) Q:'OCXD0  D
  1.  ..N TEXT S TEXT=OCXA("DATA",OCXD0,0)
  1.  ..S @$P(TEXT,"=",1)=$P(TEXT,"=",2,999)
  1.  .S DFN=+$P($G(OCXA("PATIENT")),"[",2)
  1.  .S OCXDBMSG=""
  1.  .W !! D SILENT^OCXODGPM(.OCXDBMSG)
  1.  .I ($D(OCXDBMSG)>1) D ZW("OCXDBMSG")
  1.  ;
  1.  I (OCXA("SOURCE")="OEPS") D  Q
  1.  .N OCXPSD,OCXPSM,DFN,OCXDBMSG
  1.  .S OCXD0=0 F  S OCXD0=$O(OCXA("DATA",OCXD0)) Q:'OCXD0  D
  1.  ..N TEXT S TEXT=OCXA("DATA",OCXD0,0)
  1.  ..S @$P(TEXT,"=",1)=$P(TEXT,"=",2,999)
  1.  .S DFN=+$P($G(OCXA("PATIENT")),"[",2)
  1.  .S OCXDBMSG=""
  1.  .W ! D EN^OCXOEPS(.OCXDBMSG,DFN,OCXPSD,OCXPSM) ;
  1.  .I ($D(OCXDBMSG)>1) D ZW("OCXDBMSG")
  1.  ;
  1.  I (OCXA("SOURCE")="OERR") D  Q
  1.  .N OCXORD,DFN,OCXDBMSG
  1.  .S OCXD0=0 F  S OCXD0=$O(OCXA("DATA",OCXD0)) Q:'OCXD0  D
  1.  ..N TEXT S TEXT=OCXA("DATA",OCXD0,0)
  1.  ..S @$P(TEXT,"=",1)=$P(TEXT,"=",2,999)
  1.  .S DFN=+$P($G(OCXA("PATIENT")),"[",2)
  1.  .S OCXDBMSG=""
  1.  .W ! D SILENT^OCXOERR(OCXORD,.OCXDBMSG) ;
  1.  .I ($D(OCXDBMSG)>1) D ZW("OCXDBMSG")
  1.  Q
  1.  ;
  1. LOOKUP(OCXDLG) ;
  1.  ;
  1.  N DIC,X,Y
  1.  S:$L($G(OCXDLG)) DIC("A")=OCXDLG
  1.  S DIC="^OCXD(861,",DIC(0)="AMNEQ"
  1.  S DIC("S")="I (Y>1)"
  1.  S DIC("W")="W ""  "",$G(^(""SOURCE"")),""  "",$G(^(""PATIENT""))"
  1.  S Y=0 D ^DIC
  1.  Q:(Y<0) 0 Q +Y
  1.  ;
  1. ZW(ARRAY) ;
  1.  W !,ARRAY
  1.  N NODE
  1.  I ($D(@ARRAY)#10) W !,ARRAY," = ",@ARRAY
  1.  S:($E(ARRAY,$L(ARRAY))=")") ARRAY=$E(ARRAY,1,$L(ARRAY)-1)_","
  1.  S NODE=ARRAY F  S NODE=$Q(@NODE) Q:'$L(NODE)  Q:'($E(NODE,1,$L(ARRAY))=ARRAY)  W !,NODE," = ",@NODE
  1.  Q
  1.  ;
  1. LOGAL(OCXR0,OCXR1,OCXN,OCXDFN,OCXNUM,OCXADUZ,OCXPMSG,OCXPDATA) ;
  1.  ;
  1.  ;    OCXR0: Rule IEN
  1.  ;    OCXR1: Relation IEN
  1.  ;     OCXN: notification identifier (required)
  1.  ;   OCXDFN: patient identifier   (required)
  1.  ;   OCXNUM: order number - used to determine ordering provider
  1.  ;  OCXADUZ: array of package-identified recipients
  1.  ;  OCXPMSG: package-defined message
  1.  ; OCXPDATA: package-defined data for follow-up action
  1.  ;
  1.  I $G(OCXR0),$G(OCXR1) S ^TMP("OCXDEBUG",$J,+OCXR0,+OCXR1)=$G(^TMP("OCXDEBUG",$J,+OCXR0,+OCXR1))+1
  1.  ;
  1.  Q
  1.  ;
  1. READ(OCXZ0,OCXZA,OCXZB,OCXZL) ;
  1.  N OCXLINE,DIR,DTOUT,DUOUT,DIRUT,DIROUT
  1.  Q:'$L($G(OCXZ0)) U
  1.  S DIR(0)=OCXZ0
  1.  S:$L($G(OCXZA)) DIR("A")=OCXZA
  1.  S:$L($G(OCXZB)) DIR("B")=OCXZB
  1.  F OCXLINE=1:1:($G(OCXZL)-1) W !
  1.  D ^DIR
  1.  I $D(DTOUT)!$D(DUOUT)!$D(DIRUT)!$D(DIROUT) Q U
  1.  Q Y
  1.  ;
  1. TIME ;
  1.  ;
  1.  N OCXD0,OCXT1,OCXT2,OCXT3,OCXTIME,OCXMAX
  1.  ;
  1.  S (OCXMAX,OCXD0)=0 F  S OCXD0=$O(^OCXD(861,OCXD0)) Q:'OCXD0  D
  1.  .Q:'$D(^OCXD(861,OCXD0,"STATUS"))
  1.  .S OCXT1=+$G(^OCXD(861,OCXD0,0))
  1.  .S OCXT1=$P(OCXT1,".",2)
  1.  .S OCXT1=$E(OCXT1_"000000",1,6)
  1.  .S OCXT1=($E(OCXT1,1,2)*3600)+($E(OCXT1,3,4)*60)+($E(OCXT1,5,6))
  1.  .S OCXT2=$G(^OCXD(861,OCXD0,"STATUS"))
  1.  .S OCXT2=+$P(OCXT2," AT ",2)
  1.  .S OCXT2=$P(OCXT2,".",2)
  1.  .S OCXT2=$E(OCXT2_"000000",1,6)
  1.  .S OCXT2=($E(OCXT2,1,2)*3600)+($E(OCXT2,3,4)*60)+($E(OCXT2,5,6))
  1.  .S OCXT3=(OCXT2-OCXT1) Q:(OCXT3<0)
  1.  .I (OCXT3>OCXMAX) S OCXMAX=OCXT3_U_OCXD0
  1.  .S OCXTIME(OCXT3)=$G(OCXTIME(OCXT3))+1
  1.  ;
  1.  W !!,"Number of seconds",?20,"Number of occurences",!
  1.  S OCXT1="" F  S OCXT1=$O(OCXTIME(OCXT1)) Q:'$L(OCXT1)  D
  1.  .I OCXT1 W !,$J(OCXT1,4)
  1.  .E  W !,"Less than 1 second"
  1.  .W ?20,$J(+$G(OCXTIME(OCXT1)),6)
  1.  I $P(OCXMAX,U,2) W !!,"Maximum wait: ",+OCXMAX," second(s).  Log entry: ",$P(OCXMAX,U,2)
  1.  ;
  1.  Q
  1.  ;