Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ORCACT01

ORCACT01.m

Go to the documentation of this file. 
  1. ORCACT01 ;SLC/MKB-Validate order actions cont ;14-Mar-2011 19:37;PLS
  1.  ;;3.0;ORDER ENTRY/RESULTS REPORTING;**94,116,134,141,163,187,190,1002,1004,213,243,1006,1010**;Dec 17, 1997;Build 47
  1.  ;Modified - IHS/MSC/PLS - 08/09/10 - Line ES+5,ES+7,RW+2
  1.  ;                         03/02/11 - Line XFR+5 - added check for NV RX
  1. ES ; -- sign [on chart]
  1.  I ORDSTS=11,VER<3,PKG'="OR" S ERROR="This order cannot be released and must be discontinued!" Q
  1.  N X I ACTSTS=11!(ACTSTS=10) D  Q:$L($G(ERROR))
  1.  . I $P(ORA0,U,2)="DC",$$DONE^ORCACT0 D CANCEL^ORCSEND(+IFN),UNOTIF^ORCSIGN S OREBUILD=1 Q
  1.  . S X=$$DISABLED^ORCACT0 I X S ERROR=$P(X,U,2) Q
  1.  ;I ACTION="OC",$G(DG)="NV RX" S:MEDPARM<2 ERROR="You are not authorized to release outside med orders!" Q
  1.  I ACTION="OC",$L($G(NV)) S:MEDPARM<2 ERROR="You are not authorized to release "_NV_" orders!" Q
  1.  ;S X=$P(ORA0,U,4) I X=3 S:ACTSTS'=11&(ACTSTS'=10) ERROR="This order does not require a signature!" Q
  1.  S X=$P(ORA0,U,4) I X=3 Q:$L($G(NV))  S:ACTSTS'=11&(ACTSTS'=10) ERROR="This order does not require a signature!" Q
  1.  I X'=2 S ERROR="This order has been signed!" Q
  1.  I DG="O RX",ACTION'="ES",ACTION'="DS",$G(NATR)'="I" S ERROR="Outpatient meds may not be released without a clinician's signature!" Q
  1.  I (ACTION="ES"!(ACTION="DS")),$D(^XUSEC("ORELSE",DUZ)),$P(OR0,U,16)'<2 S ERROR="You are not privileged to sign this order!" Q
  1.  I ACTION="OC" S:MEDPARM<2 ERROR="You are not authorized to release med orders!" Q
  1.  I ACTION="RS" D  Q:$D(ERROR)  Q:$G(NATR)'="I"
  1.  . Q:ACTSTS=11  Q:ACTSTS=10  ;unreleased - ok
  1.  . S ERROR="This order has already been released!"
  1. ES1 I PKG="PS" D  ;authorized to write meds?
  1.  . N TYPE,OI,PSOI,DEAFLG,PKI,IVERROR
  1.  . S X=$G(^VA(200,DUZ,"PS"))
  1.  . I '$P(X,U) S ERROR="You are not authorized to sign med orders!" Q
  1.  . I $P(X,U,4),$$NOW^XLFDT>$P(X,U,4) S ERROR="You are no longer authorized to sign med orders!" Q
  1.  . ;Q:DG="IV RX"  Q:$P(ORA0,U,2)="DC"  ;don't need to ck DEA#
  1.  . Q:$P(ORA0,U,2)="DC"
  1.  . I DG="IV RX" D  Q
  1.  . .I $$IVDEACHK(+IFN)=1 S ERROR="You must have a valid DEA# or VA# to sign this order!"
  1.  . S OI=+$$VALUE^ORX8(+IFN,"ORDERABLE")
  1.  . S PSOI=+$P($G(^ORD(101.43,OI,0)),U,2) Q:PSOI'>0
  1.  . S TYPE=$S($P(DG," ")="O":"O",1:"I"),DEAFLG=$$OIDEA^PSSUTLA1(PSOI,TYPE)
  1.  . I (DEAFLG>0||$$ISCLOZ^ORALWORD(OI)),'$L($$DEA^XUSER()) S ERROR="You must have a valid DEA# or VA# to sign this order!" Q
  1.  . D PKISITE^ORWOR(.PKI)
  1.  . I $G(PKI),ACTION="RS",DEAFLG=1 S ERROR="This order cannot be released without a Digital Signature" Q
  1.  Q
  1.  ;
  1. IVDEACHK(IFN) ; -- Returns value of prompt by ID
  1.  I '$G(IFN)!('$D(^OR(100,+$G(IFN),0))) Q ""
  1.  N I,DIAL,DIALTYP,FAIL,PATCLASS,RESULT,Y
  1.  S PATCLASS=$P(^OR(100,+IFN,0),U,12)
  1.  S RESULT=0
  1.  ;if ORNP is not set then assume this is called from VistA not CPRS
  1.  I $G(ORNP)="" S ORNP=DUZ
  1.  S I=0,Y="" S:'$G(INST) INST=1
  1.  F  S I=$O(^OR(100,+IFN,4.5,"ID","ORDERABLE",I)) Q:I'>0!(RESULT=1)  D
  1.  .S Y=$G(^OR(100,+IFN,4.5,I,1)) Q:Y'>0
  1.  .;S PSOI=+$P($G(^ORD(101.43,Y,0)),U,2) Q:PSOI'>0
  1.  .I PATCLASS="I" D  Q
  1.  ..D FAILDEA^ORWDPS1(.FAIL,Y,ORNP,"I") I FAIL=1 S RESULT=1
  1.  .S DIAL=+$P(^OR(100,+IFN,4.5,I,0),U,2)
  1.  .S DIALTYP=$S($P(^ORD(101.41,DIAL,0),U)["ADDITIVE":"A",1:"S")
  1.  .D FDEA1^ORWDPS1(.FAIL,Y,DIALTYP,ORNP)
  1.  .I FAIL=1 S RESULT=1
  1.  .;I $$OIDEA^PSSUTLA1(PSOI,"I")>0 S RESULT=1 Q
  1.  Q RESULT
  1.  ;
  1. XFR ; -- transfer to inpt/outpt [IFN=order to be transferred]
  1.  N OI,PS I DG="TPN" S ERROR="TPN orders may not be copied!" Q
  1.  I $$INACTIVE^ORCACT03 S ERROR="Orders for inactive orderables may not be transferred; please enter a new order!" Q
  1.  S OI=+$O(^OR(100,+IFN,.1,"B",0)),ORPS=$G(^ORD(101.43,OI,"PS"))
  1.  I DG="UD RX",'$P(ORPS,U,2) S ERROR="This drug may not be ordered for an outpatient!" Q
  1.  I DG="O RX" D  Q:$L($G(ERROR))
  1.  . I '$P(ORPS,U) S ERROR="This drug may not be ordered for an inpatient!" Q
  1.  . D:$O(^OR(100,+IFN,4.5,"ID","MISC",0)) DOSES^ORCACT02(+IFN)
  1.  I DG="NV RX" D  Q:$L($G(ERROR))
  1.  .N XFRIO
  1.  .S XFRIO=$P($G(^TMP("BEHPSHMX",$J)),U,2)
  1.  .I XFRIO="I",'$P(ORPS,U) S ERROR="This drug may not be ordered as an inpatient medication!" Q
  1.  .I XFRIO="O",'$P(ORPS,U,2) S ERROR="This drug may not be ordered as outpatient medication!" Q
  1.  .D:$O(^OR(100,+IFN,4.5,"ID","MISC",0)) DOSES^ORCACT02(+IFN)
  1.  Q
  1.  ;
  1. RW ; -- rewrite/copy
  1.  I ACTSTS=12 S ERROR="Orders that have been dc'd due to editing may not be copied!" Q
  1.  ;IHS/MSC/REC/PLS - 08/09/10
  1.  ;I DG="NV RX" S ERROR="Outside med orders cannot be copied!" Q
  1.  I $L($G(NV)) S ERROR=NV_" orders cannot be copied!" Q
  1.  I DG="TPN" S ERROR="TPN orders may not be rewritten!" Q
  1.  I DG="UD RX",$$NTBG^ORCACT03(+IFN) S ERROR="This order has been marked 'Not to be Given' and may not be rewritten!" Q
  1.  I $$INACTIVE^ORCACT03 S ERROR="Orders for inactive orderables may not be copied; please enter a new order!" Q
  1.  I PKG="PS",'$$MEDOK^ORCACT03 S ERROR="This drug may not be ordered!" Q
  1.  I DG="O RX",$O(^OR(100,+IFN,4.5,"ID","MISC",0)) D DOSES^ORCACT02(+IFN) ;old form
  1.  Q
  1.  ;
  1. RN ; -- renew
  1.  I PKG'="PS",PKG'="OR" S ERROR="This order may not be renewed!" Q
  1.  I (ORDSTS=11)!(ORDSTS=10) S ERROR="This order has not been released to the service." Q
  1.  I ACTSTS=12 S ERROR="Orders that have been dc'd due to editing may not be renewed!" Q
  1.  I $P(OR3,U,6) S ERROR="This order has already been "_$S($P($G(^OR(100,+$P(OR3,U,6),3)),U,11)=1:"changed!",1:"renewed!") Q
  1.  I PKG="OR" D  Q  ;Generic orders
  1.  . I $$INACTIVE^ORCACT03 S ERROR="Orders for inactive orderables may not be renewed!" Q
  1.  . I DG="ADT" S ERROR="M.A.S. orders may not be renewed!" Q
  1.  . I "^1^2^6^7^"[(U_ORDSTS_U) Q  ;ok
  1.  . S ERROR="This order may not be renewed!"
  1.  I (PKG="PS"),$$INACTIVE^ORCACT03 S ERROR="Orders for inactive orderables may not be renewed!" Q
  1.  I '$$MEDOK^ORCACT03 S ERROR="This drug may not be ordered!" Q
  1. RN1 N PSIFN S PSIFN=$G(^OR(100,+IFN,4))
  1.  I PSIFN<1,'$O(^OR(100,+IFN,2,0)) S ERROR="Missing or invalid order number!" Q
  1.  I DG="O RX" D  Q  ;Outpt Meds
  1.  . ; IHS/CIA/DKM - 10/11/2005 - Modified next 3 lines to support ORWOR RX EXPIRED MAX parameter
  1.  . ;N ORZ,ORD S ORZ=$L($T(RENEW^PSORENW),",")
  1.  . ;I ORZ>1 S ORD=+$$VALUE^ORX8(+IFN,"DRUG"),X=$$RENEW^PSORENW(PSIFN,ORD)
  1.  . ;S:ORZ'>1 X=$$RENEW^PSORENW(PSIFN) I X<1 S ERROR=$P(X,U,2) Q
  1.  . N ORZ,ORD,DAYS S ORZ=$L($T(RENEW^PSORENW),","),DAYS=$$GET^XPAR("ALL","ORWOR RX EXPIRED MAX")
  1.  . I ORZ>1 S ORD=+$$VALUE^ORX8(+IFN,"DRUG"),X=$$RENEW^PSORENW(PSIFN,ORD,DAYS)
  1.  . S:ORZ'>1 X=$$RENEW^PSORENW(PSIFN,,DAYS) I X<1 S ERROR=$P(X,U,2) Q
  1.  . S X=+$P(X,U,2) D:X RESET^ORCACT03(+IFN,X)
  1.  . I $O(^OR(100,+IFN,4.5,"ID","MISC",0)) D DOSES^ORCACT02(+IFN) ;old format
  1.  I DG="UD RX",$$NTBG^ORCACT03(+IFN) S ERROR="This order has been marked 'Not to be Given' and may not be renewed!" Q
  1.  I ORDSTS=7,'$$IV^ORCACT03,$P(OR0,U,9)<$$FMADD^XLFDT(DT,-4)  S ERROR="Inpatient med orders may not be renewed more than 4 days after expiration!" Q
  1.  I ORDSTS'=6,ORDSTS'=7 S ERROR="This order may not be renewed!" Q
  1. RN2 I $O(^OR(100,+IFN,2,0))!$P(OR3,U,9) D  Q:$D(ERROR)!'PSIFN
  1.  . I $P(OR3,U,9),$$VALUE^ORX8(+IFN,"SCHEDULE",1,"E")="NOW" S ERROR="One-time NOW orders may not be renewed!" Q
  1.  . N DAD,ORD3,I,Y S DAD=$S($P(OR3,U,9):+$P(OR3,U,9),1:+IFN),Y=0
  1.  . S ORD3=$G(^OR(100,DAD,3)) I $P(ORD3,U,6) S ERROR="This complex order has already been renewed!" Q
  1.  . I $P(ORD3,U,3)'=6 S ERROR="This complex order is not active and may not be renewed!" Q
  1.  . I '$$AND^ORX8(DAD) S ERROR="Complex orders with sequential doses may not be renewed!" Q
  1.  . S I=0 F  S I=+$O(^OR(100,DAD,2,I)) Q:I<1  D  Q:Y
  1.  .. I I=+$O(^OR(100,DAD,2,0)),$$VALUE^ORX8(I,"SCHEDULE",1,"E")="NOW",$$VALUE^ORX8(DAD,"NOW") Q  ;ignore NOW orders
  1.  .. I $P($G(^OR(100,I,3)),U,3)'=6 S Y=1,ERROR="Complex orders with terminated doses may not be renewed!" Q
  1.  .. I PSIFN<1 S X=$$ACTIVE^PSJORREN(+ORVP,$G(^OR(100,I,4))) I +X'=1 S ERROR="This order may not be renewed: "_$S(+X>1:"Inactive orderable item",1:$P(X,U,2)) Q
  1.  ;I DG="TPN" S ERROR="TPN orders may not be renewed!" Q
  1.  S X=$$ACTIVE^PSJORREN(+ORVP,PSIFN) Q:+X=1  ;Ok
  1.  I +X>1,$P(X,U,2) D RESET^ORCACT03(+IFN,+$P(X,U,2)) Q  ;replace OI
  1.  S ERROR="This order may not be renewed: "_$P(X,U,2)
  1.  Q
  1.  ;
  1. XX ; -- edit/change--
  1.  I PKG="RA",ORDSTS'=11,ORDSTS'=10 S ERROR="Orders released to Radiology cannot be changed!" Q
  1.  I PKG="LR",ORDSTS'=11,ORDSTS'=10 S ERROR="Orders released to Lab cannot be changed!" Q
  1.  I PKG="FH",ORDSTS'=11,ORDSTS'=10 S ERROR="Orders released to Dietetics cannot be changed!" Q
  1.  I PKG="GMRC",ORDSTS'=11,ORDSTS'=10 S ERROR="Orders released to Consults cannot be changed!" Q
  1.  I DG="TPN" S ERROR="TPN orders may not be changed!" Q
  1.  I ORDSTS=3 S ERROR="Orders on hold may not be changed!" Q
  1.  I DG="UD RX",$$NTBG^ORCACT03(+IFN) S ERROR="This order has been marked 'Not to be Given' and may not be changed!" Q
  1.  I $O(^OR(100,+IFN,2,0)) S ERROR="Complex orders may not be changed!" Q
  1.  I $P(OR3,U,9) D  Q:$D(ERROR)
  1.  . Q:$$VALUE^ORX8(+IFN,"SCHEDULE",1,"E")="NOW"  ;NOW ok
  1.  . Q:'$O(^OR(100,+$P(OR3,U,9),4.5,"ID","CONJ",0))  ;no conj=1dose/ok
  1.  . S ERROR="Complex orders may not be changed!" Q
  1.  I $P(OR3,U,6) S ERROR="This order may not be changed - a "_$S($P($G(^OR(100,+$P(OR3,U,6),3)),U,11)=1:"change",1:"renewal")_" order already exists!" Q
  1.  I $P(OR3,U,11)=2 D  Q:$D(ERROR)
  1.  . ;IHS/MSC/PLS - 11/04/2010 - Restore behavior
  1.  . ;I (ORDSTS=10!(ORDSTS=11)),DG'="O RX" S ERROR="Unreleased renewals may not be changed!" Q
  1.  . I (ORDSTS=10!(ORDSTS=11)) S ERROR="Unreleased renewals may not be changed!" Q
  1.  . I PKG="PS",ORDSTS=5 S ERROR="Pending renewals may not be changed!" Q
  1.  I $$INACTIVE^ORCACT03 S ERROR="Orders for inactive orderables may not be changed; please enter a new order!" Q
  1.  I PKG="PS",'$$MEDOK^ORCACT03 S ERROR="This drug may not be ordered!" Q
  1.  I DG="O RX",$O(^OR(100,+IFN,4.5,"ID","MISC",0)) D DOSES^ORCACT02(+IFN) ;old form
  1.  Q
  1.  ;