Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: OREORV

OREORV.m

Go to the documentation of this file. 
  1. OREORV ; SLC/GDU - Orderable Items File Record Validation [10/15/04 09:16]
  1.  ;;3.0;ORDER ENTRY/RESULTS REPORTING;**217**;Dec 17, 1997
  1.  ;OREORV - Orderable Item Record Validation
  1.  ;
  1.  ;FIX FOR NOIS CASES:
  1.  ;DAN-0204-42157, ALB-1001-51034, SBY-0803-30443, NJH-0402-20607
  1.  ;
  1.  ;Presents the user with an explanation of the purpose of this program.
  1.  ;It will ask the user if they wish to run the OI record validation.
  1.  ;Allows the user to select where the output of the report is sent to.
  1.  ;Also allows the user to queue the program run to TASKMAN.
  1.  ;
  1.  ;External Variables
  1.  ;  IO  - Selected IO device
  1.  ;  IOF - IO device Form Feed
  1.  ;  ION - IO device logical name
  1.  ;
  1.  ;External References
  1.  ;  ^%ZIS    - DBIA 10086
  1.  ;  ^%ZISC   - DBIA 10089
  1.  ;  ^%ZTLOAD - DBIA 10063
  1.  ;  ^DIR     - DBIA 10026
  1.  ;  ^OREORV1 - Second routine of this utility
  1.  ;  ^OREORV2 - Third routine of this utility
  1.  ;
  1. MAIN ;Main entry point for this program
  1.  ;Local Variables
  1.  ;  %ZIS   - Input specification variable, ^%ZIS
  1.  ;  DIR    - Input array variable for ^DIR
  1.  ;  DLI    - Description Line Index
  1.  ;  DL     - Description Line, indirect variable
  1.  ;  DTOUT  - Time out indicator, output variable ^DIR
  1.  ;  DUOUT  - Up arrow out indicator, output variable ^DIR
  1.  ;  PLI    - Prompt Line Index
  1.  ;  PL     - Prompt Line, indirect variable
  1.  ;  POP    - Exit Status, output variable ^%ZIS
  1.  ;  ZTDESC - Task Description, input variable ^%ZTLOAD
  1.  ;  ZTIO   - Task IO device, input variable ^%ZTLOAD
  1.  ;  ZTRTN  - Task routine entry point, input variable ^%ZTLOAD
  1.  ;  ZTSK   - Task number assigned, output variable ^%ZTLOAD
  1.  ;  Y      - Processed user input, output variable ^DIR
  1.  N %ZIS,DIR,DLI,DL,DTOUT,DUOUT,PLI,PL,POP,ZTDESC,ZTIO,ZTRTN,ZTSK,Y
  1.  ;Clears screen and presents explanation, asks if user wants to continue
  1.  W:$D(IOF) @IOF
  1.  W $P($T(SH),";",3),!
  1.  F DLI=1:1:19 S DL="DL"_DLI W !,$P($T(@DL),";",3)
  1.  S DIR(0)="Y",DIR("A")=$P($T(PMT1),";",3)
  1.  W ! D ^DIR
  1.  ;If user selects No, up-arrows out, or times out program is stopped
  1.  I Y=0!($D(DTOUT))!($D(DUOUT)) G EXIT
  1.  ;If user selects Yes, programs presents user with device selection.
  1.  W:$D(IOF) @IOF
  1.  W $P($T(SH),";",3),!
  1.  F PLI=1:1:6 S PL="PL"_PLI W !,$P($T(@PL),";",3)
  1.  W !
  1.  S %ZIS="Q" D ^%ZIS
  1.  ;Processing user device selection
  1.  I POP G EXIT
  1.  I $D(IO("Q")) D  K IO("Q") G EXIT
  1.  . S ZTDESC="Orderable Item Validation Report"
  1.  . S ZTRTN="EN^OREORV"
  1.  . S ZTIO=ION
  1.  . D ^%ZTLOAD I $D(ZTSK) W !?32,"REQUEST QUEUED"
  1.  U IO D EN
  1. EXIT ;Exit point for this program
  1.  D ^%ZISC
  1.  Q
  1. EN ;Process the File 101.43
  1.  ;TASKMAN entry point
  1.  ;^TMP($J,"OIC" is fully documented in OREORV1
  1.  K ^TMP($J,"OIC")
  1.  ;Builds temp global ^TMP($J,"OIC", flags active OI records w/o matching
  1.  ;source records.
  1.  D ^OREORV1
  1.  ;Print report from contents of ^TMP($J,"OIC"
  1.  D ^OREORV2
  1.  K ^TMP($J,"OIC")
  1.  Q
  1.  ;User interface text
  1. SH ;;Orderable Items File Record Validation
  1. DL1 ;;Brief Description:
  1. DL2 ;;This program scans the Orderable Items file, file # 101.43.
  1. DL3 ;;It take the value stored in the ID field and performs a set of tests.
  1. DL4 ;;
  1. DL5 ;;   1. It determines if the ID field is null.
  1. DL6 ;;   2. It determines if it has a source record IEN
  1. DL7 ;;   3. It determines if it has a source record package code
  1. DL8 ;;   4. It determines if the package code is formatted properly
  1. DL9 ;;   5. It determines if the package code is in the current spec*
  1. DL10 ;;      If package code is not in current spec*, it is included in the
  1. DL11 ;;      report for manual confirmation. It is not modified by this
  1. DL12 ;;      utility.
  1. DL13 ;;   6. It Validates records by matching to a source file record
  1. DL14 ;;      If no match found and record is active it is flagged inactive.
  1. DL15 ;;   7. It creates a report detailing its findings.
  1. DL16 ;;
  1. DL17 ;;* The source files the orderable item record is tested against are
  1. DL18 ;;defined in the OE/RR Version 3 Package Interface Specification July
  1. DL19 ;;2001
  1. PMT1 ;;Do you wish to run this program? Enter Yes or No
  1. PL1 ;;Select where you want the report to print to.
  1. PL2 ;;
  1. PL3 ;;Just hit enter to send the report to the screen.
  1. PL4 ;;Enter the name of the printer.
  1. PL5 ;;Queue the program to run at a later time.
  1. PL6 ;;Enter "^" to quit