Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ORCHECK

ORCHECK.m

Go to the documentation of this file. 
  1. ORCHECK ;SLC/MKB-Order checking calls ;23-Nov-2011 11:55;PLS
  1.  ;;3.0;ORDER ENTRY/RESULTS REPORTING;**7,56,70,94,141,1005,215,243,1010**;Dec 17, 1997;Build 47
  1.  ;;Per VHA Directive 2004-038, this routine should not be modified.
  1. DISPLAY ; -- DISPLAY event [called from ORCDLG,ORCACT4,ORCMED]
  1.  ;    Expects ORVP, ORNMSP, ORTAB, [ORWARD]
  1.  Q:$$GET^XPAR("DIV^SYS^PKG","ORK SYSTEM ENABLE/DISABLE")'="E"
  1.  N ORX,ORY,I
  1.  I ORNMSP="PS" D  ;reset to PSJ, PSJI, or PSO
  1.  . I $G(ORDG) S I=$P($G(^ORD(100.98,+ORDG,0)),U,3),I=$P(I," ") Q:'$L(I)  S ORNMSP="PS"_$S(I="UD":"I",1:I) Q
  1.  . I $G(ORXFER) S I=$P($P(^TMP("OR",$J,ORTAB,0),U,3),";",3) S:I="" I=$G(ORWARD) S ORNMSP="PS"_$S(I:"O",1:"I") ;opposite of list
  1.  S ORX(1)="|"_ORNMSP,ORX=1
  1.  D EN^ORKCHK(.ORY,+ORVP,.ORX,"DISPLAY") Q:'$D(ORY)
  1.  S I=0 F  S I=$O(ORY(I)) Q:I'>0  W !,$P(ORY(I),U,4) ; display only
  1.  Q
  1.  ;
  1. SELECT ; -- SELECT event
  1.  ;    Expects ORVP, ORDAILOG(PROMPT,ORI), ORNMSP
  1.  Q:$$GET^XPAR("DIV^SYS^PKG","ORK SYSTEM ENABLE/DISABLE")'="E"
  1.  N ORX,ORY,OI
  1.  S OI=+$G(ORDIALOG(PROMPT,ORI))
  1.  S ORX=1,ORX(1)=OI_"|"_ORNMSP_"|"_$$USID^ORMBLD(OI)
  1.  D EN^ORKCHK(.ORY,+ORVP,.ORX,"SELECT"),RETURN:$D(ORY)
  1.  Q
  1.  ;
  1. ACCEPT(MODE) ; -- ACCEPT event [called from ORCDLG,ORCACT4,ORCMED]
  1.  ;    Expects ORVP, ORDIALOG(), ORNMSP
  1.  Q:$$GET^XPAR("DIV^SYS^PKG","ORK SYSTEM ENABLE/DISABLE")'="E"
  1.  N ORX,ORY,ORZ,OI,ORSTRT,ORI,ORIT,ORID,ORSP
  1.  S:'$L($G(MODE)) MODE="ACCEPT"
  1.  S OI=$$PTR^ORCD("OR GTX ORDERABLE ITEM"),ORSTRT=$$START,ORX=0
  1.  S ORI=0 F  S ORI=$O(ORDIALOG(OI,ORI)) Q:ORI'>0  D STUF
  1.  I $G(ORDG)=+$O(^ORD(100.98,"B","IV RX",0)) S OI=$$PTR^ORCD("OR GTX ADDITIVE"),ORI=0 F  S ORI=$O(ORDIALOG(OI,ORI)) Q:ORI'>0  D STUF
  1.  D EN^ORKCHK(.ORY,+ORVP,.ORX,MODE),RETURN:$D(ORY)
  1.  Q
  1. STUF S ORIT=ORDIALOG(OI,ORI),ORSP=""
  1.  S:ORNMSP="LR" ORSP=+$G(ORDIALOG($$PTR^ORCD("OR GTX SPECIMEN"),ORI))
  1.  S ORID=$S($E(ORNMSP,1,2)="PS":$$DRUG(ORIT,OI),1:$$USID^ORMBLD(ORIT))
  1.  S ORZ=1,ORZ(1)=ORIT_"|"_ORNMSP_"|"_ORID
  1.  I MODE'="ALL" D EN^ORKCHK(.ORY,+ORVP,.ORZ,"SELECT"),RETURN:$D(ORY)
  1.  S ORX=ORX+1,ORX(ORX)=ORZ(1)_"|"_ORSTRT_"||"_ORSP K ORY,ORZ
  1.  Q
  1.  ;
  1. DELAY(MODE) ; -- Delayed ACCEPT event [called from ORMEVNT]
  1.  ;    Expects ORVP, ORIFN
  1.  Q:$$GET^XPAR("DIV^SYS^PKG","ORK SYSTEM ENABLE/DISABLE")'="E"
  1.  N ORX,ORY,ORCHECK S:'$L($G(MODE)) MODE="NOTIF"
  1.  D BLD(+ORIFN),EN^ORKCHK(.ORY,+ORVP,.ORX,MODE) Q:'$D(ORY)
  1.  D RETURN I MODE="NOTIF" S ORCHECK("OK")="Notification sent to provider" D OC^ORCSAVE2 Q  ; silent
  1.  Q
  1.  ;
  1. SESSION ; -- SESSION event [called from ORCSIGN]
  1.  ;    Expects ORVP, ORES()
  1.  Q:$$GET^XPAR("DIV^SYS^PKG","ORK SYSTEM ENABLE/DISABLE")'="E"
  1.  N ORX,ORY,ORIFN,I,X,Y
  1.  S ORIFN=0 F  S ORIFN=$O(ORES(ORIFN)) Q:ORIFN'>0  I +$P(ORIFN,";",2)'>1 D
  1.  . I "^5^6^10^11^"'[(U_$P($G(^OR(100,+ORIFN,3)),U,3)_U) Q  ;unreleased
  1.  . D BLD(+ORIFN) Q:'$D(^OR(100,+ORIFN,9))
  1.  . S ORCHECK("IFN")=+$G(ORCHECK("IFN"))+1
  1.  . S I=0 F  S I=$O(^OR(100,+ORIFN,9,I)) Q:I'>0  S X=$G(^(I,0)),Y=$G(^(1)),ORCHECK=+$G(ORCHECK)+1,ORCHECK(+ORIFN,$S($P(X,U,2):$P(X,U,2),1:99),ORCHECK)=$P(X,U,1,2)_U_Y
  1.  I $D(ORX) D EN^ORKCHK(.ORY,+ORVP,.ORX,"SESSION"),RETURN:$D(ORY),REMDUPS
  1.  Q
  1.  ; IHS/MSC/DKM - Added following subroutine
  1. MANUAL ; -- MANUAL event
  1.  ;    Expects ORVP, ORES()
  1.  Q:$$GET^XPAR("DIV^SYS^PKG","ORK SYSTEM ENABLE/DISABLE")'="E"
  1.  N ORX,ORY,ORIFN,I,X,Y
  1.  S ORIFN=0 F  S ORIFN=$O(ORES(ORIFN)) Q:ORIFN'>0  D
  1.  . D BLD(+ORIFN) ;Q:'$D(^OR(100,+ORIFN,9))
  1.  . S ORCHECK("IFN")=+$G(ORCHECK("IFN"))+1
  1.  I $D(ORX) D EN^ORKCHK(.ORY,+ORVP,.ORX,"MANUAL"),RETURN:$D(ORY)
  1.  Q
  1.  ;
  1. BLD(ORDER) ; -- Build new ORX(#) for ORDER
  1.  Q:'$G(ORDER)  Q:'$D(^OR(100,ORDER,0))  ;Q:$P($G(^(3)),U,11)  ;edit/renew
  1.  N PKG,START,ORI,ITEM,USID,SPEC,ORDG,PTR,INST
  1.  S ORDG=$P(^OR(100,ORDER,0),U,11),PKG=$$GET1^DIQ(9.4,$P(^(0),U,14)_",",1)
  1.  I PKG="PS",$G(ORDG) S ORI=$P($G(^ORD(100.98,+ORDG,0)),U,3),ORI=$P(ORI," "),PKG=PKG_$S(ORI="UD":"I",1:ORI)
  1.  S START=$$START(ORDER),ORI=0
  1.  F  S ORI=$O(^OR(100,ORDER,4.5,"ID","ORDERABLE",ORI)) Q:ORI'>0  D
  1.  . S INST=$P($G(^OR(100,ORDER,4.5,ORI,0)),U,3),PTR=$P($G(^(0)),U,2),ITEM=+$G(^(1))
  1.  . S USID=$S(PKG?1"PS".E:$$DRUG(ITEM,PTR,ORDER),1:$$USID^ORMBLD(ITEM))
  1.  . S SPEC=$S(PKG="LR":$$VALUE^ORCSAVE2(ORDER,"SPECIMEN",INST),1:"")
  1.  . S ORX=+$G(ORX)+1,ORX(ORX)=ITEM_"|"_PKG_"|"_USID_"|"_START_"|"_ORDER_"|"_SPEC
  1.  Q
  1.  ;
  1. RETURN ; -- Return checks in ORCHECK(ORIFN,CDL,#)
  1.  N I,IFN,CDL S I=0 F  S I=$O(ORY(I)) Q:I'>0  D
  1.  . S IFN=+$P(ORY(I),U) S:'IFN IFN="NEW"
  1.  . S CDL=+$P(ORY(I),U,3) S:'CDL CDL=99
  1.  . S:'$D(ORCHECK(IFN)) ORCHECK("IFN")=+$G(ORCHECK("IFN"))+1 ; count
  1.  . S ORCHECK=+$G(ORCHECK)+1,ORCHECK(IFN,CDL,ORCHECK)=$P(ORY(I),U,2,4)
  1.  Q
  1.  ;
  1. REMDUPS ;
  1.  N IFN,CDL,I
  1.  S IFN=0 F  S IFN=$O(ORCHECK(IFN)) Q:'IFN  D
  1.  . S CDL=0 F  S CDL=$O(ORCHECK(IFN,CDL)) Q:'CDL  D
  1.  . . S I=0 F  S I=$O(ORCHECK(IFN,CDL,I)) Q:'I  D
  1.  . . . S J=I F  S J=$O(ORCHECK(IFN,CDL,J)) Q:'J  I $G(ORCHECK(IFN,CDL,I))=$G(ORCHECK(IFN,CDL,J)) K ORCHECK(IFN,CDL,J) S ORCHECK=$G(ORCHECK)-1
  1.  Q
  1. START(DA) ; -- Returns start date/time
  1.  N I,X,Y,%DT S Y=""
  1.  I $G(DA) S X=$O(^OR(100,DA,4.5,"ID","START",0)),X=$G(^OR(100,DA,4.5,+X,1))
  1.  E  D  ; look in ORDIALOG instead
  1.  . S I=0 F  S I=$O(ORDIALOG(I)) Q:I'>0  Q:$P(ORDIALOG(I),U,2)="START"
  1.  . S X=$S(I:$G(ORDIALOG(I,1)),1:"")
  1.  D AM^ORCSAVE2:X="AM",NEXT^ORCSAVE2:X="NEXT"
  1.  D ADMIN^ORCSAVE2("NEXT"):X="NEXTA",ADMIN^ORCSAVE2("CLOSEST"):X="CLOSEST"
  1.  I $L(X) S %DT="TX" D ^%DT S:Y'>0 Y=""
  1.  Q Y
  1.  ;
  1. DRUG(OI,PTR,IFN) ; -- Returns 6 ^-piece identifier for Dispense Drug
  1.  N ORDD,ORNDF,Y
  1.  I ORDG=+$O(^ORD(100.98,"B","IV RX",0)) S ORDD=$$IV G D1
  1.  I $G(IFN) S ORDD=$O(^OR(100,IFN,4.5,"ID","DRUG",0)),ORDD=+$G(^OR(100,IFN,4.5,+ORDD,1))
  1.  E  S ORDD=+$G(ORDIALOG($$PTR^ORCD("OR GTX DISPENSE DRUG"),1))
  1. D1 Q:'ORDD "" S ORNDF=$$ENDCM^PSJORUTL(ORDD)
  1.  S Y=$P(ORNDF,U,3)_"^^99NDF^"_ORDD_U_$$NAME50^ORPEAPI(ORDD)_"^99PSD"
  1.  Q Y
  1.  ;
  1. IV() ; -- Get Dispense Drug for IV orderable
  1.  N PSOI,TYPE,VOL,ORY
  1.  S PSOI=+$P($G(^ORD(101.43,+OI,0)),U,2),VOL=""
  1.  S TYPE=$S(PTR=$$PTR^ORCD("OR GTX ADDITIVE"):"A",1:"B")
  1.  S:TYPE="B" VOL=$S($G(IFN):$$VALUE^ORCSAVE2(IFN,"VOLUME"),1:+$G(ORDIALOG($$PTR^ORCD("OR GTX VOLUME"),1)))
  1.  D ENDDIV^PSJORUTL(PSOI,TYPE,VOL,.ORY)
  1.  Q +$G(ORY)
  1.  ;
  1. LIST(IFN) ; -- Displays list of ORCHECK(IFN) checks
  1.  N ORI,ORJ,ORZ,ORMAX,ORTX,ON,OFF
  1.  S ORZ=0 F  S ORZ=$O(ORCHECK(IFN,ORZ)) Q:ORZ'>0  D
  1.  . S:ORZ=1 ON=IOINHI,OFF=IOINORM S:ORZ'=1 (ON,OFF)="" ; use bold if High
  1.  . S ORI=0 F  S ORI=$O(ORCHECK(IFN,ORZ,ORI)) Q:ORI'>0  D
  1.  . . S X=$P(ORCHECK(IFN,ORZ,ORI),U,3) I $L(X)<75 W !,ON_">>>  "_X_OFF Q
  1.  . . S ORMAX=74 K ORTX D TXT^ORCHTAB Q:'$G(ORTX)  ; wrap
  1.  . . F ORJ=1:1:ORTX W !,ON_$S(ORJ=1:">>>  ",1:"      ")_ORTX(ORJ)_OFF
  1.  W !
  1.  Q
  1.  ;
  1. CANCEL() ; -- Returns 1 or 0: Cancel order(s)?
  1.  N X,Y,DIR,NUM
  1.  S NUM=+$G(ORCHECK("IFN")),DIR(0)="YA"
  1.  S DIR("A")="Do you want to cancel "_$S(NUM>1:"any of the new orders? ",1:"the new order? ")
  1.  S DIR("?",1)="Enter YES to cancel "_$S(NUM>1:"an",1:"the")_" order.  If you wish to override these order checks"
  1.  S DIR("?",2)="and release "_$S(NUM>1:"these orders",1:"this order")_", enter NO; you will be prompted for a justification",DIR("?")="if there are any highlighted critical order checks."
  1.  D ^DIR
  1.  Q +Y
  1.  ;
  1. REASON() ; -- Reason for overriding order checks
  1.  ; I '$D(^XUSEC("ORES",DUZ)),'$D(^XUSEC("ORELSE",DUZ)) Q  ??
  1.  N X,Y,DIR
  1.  S DIR(0)="FA^2:80^K:X?1."" "" X",DIR("A")="REASON FOR OVERRIDE: "
  1.  S DIR("?")="Enter a justification for overriding these order checks, up to 80 characters"
  1.  D ^DIR I $D(DTOUT)!$D(DUOUT) S Y="^"
  1.  Q Y
  1. OCAPI(IFN,ORPLACE) ;IA #4859
  1.  ;API to get the order checking info for a specific order (IFN)
  1.  ;info is stored in ^TMP($J,ORPLACE)
  1.  ;               ^TMP($J,ORPLACE,D0,"OC LEVEL")="order check level"
  1.  ;                                                 ,"OC TEXT")="order check text"
  1.  ;                                                 ,"OR REASON")="over ride reason text"
  1.  ;                                                 ,"OR PROVIDER")="provider DUZ who entered over ride reason"
  1.  ;                                                 ,"OR DT")="date/time over ride reason was entered"
  1.  ; NOTE on OC LEVEL: 1 is HIGH, 2 is MODERATE, 3 is LOW
  1.  I '$D(^OR(100,IFN,9)) Q
  1.  N I
  1.  S I=0 F  S I=$O(^OR(100,IFN,9,I)) Q:'I  D
  1.  .S ^TMP($J,ORPLACE,I,"OC LEVEL")=$P($G(^OR(100,IFN,9,I,0)),U,2)
  1.  .S ^TMP($J,ORPLACE,I,"OC TEXT")=$G(^OR(100,IFN,9,I,1))
  1.  .S ^TMP($J,ORPLACE,I,"OR REASON")=$P($G(^OR(100,IFN,9,I,0)),U,4)
  1.  .S ^TMP($J,ORPLACE,I,"OR PROVIDER")=$P($G(^OR(100,IFN,9,I,0)),U,5)
  1.  .S ^TMP($J,ORPLACE,I,"OR DT")=$P($G(^OR(100,IFN,9,I,0)),U,6)
  1.  Q