Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ORB3F1

ORB3F1.m

Go to the documentation of this file. 
  1. ORB3F1 ; slc/CLA - Extrinsic functions to support OE/RR 3 notifications ;5/8/95  15:16 [2/24/05 1:23pm]
  1.  ;;3.0;ORDER ENTRY/RESULTS REPORTING;**9,74,139,190,220**;Dec 17, 1997
  1.  ;
  1. XQAKILL(ORN) ;extrinsic function to return the delete mechanism for the notification based on definition in PARAM DEF file
  1.  N ORBKILL S ORBKILL=1
  1.  Q:$G(ORN)="" ORBKILL
  1.  S ORBKILL=$$GET^XPAR("DIV^SYS^PKG","ORB DELETE MECHANISM",ORN,"I")
  1.  I ORBKILL="A" S ORBKILL=0  ;delete for all recipients
  1.  E  S ORBKILL=1  ;default for delete mechanism is 1 (delete only for this recipient)
  1.  Q ORBKILL
  1. SITEORD(ORNUM,IOPT) ;Extrinsic function returns 1 (Yes) if the site has flagged the
  1.  ; orderable item (determined from the order number ORNUM) to trigger a
  1.  ; notification when ordered
  1.  N ORBFLAG,OI,ORBLST,ORBERR,ORBI,ORBE
  1.  S ORBFLAG=0,OI="",ORBE="",ORBERR=""
  1.  Q:+$G(ORNUM)<1 ORBFLAG
  1.  S OI=$$OI^ORQOR2(ORNUM)
  1.  Q:+$G(OI)<1 ORBFLAG
  1.  I IOPT="I" D
  1.  .D ENVAL^XPAR(.ORBLST,"ORB OI ORDERED - INPT","`"_OI,.ORBERR)
  1.  .Q:$G(ORBLST)>0
  1.  .D ENVAL^XPAR(.ORBLST,"ORB OI ORDERED - INPT PR","`"_OI,.ORBERR)
  1.  I IOPT="O" D
  1.  .D ENVAL^XPAR(.ORBLST,"ORB OI ORDERED - OUTPT","`"_OI,.ORBERR)
  1.  .Q:$G(ORBLST)>0
  1.  .D ENVAL^XPAR(.ORBLST,"ORB OI ORDERED - OUTPT PR","`"_OI,.ORBERR)
  1.  I 'ORBERR,$G(ORBLST)>0 D
  1.  .F ORBI=1:1:ORBLST Q:ORBFLAG=1  D
  1.  ..S ORBE=$O(ORBLST(ORBE))
  1.  ..I $D(ORBLST(ORBE,OI)) S ORBFLAG=1
  1.  Q ORBFLAG
  1. SITERES(ORNUM,IOPT) ;Extrinsic function returns 1 (Yes) if the site has flagged the
  1.  ; orderable item (determined from the order number ORNUM) to trigger a
  1.  ; notification when resulted
  1.  N ORBFLAG,OI,ORBLST,ORBERR,ORBI,ORBE
  1.  S ORBFLAG=0,OI="",ORBE="",ORBERR=""
  1.  Q:+$G(ORNUM)<1 ORBFLAG
  1.  S OI=$$OI^ORQOR2(ORNUM)
  1.  Q:+$G(OI)<1 ORBFLAG
  1.  I IOPT="I" D ENVAL^XPAR(.ORBLST,"ORB OI RESULTS - INPT","`"_OI,.ORBERR)
  1.  I IOPT="O" D ENVAL^XPAR(.ORBLST,"ORB OI RESULTS - OUTPT","`"_OI,.ORBERR)
  1.  I 'ORBERR,$G(ORBLST)>0 D
  1.  .F ORBI=1:1:ORBLST Q:ORBFLAG=1  D
  1.  ..S ORBE=$O(ORBLST(ORBE))
  1.  ..I $D(ORBLST(ORBE,OI)) S ORBFLAG=1
  1.  Q ORBFLAG
  1. LRRAD(OI) ;Extrinsic function returns 1 (true) if Orderable Item is a
  1.  ;Chemistry Lab ("S.CH") or Imaging ("S.XRAY") proc or Consult ("S.CSLT")
  1.  N OITEXT,ORBFLAG
  1.  S ORBFLAG=""
  1.  Q:+$G(OI)<1 ORBFLAG
  1.  Q:'$L($G(^ORD(101.43,OI,0))) ORBFLAG
  1.  S OITEXT=$P(^ORD(101.43,OI,0),U)
  1.  S OITEXT=$$UP^XLFSTR(OITEXT)
  1.  Q:$D(^ORD(101.43,"S.CH",OITEXT)) 1
  1.  Q:$D(^ORD(101.43,"S.XRAY",OITEXT)) 1
  1.  Q:$D(^ORD(101.43,"S.CSLT",OITEXT)) 1
  1.  Q ORBFLAG
  1.  ;
  1. EXP(ORDT,ORNUM) ;set up ^XTMP("ORAE" to store expired orders
  1.  N ORNOW,X0
  1.  S ORNOW=$$NOW^XLFDT
  1.  S ^XTMP("ORAE",0)=$$FMADD^XLFDT(ORNOW,30,"","","")_U_ORNOW
  1.  S X0=^OR(100,ORNUM,0)
  1.  S ^XTMP("ORAE",$P(X0,U,2),$P(X0,U,11),ORDT,ORNUM)=""
  1.  Q
  1.  ;
  1. DELEXP ; delete ^XTMP("ORAE" entries older than param value + 48 hours 
  1.  ; or have been replaced by another order
  1.  N ORNOW,OREXDT,OREXPAR,ORDELDT,ORPT,ORDG,ORN,ORREP
  1.  S ORNOW=$$NOW^XLFDT
  1.  S OREXPAR=$$GET^XPAR("ALL","ORWOR EXPIRED ORDERS",1,"I")
  1.  S OREXPAR=$S($G(OREXPAR):OREXPAR,1:72)
  1.  S ORDELDT=$$FMADD^XLFDT(ORNOW,"",-(OREXPAR+48),"","")
  1.  S ORPT=0 F  S ORPT=$O(^XTMP("ORAE",ORPT)) Q:'ORPT  D
  1.  .S ORDG=0 F  S ORDG=$O(^XTMP("ORAE",ORPT,ORDG)) Q:'ORDG  D
  1.  ..S OREXDT=0 F  S OREXDT=$O(^XTMP("ORAE",ORPT,ORDG,OREXDT)) Q:'OREXDT  D
  1.  ...I OREXDT<ORDELDT K ^XTMP("ORAE",ORPT,ORDG,OREXDT) Q
  1.  ...S ORN=0 F  S ORN=$O(^XTMP("ORAE",ORPT,ORDG,OREXDT,ORN)) Q:'ORN  D
  1.  ....Q:'$D(^OR(100,ORN,3))
  1.  ....S ORREP=$P(^OR(100,ORN,3),U,6)
  1.  ....I +$G(ORREP)>0 K ^XTMP("ORAE",ORPT,ORDG,OREXDT,ORN)
  1.  Q